src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 set(CMAKE_C_COMPILER_NAMES clang gcc cc)
  17
  18 project(vpp C)
  19
  20 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  21   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  22 endif()
  23
  24 include(CheckCCompilerFlag)
  25 include(CheckIPOSupported)
  26 include(GNUInstallDirs)
  27 include(cmake/misc.cmake)
  28 include(cmake/cpu.cmake)
  29 include(cmake/ccache.cmake)
  30
  31 ##############################################################################
  32 # VPP Version
  33 ##############################################################################
  34 execute_process(
  35   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  36   COMMAND scripts/version
  37   OUTPUT_VARIABLE VPP_VERSION
  38   OUTPUT_STRIP_TRAILING_WHITESPACE
  39 )
  40 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  41 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  42
  43 ##############################################################################
  44 # compiler specifics
  45 ##############################################################################
  46
  47 set(MIN_SUPPORTED_CLANG_C_COMPILER_VERSION 9.0.0)
  48 set(MIN_SUPPORTED_GNU_C_COMPILER_VERSION 9.0.0)
  49
  50 if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
  51   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_CLANG_C_COMPILER_VERSION)
  52     set(COMPILER_TOO_OLD TRUE)
  53   endif()
  54 elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU")
  55   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_GNU_C_COMPILER_VERSION)
  56     set(COMPILER_TOO_OLD TRUE)
  57   endif()
  58   set(GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION 10.0.0)
  59   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION)
  60     add_compile_options(-Wno-stringop-overflow)
  61   endif()
  62   set(GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION 12.0.0)
  63   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION)
  64     add_compile_options(-Wno-stringop-overread)
  65   endif()
  66   set(GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION 12.0.0)
  67   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION)
  68     add_compile_options(-Wno-array-bounds)
  69   endif()
  70 else()
  71   message(WARNING "WARNING: Unsupported C compiler `${CMAKE_C_COMPILER_ID}` is used")
  72   set (PRINT_MIN_C_COMPILER_VER TRUE)
  73 endif()
  74 if (COMPILER_TOO_OLD)
  75   message(WARNING "WARNING: C compiler version is too old and it's usage may result")
  76   message(WARNING "         in sub-optimal binaries or lack of support for specific CPU types.")
  77   set (PRINT_MIN_C_COMPILER_VER TRUE)
  78 endif()
  79
  80 if (PRINT_MIN_C_COMPILER_VER)
  81   string (APPEND _t "Supported C compilers are ")
  82   string (APPEND _t "Clang ${MIN_SUPPORTED_CLANG_C_COMPILER_VERSION} or higher ")
  83   string (APPEND _t "and GNU ${MIN_SUPPORTED_GNU_C_COMPILER_VERSION} or higher.")
  84   message(WARNING "         ${_t}")
  85   unset (_t)
  86 endif()
  87
  88 ##############################################################################
  89 # cross compiling
  90 ##############################################################################
  91 if(CMAKE_CROSSCOMPILING)
  92   set(CMAKE_IGNORE_PATH
  93     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  94     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  95   )
  96 endif()
  97 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  98
  99 ##############################################################################
 100 # build config
 101 ##############################################################################
 102 check_c_compiler_flag("-Wno-address-of-packed-member"
 103                       compiler_flag_no_address_of_packed_member)
 104 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
 105 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
 106
 107 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
 108 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
 109 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
 110 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
 111
 112 if (CMAKE_BUILD_TYPE)
 113   add_compile_options(-g -Werror -Wall)
 114 endif()
 115
 116 if (compiler_flag_no_address_of_packed_member)
 117   add_compile_options(-Wno-address-of-packed-member)
 118 endif()
 119
 120 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
 121 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 122
 123 set(CMAKE_C_FLAGS_RELEASE "")
 124 set(CMAKE_C_FLAGS_DEBUG "")
 125
 126 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
 127   add_compile_options(-O3 -fstack-protector -fno-common)
 128   add_compile_definitions(_FORTIFY_SOURCE=2)
 129 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 130   add_compile_options(-O0 -fstack-protector -fno-common)
 131   add_compile_definitions(CLIB_DEBUG)
 132 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 133   add_compile_options(-O0)
 134   add_compile_definitions(__COVERITY__)
 135 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 136   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 137   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 138   link_libraries(gcov)
 139 endif()
 140
 141 set(BUILD_TYPES release debug coverity gcov)
 142 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 143 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 144              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 145
 146 ##############################################################################
 147 # link time optimizations
 148 ##############################################################################
 149 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 150   check_ipo_supported(RESULT _result)
 151   if (_result)
 152     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 153   endif()
 154 endif()
 155
 156 if(VPP_USE_LTO)
 157   check_c_compiler_flag("-Wno-stringop-overflow"
 158                         compiler_flag_no_stringop_overflow)
 159 endif()
 160 ##############################################################################
 161 # sanitizers
 162 ##############################################################################
 163
 164 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 165 set(VPP_SANITIZE_ADDR_OPTIONS
 166   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 167   CACHE
 168   STRING "Address sanitizer arguments"
 169 )
 170
 171 if (VPP_ENABLE_SANITIZE_ADDR)
 172   add_compile_options(-fsanitize=address)
 173   add_link_options(-fsanitize=address)
 174 endif (VPP_ENABLE_SANITIZE_ADDR)
 175
 176 ##############################################################################
 177 # trajectory trace
 178 ##############################################################################
 179
 180 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 181 if(VPP_ENABLE_TRAJECTORY_TRACE)
 182   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 183 endif()
 184
 185 ##############################################################################
 186 # unittest with clang ode coverage
 187 ##############################################################################
 188
 189 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 190   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 191 endif()
 192
 193 ##############################################################################
 194 # install config
 195 ##############################################################################
 196 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 197 if(VPP_SET_RPATH)
 198   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 199 endif()
 200 set(CMAKE_INSTALL_MESSAGE NEVER)
 201
 202 include_directories (
 203         ${CMAKE_SOURCE_DIR}
 204         ${VPP_BINARY_DIR}
 205 )
 206 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 207
 208 set(THREADS_PREFER_PTHREAD_FLAG ON)
 209 find_package(Threads REQUIRED)
 210
 211 include(cmake/syscall.cmake)
 212 include(cmake/api.cmake)
 213 include(cmake/library.cmake)
 214 include(cmake/exec.cmake)
 215 include(cmake/plugin.cmake)
 216
 217 ##############################################################################
 218 # subdirs - order matters
 219 ##############################################################################
 220 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 221 if(VPP_HOST_TOOLS_ONLY)
 222   set(SUBDIRS tools/vppapigen cmake)
 223 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 224   find_package(OpenSSL)
 225   set(SUBDIRS
 226     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 227     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 228     tools/appimage
 229   )
 230 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 231   set(SUBDIRS vppinfra)
 232 else()
 233   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 234 endif()
 235
 236 foreach(DIR ${SUBDIRS})
 237   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 238 endforeach()
 239
 240 ##############################################################################
 241 # detect if we are inside git repo and add configure dependency
 242 ##############################################################################
 243 execute_process(
 244   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 245   COMMAND git rev-parse --show-toplevel
 246   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 247   OUTPUT_STRIP_TRAILING_WHITESPACE
 248   ERROR_QUIET
 249 )
 250
 251 if (VPP_GIT_TOPLEVEL_DIR)
 252   set_property(
 253     DIRECTORY APPEND PROPERTY
 254     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 255   )
 256 endif()
 257
 258 ##############################################################################
 259 # custom targets
 260 ##############################################################################
 261
 262 add_custom_target(run
 263   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 264   COMMENT "Starting VPP..."
 265   USES_TERMINAL
 266 )
 267
 268 add_custom_target(debug
 269   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 270   COMMENT "Starting VPP in the debugger..."
 271   USES_TERMINAL
 272 )
 273
 274 add_custom_target(config
 275   COMMAND ccmake ${CMAKE_BINARY_DIR}
 276   COMMENT "Starting Configuration TUI..."
 277   USES_TERMINAL
 278 )
 279
 280 foreach(bt ${BUILD_TYPES})
 281   add_custom_target(set-build-type-${bt}
 282     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 283     COMMENT "Changing build type to ${bt}"
 284     USES_TERMINAL
 285   )
 286 endforeach()
 287
 288 mark_as_advanced(CLEAR
 289   CMAKE_C_FLAGS
 290   CMAKE_C_COMPILER
 291   CMAKE_EXPORT_COMPILE_COMMANDS
 292   CMAKE_INSTALL_PREFIX
 293   CMAKE_LINKER
 294   CMAKE_SHARED_LINKER_FLAGS
 295   CMAKE_VERBOSE_MAKEFILE
 296 )
 297
 298 ##############################################################################
 299 # print configuration
 300 ##############################################################################
 301 message(STATUS "Configuration:")
 302 pr("VPP version" ${VPP_VERSION})
 303 pr("VPP library version" ${VPP_LIB_VERSION})
 304 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 305 pr("Build type" ${CMAKE_BUILD_TYPE})
 306 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 307 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 308 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 309 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 310 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 311 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 312 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 313 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 314 pr("Library dir" ${VPP_LIBRARY_DIR})
 315 pr("Multiarch variants" ${MARCH_VARIANTS_NAMES})