src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-13
  18   clang-12
  19   clang-11
  20   clang-10
  21   clang-9
  22   gcc-10
  23   gcc-9
  24   cc
  25 )
  26
  27 project(vpp C)
  28
  29 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  30   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  31 endif()
  32
  33 include(CheckCCompilerFlag)
  34 include(CheckIPOSupported)
  35 include(GNUInstallDirs)
  36 include(cmake/misc.cmake)
  37 include(cmake/cpu.cmake)
  38 include(cmake/ccache.cmake)
  39
  40 ##############################################################################
  41 # VPP Version
  42 ##############################################################################
  43 execute_process(
  44   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  45   COMMAND scripts/version
  46   OUTPUT_VARIABLE VPP_VERSION
  47   OUTPUT_STRIP_TRAILING_WHITESPACE
  48 )
  49 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  50 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  51
  52 ##############################################################################
  53 # cross compiling
  54 ##############################################################################
  55 if(CMAKE_CROSSCOMPILING)
  56   set(CMAKE_IGNORE_PATH
  57     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  58     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  59   )
  60 endif()
  61 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  62
  63 ##############################################################################
  64 # build config
  65 ##############################################################################
  66 check_c_compiler_flag("-Wno-address-of-packed-member"
  67                       compiler_flag_no_address_of_packed_member)
  68 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  69 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  70
  71 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  72 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  73 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  74 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFile/__pycache__)
  75
  76 if (CMAKE_BUILD_TYPE)
  77   add_compile_options(-g -fPIC -Werror -Wall)
  78 endif()
  79
  80 if (compiler_flag_no_address_of_packed_member)
  81   add_compile_options(-Wno-address-of-packed-member)
  82 endif()
  83
  84 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  85 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  86
  87 set(CMAKE_C_FLAGS_RELEASE "")
  88 set(CMAKE_C_FLAGS_DEBUG "")
  89
  90 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  91   add_compile_options(-O3 -fstack-protector -fno-common)
  92   add_compile_definitions(_FORTIFY_SOURCE=2)
  93   add_link_options("-pie")
  94 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
  95   add_compile_options(-O0 -fstack-protector -fno-common)
  96   add_compile_definitions(CLIB_DEBUG)
  97 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
  98   add_compile_options(-O0)
  99   add_compile_definitions(__COVERITY__)
 100 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 101   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 102   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 103 endif()
 104
 105 set(BUILD_TYPES release debug coverity gcov)
 106 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 107 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 108              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 109
 110 ##############################################################################
 111 # link time optimizations
 112 ##############################################################################
 113 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 114   check_ipo_supported(RESULT _result)
 115   if (_result)
 116     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 117   endif()
 118 endif()
 119
 120 if(VPP_USE_LTO)
 121   check_c_compiler_flag("-Wno-stringop-overflow"
 122                         compiler_flag_no_stringop_overflow)
 123 endif()
 124 ##############################################################################
 125 # sanitizers
 126 ##############################################################################
 127
 128 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 129 set(VPP_SANITIZE_ADDR_OPTIONS
 130   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 131   CACHE
 132   STRING "Address sanitizer arguments"
 133 )
 134
 135 if (VPP_ENABLE_SANITIZE_ADDR)
 136   add_compile_options(-fsanitize=address)
 137   add_compile_definitions(CLIB_SANITIZE_ADDR)
 138   add_link_options(-fsanitize=address)
 139 endif (VPP_ENABLE_SANITIZE_ADDR)
 140
 141 ##############################################################################
 142 # trajectory trace
 143 ##############################################################################
 144
 145 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 146 if(VPP_ENABLE_TRAJECTORY_TRACE)
 147   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 148 endif()
 149
 150 ##############################################################################
 151 # unittest with clang ode coverage
 152 ##############################################################################
 153
 154 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 155   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 156 endif()
 157
 158 ##############################################################################
 159 # install config
 160 ##############################################################################
 161 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 162 if(VPP_SET_RPATH)
 163   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 164 endif()
 165 set(CMAKE_INSTALL_MESSAGE NEVER)
 166
 167 include_directories (
 168         ${CMAKE_SOURCE_DIR}
 169         ${VPP_BINARY_DIR}
 170 )
 171 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 172
 173 set(THREADS_PREFER_PTHREAD_FLAG ON)
 174 find_package(Threads REQUIRED)
 175
 176 include(cmake/syscall.cmake)
 177 include(cmake/api.cmake)
 178 include(cmake/library.cmake)
 179 include(cmake/exec.cmake)
 180 include(cmake/plugin.cmake)
 181
 182 ##############################################################################
 183 # subdirs - order matters
 184 ##############################################################################
 185 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 186 if(VPP_HOST_TOOLS_ONLY)
 187   set(SUBDIRS tools/vppapigen cmake)
 188 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 189   find_package(OpenSSL)
 190   set(SUBDIRS
 191     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 192     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 193     tools/appimage
 194   )
 195 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 196   set(SUBDIRS vppinfra)
 197 else()
 198   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 199 endif()
 200
 201 foreach(DIR ${SUBDIRS})
 202   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 203 endforeach()
 204
 205 ##############################################################################
 206 # detect if we are inside git repo and add configure dependency
 207 ##############################################################################
 208 execute_process(
 209   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 210   COMMAND git rev-parse --show-toplevel
 211   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 212   OUTPUT_STRIP_TRAILING_WHITESPACE
 213   ERROR_QUIET
 214 )
 215
 216 if (VPP_GIT_TOPLEVEL_DIR)
 217   set_property(
 218     DIRECTORY APPEND PROPERTY
 219     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 220   )
 221 endif()
 222
 223 ##############################################################################
 224 # custom targets
 225 ##############################################################################
 226
 227 add_custom_target(run
 228   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 229   COMMENT "Starting VPP..."
 230   USES_TERMINAL
 231 )
 232
 233 add_custom_target(debug
 234   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 235   COMMENT "Starting VPP in the debugger..."
 236   USES_TERMINAL
 237 )
 238
 239 add_custom_target(config
 240   COMMAND ccmake ${CMAKE_BINARY_DIR}
 241   COMMENT "Starting Configuration TUI..."
 242   USES_TERMINAL
 243 )
 244
 245 foreach(bt ${BUILD_TYPES})
 246   add_custom_target(set-build-type-${bt}
 247     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 248     COMMENT "Changing build type to ${bt}"
 249     USES_TERMINAL
 250   )
 251 endforeach()
 252
 253 mark_as_advanced(CLEAR
 254   CMAKE_C_FLAGS
 255   CMAKE_C_COMPILER
 256   CMAKE_EXPORT_COMPILE_COMMANDS
 257   CMAKE_INSTALL_PREFIX
 258   CMAKE_LINKER
 259   CMAKE_SHARED_LINKER_FLAGS
 260   CMAKE_VERBOSE_MAKEFILE
 261 )
 262
 263 ##############################################################################
 264 # print configuration
 265 ##############################################################################
 266 message(STATUS "Configuration:")
 267 pr("VPP version" ${VPP_VERSION})
 268 pr("VPP library version" ${VPP_LIB_VERSION})
 269 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 270 pr("Build type" ${CMAKE_BUILD_TYPE})
 271 pr("C compiler" ${CMAKE_C_COMPILER})
 272 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 273 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 274 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 275 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 276 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 277 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 278 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 279 pr("Library dir" ${VPP_LIBRARY_DIR})