src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-12
  18   clang-11
  19   clang-10
  20   clang-9
  21   gcc-10
  22   gcc-9
  23   cc
  24 )
  25
  26 project(vpp C)
  27
  28 if(CMAKE_VERSION VERSION_LESS 3.12)
  29   macro(add_compile_definitions defs)
  30     foreach(d ${defs})
  31       add_compile_options(-D${d})
  32     endforeach()
  33   endmacro()
  34 endif()
  35
  36 include(CheckCCompilerFlag)
  37 include(CheckIPOSupported)
  38 include(cmake/misc.cmake)
  39 include(cmake/cpu.cmake)
  40 include(cmake/ccache.cmake)
  41
  42 ##############################################################################
  43 # VPP Version
  44 ##############################################################################
  45 execute_process(
  46   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  47   COMMAND scripts/version
  48   OUTPUT_VARIABLE VPP_VERSION
  49   OUTPUT_STRIP_TRAILING_WHITESPACE
  50 )
  51 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  52 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  53
  54 ##############################################################################
  55 # cross compiling
  56 ##############################################################################
  57 if(CMAKE_CROSSCOMPILING)
  58   set(CMAKE_IGNORE_PATH
  59     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  60     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  61   )
  62 endif()
  63 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  64
  65 ##############################################################################
  66 # build config
  67 ##############################################################################
  68 check_c_compiler_flag("-Wno-address-of-packed-member"
  69                       compiler_flag_no_address_of_packed_member)
  70 set(VPP_RUNTIME_DIR "bin" CACHE STRING "Relative runtime directory path")
  71 set(VPP_LIBRARY_DIR "lib" CACHE STRING "Relative library directory path")
  72
  73 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  74 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  75 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  76
  77 if (CMAKE_BUILD_TYPE)
  78   add_compile_options(-g -fPIC -Werror -Wall)
  79 endif()
  80
  81 if (compiler_flag_no_address_of_packed_member)
  82   add_compile_options(-Wno-address-of-packed-member)
  83 endif()
  84
  85 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  86 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  87
  88 set(CMAKE_C_FLAGS_RELEASE "")
  89 set(CMAKE_C_FLAGS_DEBUG "")
  90
  91 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  92   add_compile_options(-O3 -fstack-protector -fno-common)
  93   add_compile_definitions(_FORTIFY_SOURCE=2)
  94   string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  95 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
  96   add_compile_options(-O0 -fstack-protector -fno-common)
  97   add_compile_definitions(CLIB_DEBUG)
  98 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
  99   add_compile_options(-O0)
 100   add_compile_definitions(__COVERITY__)
 101 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 102   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 103   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 104 endif()
 105
 106 set(BUILD_TYPES release debug coverity gcov)
 107 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 108 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 109              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 110
 111 ##############################################################################
 112 # link time optimizations
 113 ##############################################################################
 114 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 115   check_ipo_supported(RESULT _result)
 116   if (_result)
 117     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 118   endif()
 119 endif()
 120
 121 ##############################################################################
 122 # sanitizers
 123 ##############################################################################
 124
 125 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 126 set(VPP_SANITIZE_ADDR_OPTIONS
 127   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 128   CACHE
 129   STRING "Address sanitizer arguments"
 130 )
 131
 132 if (VPP_ENABLE_SANITIZE_ADDR)
 133   add_compile_options(-fsanitize=address)
 134   add_compile_definitions(CLIB_SANITIZE_ADDR)
 135   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 136   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 137 endif (VPP_ENABLE_SANITIZE_ADDR)
 138
 139 ##############################################################################
 140 # trajectory trace
 141 ##############################################################################
 142
 143 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 144 if(VPP_ENABLE_TRAJECTORY_TRACE)
 145   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 146 endif()
 147
 148 ##############################################################################
 149 # install config
 150 ##############################################################################
 151 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 152 if(VPP_SET_RPATH)
 153   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 154 endif()
 155 set(CMAKE_INSTALL_MESSAGE NEVER)
 156
 157 include_directories (
 158         ${CMAKE_SOURCE_DIR}
 159         ${VPP_BINARY_DIR}
 160 )
 161 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 162
 163 set(THREADS_PREFER_PTHREAD_FLAG ON)
 164 find_package(Threads REQUIRED)
 165
 166 include(cmake/syscall.cmake)
 167 include(cmake/api.cmake)
 168 include(cmake/library.cmake)
 169 include(cmake/exec.cmake)
 170 include(cmake/plugin.cmake)
 171
 172 ##############################################################################
 173 # subdirs - order matters
 174 ##############################################################################
 175 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 176 if(VPP_HOST_TOOLS_ONLY)
 177   set(SUBDIRS tools/vppapigen cmake)
 178 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 179   find_package(OpenSSL)
 180   set(SUBDIRS
 181     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl plugins
 182     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 183     tools/appimage
 184   )
 185 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 186   set(SUBDIRS vppinfra)
 187 else()
 188   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 189 endif()
 190
 191 foreach(DIR ${SUBDIRS})
 192   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 193 endforeach()
 194
 195 ##############################################################################
 196 # detect if we are inside git repo and add configure dependency
 197 ##############################################################################
 198 execute_process(
 199   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 200   COMMAND git rev-parse --show-toplevel
 201   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 202   OUTPUT_STRIP_TRAILING_WHITESPACE
 203   ERROR_QUIET
 204 )
 205
 206 if (VPP_GIT_TOPLEVEL_DIR)
 207   set_property(
 208     DIRECTORY APPEND PROPERTY
 209     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 210   )
 211 endif()
 212
 213 ##############################################################################
 214 # custom targets
 215 ##############################################################################
 216
 217 add_custom_target(run
 218   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 219   COMMENT "Starting VPP..."
 220   USES_TERMINAL
 221 )
 222
 223 add_custom_target(debug
 224   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 225   COMMENT "Starting VPP in the debugger..."
 226   USES_TERMINAL
 227 )
 228
 229 add_custom_target(config
 230   COMMAND ccmake ${CMAKE_BINARY_DIR}
 231   COMMENT "Starting Configuration TUI..."
 232   USES_TERMINAL
 233 )
 234
 235 foreach(bt ${BUILD_TYPES})
 236   add_custom_target(set-build-type-${bt}
 237     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 238     COMMENT "Changing build type to ${bt}"
 239     USES_TERMINAL
 240   )
 241 endforeach()
 242
 243 mark_as_advanced(CLEAR
 244   CMAKE_C_FLAGS
 245   CMAKE_C_COMPILER
 246   CMAKE_EXPORT_COMPILE_COMMANDS
 247   CMAKE_INSTALL_PREFIX
 248   CMAKE_LINKER
 249   CMAKE_SHARED_LINKER_FLAGS
 250   CMAKE_VERBOSE_MAKEFILE
 251 )
 252
 253 ##############################################################################
 254 # print configuration
 255 ##############################################################################
 256 message(STATUS "Configuration:")
 257 pr("VPP version" "${VPP_VERSION}")
 258 pr("VPP library version" "${VPP_LIB_VERSION}")
 259 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 260 pr("Build type" "${CMAKE_BUILD_TYPE}")
 261 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 262 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 263 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 264 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 265 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 266 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 267 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")