src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19 include(cmake/misc.cmake)
  20 include(cmake/cpu.cmake)
  21 include(cmake/ccache.cmake)
  22
  23 ##############################################################################
  24 # VPP Version
  25 ##############################################################################
  26 execute_process(
  27   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  28   COMMAND scripts/version
  29   OUTPUT_VARIABLE VPP_VERSION
  30   OUTPUT_STRIP_TRAILING_WHITESPACE
  31 )
  32 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  33 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  34
  35 ##############################################################################
  36 # cross compiling
  37 ##############################################################################
  38 if(CMAKE_CROSSCOMPILING)
  39   set(CMAKE_IGNORE_PATH
  40     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  41     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  42   )
  43 endif()
  44 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  45
  46 ##############################################################################
  47 # build config
  48 ##############################################################################
  49 check_c_compiler_flag("-Wno-address-of-packed-member"
  50                       compiler_flag_no_address_of_packed_member)
  51
  52 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  53 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  54
  55 if (CMAKE_BUILD_TYPE)
  56   set(CMAKE_C_FLAGS "-g -fPIC ${CMAKE_C_FLAGS}")
  57   set(CMAKE_C_FLAGS "-fstack-protector-all ${CMAKE_C_FLAGS}")
  58   set(CMAKE_C_FLAGS "-Werror ${CMAKE_C_FLAGS}")
  59   set(CMAKE_C_FLAGS "-DFORTIFY_SOURCE=2 ${CMAKE_C_FLAGS}")
  60 endif()
  61
  62 if (compiler_flag_no_address_of_packed_member)
  63   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  64 endif()
  65
  66 set(CMAKE_C_FLAGS_RELEASE "-O2 ${CMAKE_C_FLAGS_RELEASE}")
  67 set(CMAKE_C_FLAGS_DEBUG "-O0 -DCLIB_DEBUG ${CMAKE_C_FLAGS_DEBUG}")
  68 set(CMAKE_LINKER_FLAGS_RELEASE "-pie -Wl,-z,now ${CMAKE_LINKER_FLAGS_RELEASE}")
  69 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  70
  71 ##############################################################################
  72 # install config
  73 ##############################################################################
  74 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
  75 set(CMAKE_INSTALL_MESSAGE NEVER)
  76
  77 include_directories (
  78         ${CMAKE_SOURCE_DIR}
  79         ${CMAKE_BINARY_DIR}
  80         ${CMAKE_BINARY_DIR}/include
  81 )
  82 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
  83
  84 set(THREADS_PREFER_PTHREAD_FLAG ON)
  85 find_package(Threads REQUIRED)
  86
  87 include(cmake/syscall.cmake)
  88 include(cmake/api.cmake)
  89 include(cmake/library.cmake)
  90 include(cmake/exec.cmake)
  91 include(cmake/plugin.cmake)
  92
  93 ##############################################################################
  94 # subdirs - order matters
  95 ##############################################################################
  96 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  97   find_package(OpenSSL REQUIRED)
  98   set(SUBDIRS
  99     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
 100     vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool cmake pkg
 101     tools/appimage
 102   )
 103 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 104   set(SUBDIRS vppinfra)
 105 else()
 106   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 107 endif()
 108
 109 foreach(DIR ${SUBDIRS})
 110   add_subdirectory(${DIR})
 111 endforeach()
 112
 113 ##############################################################################
 114 # detect if we are inside git repo and add configure dependency
 115 ##############################################################################
 116 execute_process(
 117   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 118   COMMAND git rev-parse --show-toplevel
 119   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 120   OUTPUT_STRIP_TRAILING_WHITESPACE
 121   ERROR_QUIET
 122 )
 123
 124 if (VPP_GIT_TOPLEVEL_DIR)
 125   set_property(
 126     DIRECTORY APPEND PROPERTY
 127     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 128   )
 129 endif()
 130
 131 ##############################################################################
 132 # print configuration
 133 ##############################################################################
 134 message(STATUS "Configuration:")
 135 pr("VPP version" "${VPP_VERSION}")
 136 pr("VPP library version" "${VPP_LIB_VERSION}")
 137 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 138 pr("Build type" "${CMAKE_BUILD_TYPE}")
 139 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 140 pr("Linker flags" "${CMAKE_LINKER_FLAGS}${CMAKE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 141 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 142 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 143 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 144 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")