src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-12
  18   clang-11
  19   clang-10
  20   clang-9
  21   gcc-10
  22   gcc-9
  23   cc
  24 )
  25
  26 project(vpp C)
  27
  28 if(CMAKE_VERSION VERSION_LESS 3.12)
  29   macro(add_compile_definitions defs)
  30     foreach(d ${defs})
  31       add_compile_options(-D${d})
  32     endforeach()
  33   endmacro()
  34 endif()
  35
  36 include(CheckCCompilerFlag)
  37 include(CheckIPOSupported)
  38 include(cmake/misc.cmake)
  39 include(cmake/cpu.cmake)
  40 include(cmake/ccache.cmake)
  41
  42 ##############################################################################
  43 # VPP Version
  44 ##############################################################################
  45 execute_process(
  46   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  47   COMMAND scripts/version
  48   OUTPUT_VARIABLE VPP_VERSION
  49   OUTPUT_STRIP_TRAILING_WHITESPACE
  50 )
  51 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  52 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  53
  54 ##############################################################################
  55 # cross compiling
  56 ##############################################################################
  57 if(CMAKE_CROSSCOMPILING)
  58   set(CMAKE_IGNORE_PATH
  59     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  60     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  61   )
  62 endif()
  63 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  64
  65 ##############################################################################
  66 # build config
  67 ##############################################################################
  68 check_c_compiler_flag("-Wno-address-of-packed-member"
  69                       compiler_flag_no_address_of_packed_member)
  70 set(VPP_RUNTIME_DIR "bin" CACHE STRING "Relative runtime directory path")
  71 set(VPP_LIBRARY_DIR "lib" CACHE STRING "Relative library directory path")
  72
  73 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  74 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  75 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  76 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFile/__pycache__)
  77
  78 if (CMAKE_BUILD_TYPE)
  79   add_compile_options(-g -fPIC -Werror -Wall)
  80 endif()
  81
  82 if (compiler_flag_no_address_of_packed_member)
  83   add_compile_options(-Wno-address-of-packed-member)
  84 endif()
  85
  86 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  87 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  88
  89 set(CMAKE_C_FLAGS_RELEASE "")
  90 set(CMAKE_C_FLAGS_DEBUG "")
  91
  92 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  93   add_compile_options(-O3 -fstack-protector -fno-common)
  94   add_compile_definitions(_FORTIFY_SOURCE=2)
  95   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  96 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
  97   add_compile_options(-O0 -fstack-protector -fno-common)
  98   add_compile_definitions(CLIB_DEBUG)
  99 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 100   add_compile_options(-O0)
 101   add_compile_definitions(__COVERITY__)
 102 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 103   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 104   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 105 endif()
 106
 107 set(BUILD_TYPES release debug coverity gcov)
 108 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 109 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 110              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 111
 112 ##############################################################################
 113 # link time optimizations
 114 ##############################################################################
 115 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 116   check_ipo_supported(RESULT _result)
 117   if (_result)
 118     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 119   endif()
 120 endif()
 121
 122 ##############################################################################
 123 # sanitizers
 124 ##############################################################################
 125
 126 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 127 set(VPP_SANITIZE_ADDR_OPTIONS
 128   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 129   CACHE
 130   STRING "Address sanitizer arguments"
 131 )
 132
 133 if (VPP_ENABLE_SANITIZE_ADDR)
 134   add_compile_options(-fsanitize=address)
 135   add_compile_definitions(CLIB_SANITIZE_ADDR)
 136   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 137   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 138 endif (VPP_ENABLE_SANITIZE_ADDR)
 139
 140 ##############################################################################
 141 # trajectory trace
 142 ##############################################################################
 143
 144 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 145 if(VPP_ENABLE_TRAJECTORY_TRACE)
 146   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 147 endif()
 148
 149 ##############################################################################
 150 # install config
 151 ##############################################################################
 152 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 153 if(VPP_SET_RPATH)
 154   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 155 endif()
 156 set(CMAKE_INSTALL_MESSAGE NEVER)
 157
 158 include_directories (
 159         ${CMAKE_SOURCE_DIR}
 160         ${VPP_BINARY_DIR}
 161 )
 162 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 163
 164 set(THREADS_PREFER_PTHREAD_FLAG ON)
 165 find_package(Threads REQUIRED)
 166
 167 include(cmake/syscall.cmake)
 168 include(cmake/api.cmake)
 169 include(cmake/library.cmake)
 170 include(cmake/exec.cmake)
 171 include(cmake/plugin.cmake)
 172
 173 ##############################################################################
 174 # subdirs - order matters
 175 ##############################################################################
 176 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 177 if(VPP_HOST_TOOLS_ONLY)
 178   set(SUBDIRS tools/vppapigen cmake)
 179 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 180   find_package(OpenSSL)
 181   set(SUBDIRS
 182     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl plugins
 183     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 184     tools/appimage
 185   )
 186 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 187   set(SUBDIRS vppinfra)
 188 else()
 189   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 190 endif()
 191
 192 foreach(DIR ${SUBDIRS})
 193   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 194 endforeach()
 195
 196 ##############################################################################
 197 # detect if we are inside git repo and add configure dependency
 198 ##############################################################################
 199 execute_process(
 200   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 201   COMMAND git rev-parse --show-toplevel
 202   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 203   OUTPUT_STRIP_TRAILING_WHITESPACE
 204   ERROR_QUIET
 205 )
 206
 207 if (VPP_GIT_TOPLEVEL_DIR)
 208   set_property(
 209     DIRECTORY APPEND PROPERTY
 210     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 211   )
 212 endif()
 213
 214 ##############################################################################
 215 # custom targets
 216 ##############################################################################
 217
 218 add_custom_target(run
 219   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 220   COMMENT "Starting VPP..."
 221   USES_TERMINAL
 222 )
 223
 224 add_custom_target(debug
 225   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 226   COMMENT "Starting VPP in the debugger..."
 227   USES_TERMINAL
 228 )
 229
 230 add_custom_target(config
 231   COMMAND ccmake ${CMAKE_BINARY_DIR}
 232   COMMENT "Starting Configuration TUI..."
 233   USES_TERMINAL
 234 )
 235
 236 foreach(bt ${BUILD_TYPES})
 237   add_custom_target(set-build-type-${bt}
 238     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 239     COMMENT "Changing build type to ${bt}"
 240     USES_TERMINAL
 241   )
 242 endforeach()
 243
 244 mark_as_advanced(CLEAR
 245   CMAKE_C_FLAGS
 246   CMAKE_C_COMPILER
 247   CMAKE_EXPORT_COMPILE_COMMANDS
 248   CMAKE_INSTALL_PREFIX
 249   CMAKE_LINKER
 250   CMAKE_SHARED_LINKER_FLAGS
 251   CMAKE_VERBOSE_MAKEFILE
 252 )
 253
 254 ##############################################################################
 255 # print configuration
 256 ##############################################################################
 257 message(STATUS "Configuration:")
 258 pr("VPP version" ${VPP_VERSION})
 259 pr("VPP library version" ${VPP_LIB_VERSION})
 260 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 261 pr("Build type" ${CMAKE_BUILD_TYPE})
 262 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 263 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 264 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 265 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 266 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 267 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 268 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})