src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-13
  18   clang-12
  19   clang-11
  20   clang-10
  21   clang-9
  22   gcc-10
  23   gcc-9
  24   cc
  25 )
  26
  27 project(vpp C)
  28
  29 if(CMAKE_VERSION VERSION_LESS 3.12)
  30   macro(add_compile_definitions defs)
  31     foreach(d ${defs})
  32       add_compile_options(-D${d})
  33     endforeach()
  34   endmacro()
  35 endif()
  36
  37 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  38   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  39 endif()
  40
  41 include(CheckCCompilerFlag)
  42 include(CheckIPOSupported)
  43 include(GNUInstallDirs)
  44 include(cmake/misc.cmake)
  45 include(cmake/cpu.cmake)
  46 include(cmake/ccache.cmake)
  47
  48 ##############################################################################
  49 # VPP Version
  50 ##############################################################################
  51 execute_process(
  52   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  53   COMMAND scripts/version
  54   OUTPUT_VARIABLE VPP_VERSION
  55   OUTPUT_STRIP_TRAILING_WHITESPACE
  56 )
  57 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  58 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  59
  60 ##############################################################################
  61 # cross compiling
  62 ##############################################################################
  63 if(CMAKE_CROSSCOMPILING)
  64   set(CMAKE_IGNORE_PATH
  65     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  66     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  67   )
  68 endif()
  69 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  70
  71 ##############################################################################
  72 # build config
  73 ##############################################################################
  74 check_c_compiler_flag("-Wno-address-of-packed-member"
  75                       compiler_flag_no_address_of_packed_member)
  76 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  77 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  78
  79 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  80 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  81 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  82 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFile/__pycache__)
  83
  84 if (CMAKE_BUILD_TYPE)
  85   add_compile_options(-g -fPIC -Werror -Wall)
  86 endif()
  87
  88 if (compiler_flag_no_address_of_packed_member)
  89   add_compile_options(-Wno-address-of-packed-member)
  90 endif()
  91
  92 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  93 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  94
  95 set(CMAKE_C_FLAGS_RELEASE "")
  96 set(CMAKE_C_FLAGS_DEBUG "")
  97
  98 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  99   add_compile_options(-O3 -fstack-protector -fno-common)
 100   add_compile_definitions(_FORTIFY_SOURCE=2)
 101   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
 102 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 103   add_compile_options(-O0 -fstack-protector -fno-common)
 104   add_compile_definitions(CLIB_DEBUG)
 105 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 106   add_compile_options(-O0)
 107   add_compile_definitions(__COVERITY__)
 108 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 109   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 110   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 111 endif()
 112
 113 set(BUILD_TYPES release debug coverity gcov)
 114 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 115 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 116              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 117
 118 ##############################################################################
 119 # link time optimizations
 120 ##############################################################################
 121 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 122   check_ipo_supported(RESULT _result)
 123   if (_result)
 124     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 125   endif()
 126 endif()
 127
 128 if(VPP_USE_LTO)
 129   check_c_compiler_flag("-Wno-stringop-overflow"
 130                         compiler_flag_no_stringop_overflow)
 131 endif()
 132 ##############################################################################
 133 # sanitizers
 134 ##############################################################################
 135
 136 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 137 set(VPP_SANITIZE_ADDR_OPTIONS
 138   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 139   CACHE
 140   STRING "Address sanitizer arguments"
 141 )
 142
 143 if (VPP_ENABLE_SANITIZE_ADDR)
 144   add_compile_options(-fsanitize=address)
 145   add_compile_definitions(CLIB_SANITIZE_ADDR)
 146   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 147   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 148 endif (VPP_ENABLE_SANITIZE_ADDR)
 149
 150 ##############################################################################
 151 # trajectory trace
 152 ##############################################################################
 153
 154 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 155 if(VPP_ENABLE_TRAJECTORY_TRACE)
 156   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 157 endif()
 158
 159 ##############################################################################
 160 # install config
 161 ##############################################################################
 162 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 163 if(VPP_SET_RPATH)
 164   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 165 endif()
 166 set(CMAKE_INSTALL_MESSAGE NEVER)
 167
 168 include_directories (
 169         ${CMAKE_SOURCE_DIR}
 170         ${VPP_BINARY_DIR}
 171 )
 172 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 173
 174 set(THREADS_PREFER_PTHREAD_FLAG ON)
 175 find_package(Threads REQUIRED)
 176
 177 include(cmake/syscall.cmake)
 178 include(cmake/api.cmake)
 179 include(cmake/library.cmake)
 180 include(cmake/exec.cmake)
 181 include(cmake/plugin.cmake)
 182
 183 ##############################################################################
 184 # subdirs - order matters
 185 ##############################################################################
 186 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 187 if(VPP_HOST_TOOLS_ONLY)
 188   set(SUBDIRS tools/vppapigen cmake)
 189 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 190   find_package(OpenSSL)
 191   set(SUBDIRS
 192     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 193     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 194     tools/appimage
 195   )
 196 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 197   set(SUBDIRS vppinfra)
 198 else()
 199   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 200 endif()
 201
 202 foreach(DIR ${SUBDIRS})
 203   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 204 endforeach()
 205
 206 ##############################################################################
 207 # detect if we are inside git repo and add configure dependency
 208 ##############################################################################
 209 execute_process(
 210   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 211   COMMAND git rev-parse --show-toplevel
 212   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 213   OUTPUT_STRIP_TRAILING_WHITESPACE
 214   ERROR_QUIET
 215 )
 216
 217 if (VPP_GIT_TOPLEVEL_DIR)
 218   set_property(
 219     DIRECTORY APPEND PROPERTY
 220     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 221   )
 222 endif()
 223
 224 ##############################################################################
 225 # custom targets
 226 ##############################################################################
 227
 228 add_custom_target(run
 229   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 230   COMMENT "Starting VPP..."
 231   USES_TERMINAL
 232 )
 233
 234 add_custom_target(debug
 235   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 236   COMMENT "Starting VPP in the debugger..."
 237   USES_TERMINAL
 238 )
 239
 240 add_custom_target(config
 241   COMMAND ccmake ${CMAKE_BINARY_DIR}
 242   COMMENT "Starting Configuration TUI..."
 243   USES_TERMINAL
 244 )
 245
 246 foreach(bt ${BUILD_TYPES})
 247   add_custom_target(set-build-type-${bt}
 248     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 249     COMMENT "Changing build type to ${bt}"
 250     USES_TERMINAL
 251   )
 252 endforeach()
 253
 254 mark_as_advanced(CLEAR
 255   CMAKE_C_FLAGS
 256   CMAKE_C_COMPILER
 257   CMAKE_EXPORT_COMPILE_COMMANDS
 258   CMAKE_INSTALL_PREFIX
 259   CMAKE_LINKER
 260   CMAKE_SHARED_LINKER_FLAGS
 261   CMAKE_VERBOSE_MAKEFILE
 262 )
 263
 264 ##############################################################################
 265 # print configuration
 266 ##############################################################################
 267 message(STATUS "Configuration:")
 268 pr("VPP version" ${VPP_VERSION})
 269 pr("VPP library version" ${VPP_LIB_VERSION})
 270 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 271 pr("Build type" ${CMAKE_BUILD_TYPE})
 272 pr("C compiler" ${CMAKE_C_COMPILER})
 273 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 274 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 275 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 276 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 277 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 278 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 279 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 280 pr("Library dir" ${VPP_LIBRARY_DIR})