src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 if(DEFINED VPP_PLATFORM AND VPP_PLATFORM STREQUAL "default")
  17   unset(VPP_PLATFORM)
  18   unset(VPP_PLATFORM CACHE)
  19   set(VPP_PLATFORM_NAME "default")
  20 elseif(DEFINED VPP_PLATFORM)
  21   set(platform_file ${CMAKE_SOURCE_DIR}/cmake/platform/${VPP_PLATFORM}.cmake)
  22   if(NOT EXISTS ${platform_file})
  23      message(FATAL_ERROR "unknown platform ${VPP_PLATFORM}")
  24   endif()
  25   include(${platform_file})
  26   set(VPP_PLATFORM_NAME ${VPP_PLATFORM})
  27 else()
  28   set(VPP_PLATFORM_NAME "default")
  29 endif()
  30
  31 if (DEFINED VPP_PLATFORM_C_COMPILER_NAMES)
  32   set(CMAKE_C_COMPILER_NAMES ${VPP_PLATFORM_C_COMPILER_NAME})
  33 else()
  34   set(CMAKE_C_COMPILER_NAMES clang gcc cc)
  35 endif()
  36
  37 project(vpp C)
  38
  39 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  40   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  41 endif()
  42
  43 include(CheckCCompilerFlag)
  44 include(CheckIPOSupported)
  45 include(GNUInstallDirs)
  46 include(cmake/misc.cmake)
  47 include(cmake/cpu.cmake)
  48 include(cmake/ccache.cmake)
  49
  50 ##############################################################################
  51 # VPP Version
  52 ##############################################################################
  53 execute_process(
  54   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  55   COMMAND scripts/version
  56   OUTPUT_VARIABLE VPP_VERSION
  57   OUTPUT_STRIP_TRAILING_WHITESPACE
  58 )
  59
  60 if (VPP_PLATFORM)
  61   set(VPP_VERSION ${VPP_VERSION}-${VPP_PLATFORM_NAME})
  62 endif()
  63
  64 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  65 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  66
  67 ##############################################################################
  68 # compiler specifics
  69 ##############################################################################
  70
  71 set(MIN_SUPPORTED_CLANG_C_COMPILER_VERSION 9.0.0)
  72 set(MIN_SUPPORTED_GNU_C_COMPILER_VERSION 9.0.0)
  73
  74 if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
  75   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_CLANG_C_COMPILER_VERSION)
  76     set(COMPILER_TOO_OLD TRUE)
  77   endif()
  78 elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU")
  79   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_GNU_C_COMPILER_VERSION)
  80     set(COMPILER_TOO_OLD TRUE)
  81   endif()
  82   set(GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION 10.0.0)
  83   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION)
  84     add_compile_options(-Wno-stringop-overflow)
  85   endif()
  86   set(GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION 12.0.0)
  87   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION)
  88     add_compile_options(-Wno-stringop-overread)
  89   endif()
  90   set(GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION 12.0.0)
  91   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION)
  92     add_compile_options(-Wno-array-bounds)
  93   endif()
  94 else()
  95   message(WARNING "WARNING: Unsupported C compiler `${CMAKE_C_COMPILER_ID}` is used")
  96   set (PRINT_MIN_C_COMPILER_VER TRUE)
  97 endif()
  98 if (COMPILER_TOO_OLD)
  99   message(WARNING "WARNING: C compiler version is too old and it's usage may result")
 100   message(WARNING "         in sub-optimal binaries or lack of support for specific CPU types.")
 101   set (PRINT_MIN_C_COMPILER_VER TRUE)
 102 endif()
 103
 104 if (PRINT_MIN_C_COMPILER_VER)
 105   string (APPEND _t "Supported C compilers are ")
 106   string (APPEND _t "Clang ${MIN_SUPPORTED_CLANG_C_COMPILER_VERSION} or higher ")
 107   string (APPEND _t "and GNU ${MIN_SUPPORTED_GNU_C_COMPILER_VERSION} or higher.")
 108   message(WARNING "         ${_t}")
 109   unset (_t)
 110 endif()
 111
 112 ##############################################################################
 113 # cross compiling
 114 ##############################################################################
 115
 116 if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 117   set(COMPILER_SUFFIX "linux-gnu")
 118 elseif (${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
 119   set(COMPILER_SUFFIX "freebsd")
 120 endif()
 121
 122 if(CMAKE_CROSSCOMPILING)
 123   set(CMAKE_IGNORE_PATH
 124     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-${COMPILER_SUFFIX}/
 125     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-${COMPILER_SUFFIX}/lib/
 126   )
 127 endif()
 128   set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-${COMPILER_SUFFIX})
 129 ##############################################################################
 130 # build config
 131 ##############################################################################
 132 check_c_compiler_flag("-Wno-address-of-packed-member"
 133                       compiler_flag_no_address_of_packed_member)
 134 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
 135 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
 136
 137 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
 138 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
 139 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
 140 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
 141
 142 if (CMAKE_BUILD_TYPE)
 143   add_compile_options(-g -Werror -Wall)
 144 endif()
 145
 146 if (compiler_flag_no_address_of_packed_member)
 147   add_compile_options(-Wno-address-of-packed-member)
 148 endif()
 149
 150 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
 151 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 152
 153 set(CMAKE_C_FLAGS_RELEASE "")
 154 set(CMAKE_C_FLAGS_DEBUG "")
 155
 156 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
 157   add_compile_options(-O3 -fstack-protector -fno-common)
 158   add_compile_definitions(_FORTIFY_SOURCE=2)
 159 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 160   add_compile_options(-O0 -fstack-protector -fno-common)
 161   add_compile_definitions(CLIB_DEBUG)
 162 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 163   add_compile_options(-O0)
 164   add_compile_definitions(__COVERITY__)
 165 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 166   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 167   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 168   link_libraries(gcov)
 169 endif()
 170
 171 set(BUILD_TYPES release debug coverity gcov)
 172 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 173 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 174              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 175
 176 ##############################################################################
 177 # link time optimizations
 178 ##############################################################################
 179 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 180   check_ipo_supported(RESULT _result)
 181   if (_result)
 182     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 183   endif()
 184 endif()
 185
 186 if(VPP_USE_LTO)
 187   check_c_compiler_flag("-Wno-stringop-overflow"
 188                         compiler_flag_no_stringop_overflow)
 189 endif()
 190 ##############################################################################
 191 # sanitizers
 192 ##############################################################################
 193
 194 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 195 set(VPP_SANITIZE_ADDR_OPTIONS
 196   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 197   CACHE
 198   STRING "Address sanitizer arguments"
 199 )
 200
 201 if (VPP_ENABLE_SANITIZE_ADDR)
 202   add_compile_options(-fsanitize=address)
 203   add_link_options(-fsanitize=address)
 204 endif (VPP_ENABLE_SANITIZE_ADDR)
 205
 206 ##############################################################################
 207 # trajectory trace
 208 ##############################################################################
 209
 210 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 211 if(VPP_ENABLE_TRAJECTORY_TRACE)
 212   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 213 endif()
 214
 215 ##############################################################################
 216 # unittest with clang code coverage
 217 ##############################################################################
 218
 219 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 220   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 221 endif()
 222
 223 ##############################################################################
 224 # install config
 225 ##############################################################################
 226 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 227 if(VPP_SET_RPATH)
 228   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 229 endif()
 230 set(CMAKE_INSTALL_MESSAGE NEVER)
 231
 232 include_directories (
 233         ${CMAKE_SOURCE_DIR}
 234         ${VPP_BINARY_DIR}
 235 )
 236 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 237
 238 set(THREADS_PREFER_PTHREAD_FLAG ON)
 239 find_package(Threads REQUIRED)
 240
 241 include(cmake/syscall.cmake)
 242 include(cmake/api.cmake)
 243 include(cmake/library.cmake)
 244 include(cmake/exec.cmake)
 245 include(cmake/plugin.cmake)
 246
 247 ##############################################################################
 248 # FreeBSD - use epoll-shim
 249 ##############################################################################
 250 set(EPOLL_LIB "")
 251 if("${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD")
 252   find_path(EPOLL_SHIM_INCLUDE_DIR NAMES sys/epoll.h HINTS /usr/local/include/libepoll-shim)
 253   find_library(EPOLL_SHIM_LIB NAMES epoll-shim HINTS /usr/local/lib)
 254
 255   if(EPOLL_SHIM_INCLUDE_DIR AND EPOLL_SHIM_LIB)
 256     message(STATUS "Found epoll-shim in ${EPOLL_SHIM_INCLUDE_DIR}")
 257     include_directories(${EPOLL_SHIM_INCLUDE_DIR})
 258     string(JOIN " " EPOLL_LIB "${EPOLL_SHIM_LIB}")
 259   endif()
 260 endif()
 261
 262 ##############################################################################
 263 # subdirs - order matters
 264 ##############################################################################
 265 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 266 if(VPP_HOST_TOOLS_ONLY)
 267   set(SUBDIRS tools/vppapigen cmake)
 268   install(
 269     PROGRAMS
 270     vpp-api/vapi/vapi_c_gen.py
 271     vpp-api/vapi/vapi_cpp_gen.py
 272     vpp-api/vapi/vapi_json_parser.py
 273     DESTINATION ${VPP_RUNTIME_DIR}
 274     COMPONENT vpp-dev
 275   )
 276 elseif(${CMAKE_SYSTEM_NAME} MATCHES "Linux|FreeBSD")
 277   find_package(OpenSSL)
 278   set(SUBDIRS
 279     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 280     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 281     tools/appimage
 282   )
 283 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 284   set(SUBDIRS vppinfra)
 285 else()
 286   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 287 endif()
 288
 289 foreach(DIR ${SUBDIRS})
 290   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 291 endforeach()
 292
 293 ##############################################################################
 294 # detect if we are inside git repo and add configure dependency
 295 ##############################################################################
 296 execute_process(
 297   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 298   COMMAND git rev-parse --show-toplevel
 299   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 300   OUTPUT_STRIP_TRAILING_WHITESPACE
 301   ERROR_QUIET
 302 )
 303
 304 if (VPP_GIT_TOPLEVEL_DIR)
 305   set_property(
 306     DIRECTORY APPEND PROPERTY
 307     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 308   )
 309 endif()
 310
 311 ##############################################################################
 312 # custom targets
 313 ##############################################################################
 314
 315 add_custom_target(run
 316   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 317   COMMENT "Starting VPP..."
 318   USES_TERMINAL
 319 )
 320
 321 add_custom_target(debug
 322   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 323   COMMENT "Starting VPP in the debugger..."
 324   USES_TERMINAL
 325 )
 326
 327 add_custom_target(config
 328   COMMAND ccmake ${CMAKE_BINARY_DIR}
 329   COMMENT "Starting Configuration TUI..."
 330   USES_TERMINAL
 331 )
 332
 333 foreach(bt ${BUILD_TYPES})
 334   add_custom_target(set-build-type-${bt}
 335     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 336     COMMENT "Changing build type to ${bt}"
 337     USES_TERMINAL
 338   )
 339 endforeach()
 340
 341 mark_as_advanced(CLEAR
 342   CMAKE_C_FLAGS
 343   CMAKE_C_COMPILER
 344   CMAKE_EXPORT_COMPILE_COMMANDS
 345   CMAKE_INSTALL_PREFIX
 346   CMAKE_LINKER
 347   CMAKE_SHARED_LINKER_FLAGS
 348   CMAKE_VERBOSE_MAKEFILE
 349 )
 350
 351 ##############################################################################
 352 # print configuration
 353 ##############################################################################
 354 message(STATUS "Configuration:")
 355 pr("VPP platform" ${VPP_PLATFORM_NAME})
 356 pr("VPP version" ${VPP_VERSION})
 357 pr("VPP library version" ${VPP_LIB_VERSION})
 358 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 359 pr("Build type" ${CMAKE_BUILD_TYPE})
 360 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 361 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 362 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 363 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 364 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 365 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 366 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 367 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 368 pr("Library dir" ${VPP_LIBRARY_DIR})
 369 pr("Multiarch variants" ${MARCH_VARIANTS_NAMES})