src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 set(CMAKE_C_COMPILER_NAMES clang gcc cc)
  17
  18 project(vpp C)
  19
  20 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  21   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  22 endif()
  23
  24 include(CheckCCompilerFlag)
  25 include(CheckIPOSupported)
  26 include(GNUInstallDirs)
  27 include(cmake/misc.cmake)
  28 include(cmake/cpu.cmake)
  29 include(cmake/ccache.cmake)
  30
  31 ##############################################################################
  32 # VPP Version
  33 ##############################################################################
  34 execute_process(
  35   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  36   COMMAND scripts/version
  37   OUTPUT_VARIABLE VPP_VERSION
  38   OUTPUT_STRIP_TRAILING_WHITESPACE
  39 )
  40 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  41 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  42
  43 ##############################################################################
  44 # compiler specifics
  45 ##############################################################################
  46
  47 set(MIN_SUPPORTED_CLANG_C_COMPILER_VERSION 9.0.0)
  48 set(MIN_SUPPORTED_GNU_C_COMPILER_VERSION 9.0.0)
  49
  50 if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
  51   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_CLANG_C_COMPILER_VERSION)
  52     set(COMPILER_TOO_OLD TRUE)
  53   endif()
  54 elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU")
  55   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_GNU_C_COMPILER_VERSION)
  56     set(COMPILER_TOO_OLD TRUE)
  57   endif()
  58 else()
  59   message(WARNING "WARNING: Unsupported C compiler `${CMAKE_C_COMPILER_ID}` is used")
  60   set (PRINT_MIN_C_COMPILER_VER TRUE)
  61 endif()
  62 if (COMPILER_TOO_OLD)
  63   message(WARNING "WARNING: C compiler version is too old and it's usage may result")
  64   message(WARNING "         in sub-optimal binaries or lack of support for specific CPU types.")
  65   set (PRINT_MIN_C_COMPILER_VER TRUE)
  66 endif()
  67
  68 if (PRINT_MIN_C_COMPILER_VER)
  69   string (APPEND _t "Supported C compilers are ")
  70   string (APPEND _t "Clang ${MIN_SUPPORTED_CLANG_C_COMPILER_VERSION} or higher ")
  71   string (APPEND _t "and GNU ${MIN_SUPPORTED_GNU_C_COMPILER_VERSION} or higher.")
  72   message(WARNING "         ${_t}")
  73   unset (_t)
  74 endif()
  75
  76 ##############################################################################
  77 # cross compiling
  78 ##############################################################################
  79 if(CMAKE_CROSSCOMPILING)
  80   set(CMAKE_IGNORE_PATH
  81     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  82     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  83   )
  84 endif()
  85 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  86
  87 ##############################################################################
  88 # build config
  89 ##############################################################################
  90 check_c_compiler_flag("-Wno-address-of-packed-member"
  91                       compiler_flag_no_address_of_packed_member)
  92 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  93 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  94
  95 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  96 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  97 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  98 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
  99
 100 if (CMAKE_BUILD_TYPE)
 101   add_compile_options(-g -Werror -Wall)
 102 endif()
 103
 104 if (compiler_flag_no_address_of_packed_member)
 105   add_compile_options(-Wno-address-of-packed-member)
 106 endif()
 107
 108 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
 109 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 110
 111 set(CMAKE_C_FLAGS_RELEASE "")
 112 set(CMAKE_C_FLAGS_DEBUG "")
 113
 114 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
 115   add_compile_options(-O3 -fstack-protector -fno-common)
 116   add_compile_definitions(_FORTIFY_SOURCE=2)
 117 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 118   add_compile_options(-O0 -fstack-protector -fno-common)
 119   add_compile_definitions(CLIB_DEBUG)
 120 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 121   add_compile_options(-O0)
 122   add_compile_definitions(__COVERITY__)
 123 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 124   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 125   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 126 endif()
 127
 128 set(BUILD_TYPES release debug coverity gcov)
 129 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 130 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 131              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 132
 133 ##############################################################################
 134 # link time optimizations
 135 ##############################################################################
 136 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 137   check_ipo_supported(RESULT _result)
 138   if (_result)
 139     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 140   endif()
 141 endif()
 142
 143 if(VPP_USE_LTO)
 144   check_c_compiler_flag("-Wno-stringop-overflow"
 145                         compiler_flag_no_stringop_overflow)
 146 endif()
 147 ##############################################################################
 148 # sanitizers
 149 ##############################################################################
 150
 151 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 152 set(VPP_SANITIZE_ADDR_OPTIONS
 153   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 154   CACHE
 155   STRING "Address sanitizer arguments"
 156 )
 157
 158 if (VPP_ENABLE_SANITIZE_ADDR)
 159   add_compile_options(-fsanitize=address)
 160   add_link_options(-fsanitize=address)
 161 endif (VPP_ENABLE_SANITIZE_ADDR)
 162
 163 ##############################################################################
 164 # trajectory trace
 165 ##############################################################################
 166
 167 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 168 if(VPP_ENABLE_TRAJECTORY_TRACE)
 169   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 170 endif()
 171
 172 ##############################################################################
 173 # unittest with clang ode coverage
 174 ##############################################################################
 175
 176 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 177   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 178 endif()
 179
 180 ##############################################################################
 181 # install config
 182 ##############################################################################
 183 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 184 if(VPP_SET_RPATH)
 185   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 186 endif()
 187 set(CMAKE_INSTALL_MESSAGE NEVER)
 188
 189 include_directories (
 190         ${CMAKE_SOURCE_DIR}
 191         ${VPP_BINARY_DIR}
 192 )
 193 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 194
 195 set(THREADS_PREFER_PTHREAD_FLAG ON)
 196 find_package(Threads REQUIRED)
 197
 198 include(cmake/syscall.cmake)
 199 include(cmake/api.cmake)
 200 include(cmake/library.cmake)
 201 include(cmake/exec.cmake)
 202 include(cmake/plugin.cmake)
 203
 204 ##############################################################################
 205 # subdirs - order matters
 206 ##############################################################################
 207 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 208 if(VPP_HOST_TOOLS_ONLY)
 209   set(SUBDIRS tools/vppapigen cmake)
 210 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 211   find_package(OpenSSL)
 212   set(SUBDIRS
 213     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 214     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 215     tools/appimage
 216   )
 217 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 218   set(SUBDIRS vppinfra)
 219 else()
 220   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 221 endif()
 222
 223 foreach(DIR ${SUBDIRS})
 224   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 225 endforeach()
 226
 227 ##############################################################################
 228 # detect if we are inside git repo and add configure dependency
 229 ##############################################################################
 230 execute_process(
 231   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 232   COMMAND git rev-parse --show-toplevel
 233   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 234   OUTPUT_STRIP_TRAILING_WHITESPACE
 235   ERROR_QUIET
 236 )
 237
 238 if (VPP_GIT_TOPLEVEL_DIR)
 239   set_property(
 240     DIRECTORY APPEND PROPERTY
 241     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 242   )
 243 endif()
 244
 245 ##############################################################################
 246 # custom targets
 247 ##############################################################################
 248
 249 add_custom_target(run
 250   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 251   COMMENT "Starting VPP..."
 252   USES_TERMINAL
 253 )
 254
 255 add_custom_target(debug
 256   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 257   COMMENT "Starting VPP in the debugger..."
 258   USES_TERMINAL
 259 )
 260
 261 add_custom_target(config
 262   COMMAND ccmake ${CMAKE_BINARY_DIR}
 263   COMMENT "Starting Configuration TUI..."
 264   USES_TERMINAL
 265 )
 266
 267 foreach(bt ${BUILD_TYPES})
 268   add_custom_target(set-build-type-${bt}
 269     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 270     COMMENT "Changing build type to ${bt}"
 271     USES_TERMINAL
 272   )
 273 endforeach()
 274
 275 mark_as_advanced(CLEAR
 276   CMAKE_C_FLAGS
 277   CMAKE_C_COMPILER
 278   CMAKE_EXPORT_COMPILE_COMMANDS
 279   CMAKE_INSTALL_PREFIX
 280   CMAKE_LINKER
 281   CMAKE_SHARED_LINKER_FLAGS
 282   CMAKE_VERBOSE_MAKEFILE
 283 )
 284
 285 ##############################################################################
 286 # print configuration
 287 ##############################################################################
 288 message(STATUS "Configuration:")
 289 pr("VPP version" ${VPP_VERSION})
 290 pr("VPP library version" ${VPP_LIB_VERSION})
 291 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 292 pr("Build type" ${CMAKE_BUILD_TYPE})
 293 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 294 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 295 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 296 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 297 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 298 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 299 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 300 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 301 pr("Library dir" ${VPP_LIBRARY_DIR})
 302 pr("Multiarch variants" ${MARCH_VARIANTS_NAMES})