src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 if(DEFINED VPP_PLATFORM AND VPP_PLATFORM STREQUAL "default")
  17   unset(VPP_PLATFORM)
  18   unset(VPP_PLATFORM CACHE)
  19   set(VPP_PLATFORM_NAME "default")
  20 elseif(DEFINED VPP_PLATFORM)
  21   set(platform_file ${CMAKE_SOURCE_DIR}/cmake/platform/${VPP_PLATFORM}.cmake)
  22   if(NOT EXISTS ${platform_file})
  23      message(FATAL_ERROR "unknown platform ${VPP_PLATFORM}")
  24   endif()
  25   include(${platform_file})
  26   set(VPP_PLATFORM_NAME ${VPP_PLATFORM})
  27 else()
  28   set(VPP_PLATFORM_NAME "default")
  29 endif()
  30
  31 if (DEFINED VPP_PLATFORM_C_COMPILER_NAMES)
  32   set(CMAKE_C_COMPILER_NAMES ${VPP_PLATFORM_C_COMPILER_NAME})
  33 else()
  34   set(CMAKE_C_COMPILER_NAMES clang gcc cc)
  35 endif()
  36
  37 project(vpp C)
  38
  39 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  40   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  41 endif()
  42
  43 include(CheckCCompilerFlag)
  44 include(CheckIPOSupported)
  45 include(GNUInstallDirs)
  46 include(cmake/misc.cmake)
  47 include(cmake/cpu.cmake)
  48 include(cmake/ccache.cmake)
  49
  50 ##############################################################################
  51 # VPP Version
  52 ##############################################################################
  53 execute_process(
  54   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  55   COMMAND scripts/version
  56   OUTPUT_VARIABLE VPP_VERSION
  57   OUTPUT_STRIP_TRAILING_WHITESPACE
  58 )
  59
  60 if (VPP_PLATFORM)
  61   set(VPP_VERSION ${VPP_VERSION}-${VPP_PLATFORM_NAME})
  62 endif()
  63
  64 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  65 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  66
  67 ##############################################################################
  68 # compiler specifics
  69 ##############################################################################
  70
  71 set(MIN_SUPPORTED_CLANG_C_COMPILER_VERSION 9.0.0)
  72 set(MIN_SUPPORTED_GNU_C_COMPILER_VERSION 9.0.0)
  73
  74 if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
  75   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_CLANG_C_COMPILER_VERSION)
  76     set(COMPILER_TOO_OLD TRUE)
  77   endif()
  78 elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU")
  79   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_GNU_C_COMPILER_VERSION)
  80     set(COMPILER_TOO_OLD TRUE)
  81   endif()
  82   set(GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION 10.0.0)
  83   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION)
  84     add_compile_options(-Wno-stringop-overflow)
  85   endif()
  86   set(GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION 12.0.0)
  87   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION)
  88     add_compile_options(-Wno-stringop-overread)
  89   endif()
  90   set(GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION 12.0.0)
  91   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION)
  92     add_compile_options(-Wno-array-bounds)
  93   endif()
  94 else()
  95   message(WARNING "WARNING: Unsupported C compiler `${CMAKE_C_COMPILER_ID}` is used")
  96   set (PRINT_MIN_C_COMPILER_VER TRUE)
  97 endif()
  98 if (COMPILER_TOO_OLD)
  99   message(WARNING "WARNING: C compiler version is too old and it's usage may result")
 100   message(WARNING "         in sub-optimal binaries or lack of support for specific CPU types.")
 101   set (PRINT_MIN_C_COMPILER_VER TRUE)
 102 endif()
 103
 104 if (PRINT_MIN_C_COMPILER_VER)
 105   string (APPEND _t "Supported C compilers are ")
 106   string (APPEND _t "Clang ${MIN_SUPPORTED_CLANG_C_COMPILER_VERSION} or higher ")
 107   string (APPEND _t "and GNU ${MIN_SUPPORTED_GNU_C_COMPILER_VERSION} or higher.")
 108   message(WARNING "         ${_t}")
 109   unset (_t)
 110 endif()
 111
 112 ##############################################################################
 113 # cross compiling
 114 ##############################################################################
 115 if(CMAKE_CROSSCOMPILING)
 116   set(CMAKE_IGNORE_PATH
 117     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
 118     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
 119   )
 120 endif()
 121 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
 122
 123 ##############################################################################
 124 # build config
 125 ##############################################################################
 126 check_c_compiler_flag("-Wno-address-of-packed-member"
 127                       compiler_flag_no_address_of_packed_member)
 128 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
 129 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
 130
 131 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
 132 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
 133 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
 134 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
 135
 136 if (CMAKE_BUILD_TYPE)
 137   add_compile_options(-g -Werror -Wall)
 138 endif()
 139
 140 if (compiler_flag_no_address_of_packed_member)
 141   add_compile_options(-Wno-address-of-packed-member)
 142 endif()
 143
 144 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
 145 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 146
 147 set(CMAKE_C_FLAGS_RELEASE "")
 148 set(CMAKE_C_FLAGS_DEBUG "")
 149
 150 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
 151   add_compile_options(-O3 -fstack-protector -fno-common)
 152   add_compile_definitions(_FORTIFY_SOURCE=2)
 153 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 154   add_compile_options(-O0 -fstack-protector -fno-common)
 155   add_compile_definitions(CLIB_DEBUG)
 156 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 157   add_compile_options(-O0)
 158   add_compile_definitions(__COVERITY__)
 159 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 160   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 161   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 162   link_libraries(gcov)
 163 endif()
 164
 165 set(BUILD_TYPES release debug coverity gcov)
 166 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 167 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 168              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 169
 170 ##############################################################################
 171 # link time optimizations
 172 ##############################################################################
 173 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 174   check_ipo_supported(RESULT _result)
 175   if (_result)
 176     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 177   endif()
 178 endif()
 179
 180 if(VPP_USE_LTO)
 181   check_c_compiler_flag("-Wno-stringop-overflow"
 182                         compiler_flag_no_stringop_overflow)
 183 endif()
 184 ##############################################################################
 185 # sanitizers
 186 ##############################################################################
 187
 188 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 189 set(VPP_SANITIZE_ADDR_OPTIONS
 190   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 191   CACHE
 192   STRING "Address sanitizer arguments"
 193 )
 194
 195 if (VPP_ENABLE_SANITIZE_ADDR)
 196   add_compile_options(-fsanitize=address)
 197   add_link_options(-fsanitize=address)
 198 endif (VPP_ENABLE_SANITIZE_ADDR)
 199
 200 ##############################################################################
 201 # trajectory trace
 202 ##############################################################################
 203
 204 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 205 if(VPP_ENABLE_TRAJECTORY_TRACE)
 206   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 207 endif()
 208
 209 ##############################################################################
 210 # unittest with clang code coverage
 211 ##############################################################################
 212
 213 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 214   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 215 endif()
 216
 217 ##############################################################################
 218 # install config
 219 ##############################################################################
 220 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 221 if(VPP_SET_RPATH)
 222   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 223 endif()
 224 set(CMAKE_INSTALL_MESSAGE NEVER)
 225
 226 include_directories (
 227         ${CMAKE_SOURCE_DIR}
 228         ${VPP_BINARY_DIR}
 229 )
 230 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 231
 232 set(THREADS_PREFER_PTHREAD_FLAG ON)
 233 find_package(Threads REQUIRED)
 234
 235 include(cmake/syscall.cmake)
 236 include(cmake/api.cmake)
 237 include(cmake/library.cmake)
 238 include(cmake/exec.cmake)
 239 include(cmake/plugin.cmake)
 240
 241 ##############################################################################
 242 # subdirs - order matters
 243 ##############################################################################
 244 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 245 if(VPP_HOST_TOOLS_ONLY)
 246   set(SUBDIRS tools/vppapigen cmake)
 247   install(
 248     PROGRAMS
 249     vpp-api/vapi/vapi_c_gen.py
 250     vpp-api/vapi/vapi_cpp_gen.py
 251     vpp-api/vapi/vapi_json_parser.py
 252     DESTINATION ${VPP_RUNTIME_DIR}
 253     COMPONENT vpp-dev
 254   )
 255 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 256   find_package(OpenSSL)
 257   set(SUBDIRS
 258     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 259     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 260     tools/appimage
 261   )
 262 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 263   set(SUBDIRS vppinfra)
 264 else()
 265   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 266 endif()
 267
 268 foreach(DIR ${SUBDIRS})
 269   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 270 endforeach()
 271
 272 ##############################################################################
 273 # detect if we are inside git repo and add configure dependency
 274 ##############################################################################
 275 execute_process(
 276   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 277   COMMAND git rev-parse --show-toplevel
 278   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 279   OUTPUT_STRIP_TRAILING_WHITESPACE
 280   ERROR_QUIET
 281 )
 282
 283 if (VPP_GIT_TOPLEVEL_DIR)
 284   set_property(
 285     DIRECTORY APPEND PROPERTY
 286     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 287   )
 288 endif()
 289
 290 ##############################################################################
 291 # custom targets
 292 ##############################################################################
 293
 294 add_custom_target(run
 295   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 296   COMMENT "Starting VPP..."
 297   USES_TERMINAL
 298 )
 299
 300 add_custom_target(debug
 301   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 302   COMMENT "Starting VPP in the debugger..."
 303   USES_TERMINAL
 304 )
 305
 306 add_custom_target(config
 307   COMMAND ccmake ${CMAKE_BINARY_DIR}
 308   COMMENT "Starting Configuration TUI..."
 309   USES_TERMINAL
 310 )
 311
 312 foreach(bt ${BUILD_TYPES})
 313   add_custom_target(set-build-type-${bt}
 314     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 315     COMMENT "Changing build type to ${bt}"
 316     USES_TERMINAL
 317   )
 318 endforeach()
 319
 320 mark_as_advanced(CLEAR
 321   CMAKE_C_FLAGS
 322   CMAKE_C_COMPILER
 323   CMAKE_EXPORT_COMPILE_COMMANDS
 324   CMAKE_INSTALL_PREFIX
 325   CMAKE_LINKER
 326   CMAKE_SHARED_LINKER_FLAGS
 327   CMAKE_VERBOSE_MAKEFILE
 328 )
 329
 330 ##############################################################################
 331 # print configuration
 332 ##############################################################################
 333 message(STATUS "Configuration:")
 334 pr("VPP platform" ${VPP_PLATFORM_NAME})
 335 pr("VPP version" ${VPP_VERSION})
 336 pr("VPP library version" ${VPP_LIB_VERSION})
 337 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 338 pr("Build type" ${CMAKE_BUILD_TYPE})
 339 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 340 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 341 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 342 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 343 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 344 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 345 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 346 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 347 pr("Library dir" ${VPP_LIBRARY_DIR})
 348 pr("Multiarch variants" ${MARCH_VARIANTS_NAMES})