src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-12
  18   clang-11
  19   clang-10
  20   clang-9
  21   gcc-10
  22   gcc-9
  23   cc
  24 )
  25
  26 project(vpp C)
  27
  28 include(CheckCCompilerFlag)
  29 include(CheckIPOSupported)
  30 include(cmake/misc.cmake)
  31 include(cmake/cpu.cmake)
  32 include(cmake/ccache.cmake)
  33
  34 ##############################################################################
  35 # VPP Version
  36 ##############################################################################
  37 execute_process(
  38   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  39   COMMAND scripts/version
  40   OUTPUT_VARIABLE VPP_VERSION
  41   OUTPUT_STRIP_TRAILING_WHITESPACE
  42 )
  43 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  44 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  45
  46 ##############################################################################
  47 # cross compiling
  48 ##############################################################################
  49 if(CMAKE_CROSSCOMPILING)
  50   set(CMAKE_IGNORE_PATH
  51     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  52     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  53   )
  54 endif()
  55 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  56
  57 ##############################################################################
  58 # build config
  59 ##############################################################################
  60 check_c_compiler_flag("-Wno-address-of-packed-member"
  61                       compiler_flag_no_address_of_packed_member)
  62 set(VPP_RUNTIME_DIR "bin" CACHE STRING "Relative runtime directory path")
  63 set(VPP_LIBRARY_DIR "lib" CACHE STRING "Relative library directory path")
  64
  65 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  66 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  67 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  68
  69 if (CMAKE_BUILD_TYPE)
  70   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  71 endif()
  72
  73 if (compiler_flag_no_address_of_packed_member)
  74   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  75 endif()
  76
  77 # release
  78 list(APPEND BUILD_TYPES "release")
  79 string(CONCAT CMAKE_C_FLAGS_RELEASE
  80   "-O3 "
  81   "-fstack-protector "
  82   "-D_FORTIFY_SOURCE=2 "
  83   "-fno-common "
  84 )
  85
  86 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  87
  88 # debug
  89 list(APPEND BUILD_TYPES "debug")
  90 string(CONCAT CMAKE_C_FLAGS_DEBUG
  91   "-O0 "
  92   "-DCLIB_DEBUG "
  93   "-fstack-protector "
  94   "-fno-common "
  95 )
  96
  97 # coverity
  98 list(APPEND BUILD_TYPES "coverity")
  99 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
 100
 101 # gcov
 102 list(APPEND BUILD_TYPES "gcov")
 103 string(CONCAT CMAKE_C_FLAGS_GCOV
 104   "-O0 "
 105   "-DCLIB_DEBUG "
 106   "-DCLIB_GCOV "
 107   "-fprofile-arcs "
 108   "-ftest-coverage ")
 109
 110 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 111
 112
 113 string(REPLACE ";" " " BUILD_TYPES "${BUILD_TYPES}")
 114 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 115              HELPSTRING "Build type - valid options are: ${BUILD_TYPES}")
 116
 117 ##############################################################################
 118 # link time optimizations
 119 ##############################################################################
 120 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 121   check_ipo_supported(RESULT _result)
 122   if (_result)
 123     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 124   endif()
 125 endif()
 126
 127 ##############################################################################
 128 # sanitizers
 129 ##############################################################################
 130
 131 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 132 set(VPP_SANITIZE_ADDR_OPTIONS
 133   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 134   CACHE
 135   STRING "Address sanitizer arguments"
 136 )
 137
 138 if (VPP_ENABLE_SANITIZE_ADDR)
 139   set(CMAKE_C_FLAGS "-fsanitize=address -DCLIB_SANITIZE_ADDR ${CMAKE_C_FLAGS}")
 140   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 141   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 142 endif (VPP_ENABLE_SANITIZE_ADDR)
 143
 144 ##############################################################################
 145 # install config
 146 ##############################################################################
 147 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 148 if(VPP_SET_RPATH)
 149   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 150 endif()
 151 set(CMAKE_INSTALL_MESSAGE NEVER)
 152
 153 include_directories (
 154         ${CMAKE_SOURCE_DIR}
 155         ${VPP_BINARY_DIR}
 156 )
 157 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 158
 159 set(THREADS_PREFER_PTHREAD_FLAG ON)
 160 find_package(Threads REQUIRED)
 161
 162 include(cmake/syscall.cmake)
 163 include(cmake/api.cmake)
 164 include(cmake/library.cmake)
 165 include(cmake/exec.cmake)
 166 include(cmake/plugin.cmake)
 167
 168 ##############################################################################
 169 # subdirs - order matters
 170 ##############################################################################
 171 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 172 if(VPP_HOST_TOOLS_ONLY)
 173   set(SUBDIRS tools/vppapigen cmake)
 174 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 175   find_package(OpenSSL REQUIRED)
 176   set(SUBDIRS
 177     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl plugins
 178     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 179     tools/appimage
 180   )
 181 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 182   set(SUBDIRS vppinfra)
 183 else()
 184   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 185 endif()
 186
 187 foreach(DIR ${SUBDIRS})
 188   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 189 endforeach()
 190
 191 ##############################################################################
 192 # detect if we are inside git repo and add configure dependency
 193 ##############################################################################
 194 execute_process(
 195   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 196   COMMAND git rev-parse --show-toplevel
 197   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 198   OUTPUT_STRIP_TRAILING_WHITESPACE
 199   ERROR_QUIET
 200 )
 201
 202 if (VPP_GIT_TOPLEVEL_DIR)
 203   set_property(
 204     DIRECTORY APPEND PROPERTY
 205     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 206   )
 207 endif()
 208
 209 ##############################################################################
 210 # custom targets
 211 ##############################################################################
 212
 213 add_custom_target(run
 214   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 215   COMMENT "Starting VPP..."
 216   USES_TERMINAL
 217 )
 218
 219 add_custom_target(debug
 220   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 221   COMMENT "Starting VPP in the debugger..."
 222   USES_TERMINAL
 223 )
 224
 225 add_custom_target(menu
 226   COMMAND ccmake ${CMAKE_BINARY_DIR}
 227   COMMENT "Starting Configuration TUI..."
 228   USES_TERMINAL
 229 )
 230
 231 add_custom_target(compdb
 232   COMMAND ninja -C ${CMAKE_BINARY_DIR} -t compdb |
 233           ${CMAKE_SOURCE_DIR}/scripts/compdb_cleanup.py >
 234           ${CMAKE_BINARY_DIR}/compile_commands.json
 235   COMMENT "Generating compile_commands.json"
 236   USES_TERMINAL
 237 )
 238
 239 ##############################################################################
 240 # print configuration
 241 ##############################################################################
 242 message(STATUS "Configuration:")
 243 pr("VPP version" "${VPP_VERSION}")
 244 pr("VPP library version" "${VPP_LIB_VERSION}")
 245 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 246 pr("Build type" "${CMAKE_BUILD_TYPE}")
 247 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 248 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 249 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 250 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 251 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 252 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 253 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")