src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-12
  18   clang-11
  19   clang-10
  20   clang-9
  21   gcc-10
  22   gcc-9
  23   cc
  24 )
  25
  26 project(vpp C)
  27
  28 if(CMAKE_VERSION VERSION_LESS 3.12)
  29   macro(add_compile_definitions defs)
  30     foreach(d ${defs})
  31       add_compile_options(-D${d})
  32     endforeach()
  33   endmacro()
  34 endif()
  35
  36 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  37   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  38 endif()
  39
  40 include(CheckCCompilerFlag)
  41 include(CheckIPOSupported)
  42 include(GNUInstallDirs)
  43 include(cmake/misc.cmake)
  44 include(cmake/cpu.cmake)
  45 include(cmake/ccache.cmake)
  46
  47 ##############################################################################
  48 # VPP Version
  49 ##############################################################################
  50 execute_process(
  51   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  52   COMMAND scripts/version
  53   OUTPUT_VARIABLE VPP_VERSION
  54   OUTPUT_STRIP_TRAILING_WHITESPACE
  55 )
  56 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  57 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  58
  59 ##############################################################################
  60 # cross compiling
  61 ##############################################################################
  62 if(CMAKE_CROSSCOMPILING)
  63   set(CMAKE_IGNORE_PATH
  64     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  65     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  66   )
  67 endif()
  68 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  69
  70 ##############################################################################
  71 # build config
  72 ##############################################################################
  73 check_c_compiler_flag("-Wno-address-of-packed-member"
  74                       compiler_flag_no_address_of_packed_member)
  75 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  76 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  77
  78 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  79 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  80 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  81 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFile/__pycache__)
  82
  83 if (CMAKE_BUILD_TYPE)
  84   add_compile_options(-g -fPIC -Werror -Wall)
  85 endif()
  86
  87 if (compiler_flag_no_address_of_packed_member)
  88   add_compile_options(-Wno-address-of-packed-member)
  89 endif()
  90
  91 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  92 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  93
  94 set(CMAKE_C_FLAGS_RELEASE "")
  95 set(CMAKE_C_FLAGS_DEBUG "")
  96
  97 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  98   add_compile_options(-O3 -fstack-protector -fno-common)
  99   add_compile_definitions(_FORTIFY_SOURCE=2)
 100   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
 101 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 102   add_compile_options(-O0 -fstack-protector -fno-common)
 103   add_compile_definitions(CLIB_DEBUG)
 104 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 105   add_compile_options(-O0)
 106   add_compile_definitions(__COVERITY__)
 107 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 108   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 109   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 110 endif()
 111
 112 set(BUILD_TYPES release debug coverity gcov)
 113 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 114 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 115              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 116
 117 ##############################################################################
 118 # link time optimizations
 119 ##############################################################################
 120 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 121   check_ipo_supported(RESULT _result)
 122   if (_result)
 123     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 124   endif()
 125 endif()
 126
 127 ##############################################################################
 128 # sanitizers
 129 ##############################################################################
 130
 131 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 132 set(VPP_SANITIZE_ADDR_OPTIONS
 133   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 134   CACHE
 135   STRING "Address sanitizer arguments"
 136 )
 137
 138 if (VPP_ENABLE_SANITIZE_ADDR)
 139   add_compile_options(-fsanitize=address)
 140   add_compile_definitions(CLIB_SANITIZE_ADDR)
 141   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 142   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 143 endif (VPP_ENABLE_SANITIZE_ADDR)
 144
 145 ##############################################################################
 146 # trajectory trace
 147 ##############################################################################
 148
 149 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 150 if(VPP_ENABLE_TRAJECTORY_TRACE)
 151   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 152 endif()
 153
 154 ##############################################################################
 155 # install config
 156 ##############################################################################
 157 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 158 if(VPP_SET_RPATH)
 159   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 160 endif()
 161 set(CMAKE_INSTALL_MESSAGE NEVER)
 162
 163 include_directories (
 164         ${CMAKE_SOURCE_DIR}
 165         ${VPP_BINARY_DIR}
 166 )
 167 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 168
 169 set(THREADS_PREFER_PTHREAD_FLAG ON)
 170 find_package(Threads REQUIRED)
 171
 172 include(cmake/syscall.cmake)
 173 include(cmake/api.cmake)
 174 include(cmake/library.cmake)
 175 include(cmake/exec.cmake)
 176 include(cmake/plugin.cmake)
 177
 178 ##############################################################################
 179 # subdirs - order matters
 180 ##############################################################################
 181 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 182 if(VPP_HOST_TOOLS_ONLY)
 183   set(SUBDIRS tools/vppapigen cmake)
 184 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 185   find_package(OpenSSL)
 186   set(SUBDIRS
 187     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 188     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 189     tools/appimage
 190   )
 191 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 192   set(SUBDIRS vppinfra)
 193 else()
 194   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 195 endif()
 196
 197 foreach(DIR ${SUBDIRS})
 198   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 199 endforeach()
 200
 201 ##############################################################################
 202 # detect if we are inside git repo and add configure dependency
 203 ##############################################################################
 204 execute_process(
 205   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 206   COMMAND git rev-parse --show-toplevel
 207   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 208   OUTPUT_STRIP_TRAILING_WHITESPACE
 209   ERROR_QUIET
 210 )
 211
 212 if (VPP_GIT_TOPLEVEL_DIR)
 213   set_property(
 214     DIRECTORY APPEND PROPERTY
 215     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 216   )
 217 endif()
 218
 219 ##############################################################################
 220 # custom targets
 221 ##############################################################################
 222
 223 add_custom_target(run
 224   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 225   COMMENT "Starting VPP..."
 226   USES_TERMINAL
 227 )
 228
 229 add_custom_target(debug
 230   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 231   COMMENT "Starting VPP in the debugger..."
 232   USES_TERMINAL
 233 )
 234
 235 add_custom_target(config
 236   COMMAND ccmake ${CMAKE_BINARY_DIR}
 237   COMMENT "Starting Configuration TUI..."
 238   USES_TERMINAL
 239 )
 240
 241 foreach(bt ${BUILD_TYPES})
 242   add_custom_target(set-build-type-${bt}
 243     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 244     COMMENT "Changing build type to ${bt}"
 245     USES_TERMINAL
 246   )
 247 endforeach()
 248
 249 mark_as_advanced(CLEAR
 250   CMAKE_C_FLAGS
 251   CMAKE_C_COMPILER
 252   CMAKE_EXPORT_COMPILE_COMMANDS
 253   CMAKE_INSTALL_PREFIX
 254   CMAKE_LINKER
 255   CMAKE_SHARED_LINKER_FLAGS
 256   CMAKE_VERBOSE_MAKEFILE
 257 )
 258
 259 ##############################################################################
 260 # print configuration
 261 ##############################################################################
 262 message(STATUS "Configuration:")
 263 pr("VPP version" ${VPP_VERSION})
 264 pr("VPP library version" ${VPP_LIB_VERSION})
 265 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 266 pr("Build type" ${CMAKE_BUILD_TYPE})
 267 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 268 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 269 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 270 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 271 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 272 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 273 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})