src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES clang-11 clang-10 clang-9 gcc-10 gcc-9 cc)
  17
  18 project(vpp C)
  19
  20 include(CheckCCompilerFlag)
  21 include(CheckIPOSupported)
  22 include(cmake/misc.cmake)
  23 include(cmake/cpu.cmake)
  24 include(cmake/ccache.cmake)
  25
  26 ##############################################################################
  27 # VPP Version
  28 ##############################################################################
  29 execute_process(
  30   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  31   COMMAND scripts/version
  32   OUTPUT_VARIABLE VPP_VERSION
  33   OUTPUT_STRIP_TRAILING_WHITESPACE
  34 )
  35 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  36 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  37
  38 ##############################################################################
  39 # cross compiling
  40 ##############################################################################
  41 if(CMAKE_CROSSCOMPILING)
  42   set(CMAKE_IGNORE_PATH
  43     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  44     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  45   )
  46 endif()
  47 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  48
  49 ##############################################################################
  50 # build config
  51 ##############################################################################
  52 check_c_compiler_flag("-Wno-address-of-packed-member"
  53                       compiler_flag_no_address_of_packed_member)
  54 set(VPP_RUNTIME_DIR "bin" CACHE STRING "Relative runtime directory path")
  55 set(VPP_LIBRARY_DIR "lib" CACHE STRING "Relative library directory path")
  56
  57 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  58 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  59
  60 if (CMAKE_BUILD_TYPE)
  61   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  62 endif()
  63
  64 if (compiler_flag_no_address_of_packed_member)
  65   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  66 endif()
  67
  68 # release
  69 list(APPEND BUILD_TYPES "release")
  70 string(CONCAT CMAKE_C_FLAGS_RELEASE
  71   "-O2 "
  72   "-fstack-protector "
  73   "-D_FORTIFY_SOURCE=2 "
  74   "-fno-common "
  75 )
  76
  77 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  78
  79 # debug
  80 list(APPEND BUILD_TYPES "debug")
  81 string(CONCAT CMAKE_C_FLAGS_DEBUG
  82   "-O0 "
  83   "-DCLIB_DEBUG "
  84   "-fstack-protector "
  85   "-fno-common "
  86 )
  87
  88 # coverity
  89 list(APPEND BUILD_TYPES "coverity")
  90 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
  91
  92 # gcov
  93 list(APPEND BUILD_TYPES "gcov")
  94 string(CONCAT CMAKE_C_FLAGS_GCOV
  95   "-O0 "
  96   "-DCLIB_DEBUG "
  97   "-DCLIB_GCOV "
  98   "-fprofile-arcs "
  99   "-ftest-coverage ")
 100
 101 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 102
 103
 104 string(REPLACE ";" " " BUILD_TYPES "${BUILD_TYPES}")
 105 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 106              HELPSTRING "Build type - valid options are: ${BUILD_TYPES}")
 107
 108 ##############################################################################
 109 # link time optimizations
 110 ##############################################################################
 111 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 112   check_ipo_supported(RESULT _result)
 113   if (_result)
 114     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 115   endif()
 116 endif()
 117
 118 ##############################################################################
 119 # sanitizers
 120 ##############################################################################
 121
 122 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 123 set(VPP_SANITIZE_ADDR_OPTIONS
 124   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 125   CACHE
 126   STRING "Address sanitizer arguments"
 127 )
 128
 129 if (VPP_ENABLE_SANITIZE_ADDR)
 130   set(CMAKE_C_FLAGS "-fsanitize=address -DCLIB_SANITIZE_ADDR ${CMAKE_C_FLAGS}")
 131   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 132   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 133 endif (VPP_ENABLE_SANITIZE_ADDR)
 134
 135 ##############################################################################
 136 # install config
 137 ##############################################################################
 138 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 139 if(VPP_SET_RPATH)
 140   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 141 endif()
 142 set(CMAKE_INSTALL_MESSAGE NEVER)
 143
 144 include_directories (
 145         ${CMAKE_SOURCE_DIR}
 146         ${CMAKE_BINARY_DIR}
 147         ${CMAKE_BINARY_DIR}/include
 148 )
 149 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 150
 151 set(THREADS_PREFER_PTHREAD_FLAG ON)
 152 find_package(Threads REQUIRED)
 153
 154 include(cmake/syscall.cmake)
 155 include(cmake/api.cmake)
 156 include(cmake/library.cmake)
 157 include(cmake/exec.cmake)
 158 include(cmake/plugin.cmake)
 159
 160 ##############################################################################
 161 # subdirs - order matters
 162 ##############################################################################
 163 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 164 if(VPP_HOST_TOOLS_ONLY)
 165   set(SUBDIRS tools/vppapigen cmake)
 166 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 167   find_package(OpenSSL REQUIRED)
 168   set(SUBDIRS
 169     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl plugins
 170     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 171     tools/appimage
 172   )
 173 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 174   set(SUBDIRS vppinfra)
 175 else()
 176   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 177 endif()
 178
 179 foreach(DIR ${SUBDIRS})
 180   add_subdirectory(${DIR})
 181 endforeach()
 182
 183 ##############################################################################
 184 # detect if we are inside git repo and add configure dependency
 185 ##############################################################################
 186 execute_process(
 187   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 188   COMMAND git rev-parse --show-toplevel
 189   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 190   OUTPUT_STRIP_TRAILING_WHITESPACE
 191   ERROR_QUIET
 192 )
 193
 194 if (VPP_GIT_TOPLEVEL_DIR)
 195   set_property(
 196     DIRECTORY APPEND PROPERTY
 197     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 198   )
 199 endif()
 200
 201 ##############################################################################
 202 # print configuration
 203 ##############################################################################
 204 message(STATUS "Configuration:")
 205 pr("VPP version" "${VPP_VERSION}")
 206 pr("VPP library version" "${VPP_LIB_VERSION}")
 207 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 208 pr("Build type" "${CMAKE_BUILD_TYPE}")
 209 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 210 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 211 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 212 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 213 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 214 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 215 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")