src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-13
  18   clang-12
  19   clang-11
  20   clang-10
  21   clang-9
  22   gcc-10
  23   gcc-9
  24   cc
  25 )
  26
  27 project(vpp C)
  28
  29 if(CMAKE_VERSION VERSION_LESS 3.12)
  30   macro(add_compile_definitions defs)
  31     foreach(d ${defs})
  32       add_compile_options(-D${d})
  33     endforeach()
  34   endmacro()
  35 endif()
  36
  37 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  38   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  39 endif()
  40
  41 include(CheckCCompilerFlag)
  42 include(CheckIPOSupported)
  43 include(GNUInstallDirs)
  44 include(cmake/misc.cmake)
  45 include(cmake/cpu.cmake)
  46 include(cmake/ccache.cmake)
  47
  48 ##############################################################################
  49 # VPP Version
  50 ##############################################################################
  51 execute_process(
  52   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  53   COMMAND scripts/version
  54   OUTPUT_VARIABLE VPP_VERSION
  55   OUTPUT_STRIP_TRAILING_WHITESPACE
  56 )
  57 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  58 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  59
  60 ##############################################################################
  61 # cross compiling
  62 ##############################################################################
  63 if(CMAKE_CROSSCOMPILING)
  64   set(CMAKE_IGNORE_PATH
  65     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  66     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  67   )
  68 endif()
  69 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  70
  71 ##############################################################################
  72 # build config
  73 ##############################################################################
  74 check_c_compiler_flag("-Wno-address-of-packed-member"
  75                       compiler_flag_no_address_of_packed_member)
  76 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  77 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  78
  79 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  80 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  81 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  82 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFile/__pycache__)
  83
  84 if (CMAKE_BUILD_TYPE)
  85   add_compile_options(-g -fPIC -Werror -Wall)
  86 endif()
  87
  88 if (compiler_flag_no_address_of_packed_member)
  89   add_compile_options(-Wno-address-of-packed-member)
  90 endif()
  91
  92 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  93 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  94
  95 set(CMAKE_C_FLAGS_RELEASE "")
  96 set(CMAKE_C_FLAGS_DEBUG "")
  97
  98 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  99   add_compile_options(-O3 -fstack-protector -fno-common)
 100   add_compile_definitions(_FORTIFY_SOURCE=2)
 101   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
 102 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 103   add_compile_options(-O0 -fstack-protector -fno-common)
 104   add_compile_definitions(CLIB_DEBUG)
 105 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 106   add_compile_options(-O0)
 107   add_compile_definitions(__COVERITY__)
 108 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 109   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 110   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 111 endif()
 112
 113 set(BUILD_TYPES release debug coverity gcov)
 114 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 115 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 116              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 117
 118 ##############################################################################
 119 # link time optimizations
 120 ##############################################################################
 121 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 122   check_ipo_supported(RESULT _result)
 123   if (_result)
 124     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 125   endif()
 126 endif()
 127
 128 ##############################################################################
 129 # sanitizers
 130 ##############################################################################
 131
 132 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 133 set(VPP_SANITIZE_ADDR_OPTIONS
 134   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 135   CACHE
 136   STRING "Address sanitizer arguments"
 137 )
 138
 139 if (VPP_ENABLE_SANITIZE_ADDR)
 140   add_compile_options(-fsanitize=address)
 141   add_compile_definitions(CLIB_SANITIZE_ADDR)
 142   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 143   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 144 endif (VPP_ENABLE_SANITIZE_ADDR)
 145
 146 ##############################################################################
 147 # trajectory trace
 148 ##############################################################################
 149
 150 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 151 if(VPP_ENABLE_TRAJECTORY_TRACE)
 152   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 153 endif()
 154
 155 ##############################################################################
 156 # install config
 157 ##############################################################################
 158 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 159 if(VPP_SET_RPATH)
 160   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 161 endif()
 162 set(CMAKE_INSTALL_MESSAGE NEVER)
 163
 164 include_directories (
 165         ${CMAKE_SOURCE_DIR}
 166         ${VPP_BINARY_DIR}
 167 )
 168 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 169
 170 set(THREADS_PREFER_PTHREAD_FLAG ON)
 171 find_package(Threads REQUIRED)
 172
 173 include(cmake/syscall.cmake)
 174 include(cmake/api.cmake)
 175 include(cmake/library.cmake)
 176 include(cmake/exec.cmake)
 177 include(cmake/plugin.cmake)
 178
 179 ##############################################################################
 180 # subdirs - order matters
 181 ##############################################################################
 182 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 183 if(VPP_HOST_TOOLS_ONLY)
 184   set(SUBDIRS tools/vppapigen cmake)
 185 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 186   find_package(OpenSSL)
 187   set(SUBDIRS
 188     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 189     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 190     tools/appimage
 191   )
 192 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 193   set(SUBDIRS vppinfra)
 194 else()
 195   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 196 endif()
 197
 198 foreach(DIR ${SUBDIRS})
 199   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 200 endforeach()
 201
 202 ##############################################################################
 203 # detect if we are inside git repo and add configure dependency
 204 ##############################################################################
 205 execute_process(
 206   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 207   COMMAND git rev-parse --show-toplevel
 208   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 209   OUTPUT_STRIP_TRAILING_WHITESPACE
 210   ERROR_QUIET
 211 )
 212
 213 if (VPP_GIT_TOPLEVEL_DIR)
 214   set_property(
 215     DIRECTORY APPEND PROPERTY
 216     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 217   )
 218 endif()
 219
 220 ##############################################################################
 221 # custom targets
 222 ##############################################################################
 223
 224 add_custom_target(run
 225   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 226   COMMENT "Starting VPP..."
 227   USES_TERMINAL
 228 )
 229
 230 add_custom_target(debug
 231   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 232   COMMENT "Starting VPP in the debugger..."
 233   USES_TERMINAL
 234 )
 235
 236 add_custom_target(config
 237   COMMAND ccmake ${CMAKE_BINARY_DIR}
 238   COMMENT "Starting Configuration TUI..."
 239   USES_TERMINAL
 240 )
 241
 242 foreach(bt ${BUILD_TYPES})
 243   add_custom_target(set-build-type-${bt}
 244     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 245     COMMENT "Changing build type to ${bt}"
 246     USES_TERMINAL
 247   )
 248 endforeach()
 249
 250 mark_as_advanced(CLEAR
 251   CMAKE_C_FLAGS
 252   CMAKE_C_COMPILER
 253   CMAKE_EXPORT_COMPILE_COMMANDS
 254   CMAKE_INSTALL_PREFIX
 255   CMAKE_LINKER
 256   CMAKE_SHARED_LINKER_FLAGS
 257   CMAKE_VERBOSE_MAKEFILE
 258 )
 259
 260 ##############################################################################
 261 # print configuration
 262 ##############################################################################
 263 message(STATUS "Configuration:")
 264 pr("VPP version" ${VPP_VERSION})
 265 pr("VPP library version" ${VPP_LIB_VERSION})
 266 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 267 pr("Build type" ${CMAKE_BUILD_TYPE})
 268 pr("C compiler" ${CMAKE_C_COMPILER})
 269 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 270 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 271 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 272 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 273 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 274 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 275 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 276 pr("Library dir" ${VPP_LIBRARY_DIR})