src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-13
  18   clang-12
  19   clang-11
  20   clang-10
  21   clang-9
  22   gcc-10
  23   gcc-9
  24   cc
  25 )
  26
  27 project(vpp C)
  28
  29 if(CMAKE_VERSION VERSION_LESS 3.12)
  30   macro(add_compile_definitions defs)
  31     foreach(d ${defs})
  32       add_compile_options(-D${d})
  33     endforeach()
  34   endmacro()
  35 endif()
  36
  37 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  38   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  39 endif()
  40
  41 include(CheckCCompilerFlag)
  42 include(CheckIPOSupported)
  43 include(GNUInstallDirs)
  44 include(cmake/misc.cmake)
  45 include(cmake/cpu.cmake)
  46 include(cmake/ccache.cmake)
  47
  48 ##############################################################################
  49 # VPP Version
  50 ##############################################################################
  51 execute_process(
  52   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  53   COMMAND scripts/version
  54   OUTPUT_VARIABLE VPP_VERSION
  55   OUTPUT_STRIP_TRAILING_WHITESPACE
  56 )
  57 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  58 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  59
  60 ##############################################################################
  61 # cross compiling
  62 ##############################################################################
  63 if(CMAKE_CROSSCOMPILING)
  64   set(CMAKE_IGNORE_PATH
  65     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  66     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  67   )
  68 endif()
  69 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  70
  71 ##############################################################################
  72 # build config
  73 ##############################################################################
  74 check_c_compiler_flag("-Wno-address-of-packed-member"
  75                       compiler_flag_no_address_of_packed_member)
  76 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  77 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  78
  79 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  80 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  81 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  82 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFile/__pycache__)
  83
  84 if (CMAKE_BUILD_TYPE)
  85   add_compile_options(-g -fPIC -Werror -Wall)
  86 endif()
  87
  88 if (compiler_flag_no_address_of_packed_member)
  89   add_compile_options(-Wno-address-of-packed-member)
  90 endif()
  91
  92 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  93 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  94
  95 set(CMAKE_C_FLAGS_RELEASE "")
  96 set(CMAKE_C_FLAGS_DEBUG "")
  97
  98 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  99   add_compile_options(-O3 -fstack-protector -fno-common)
 100   add_compile_definitions(_FORTIFY_SOURCE=2)
 101   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
 102 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 103   add_compile_options(-O0 -fstack-protector -fno-common)
 104   add_compile_definitions(CLIB_DEBUG)
 105 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 106   add_compile_options(-O0)
 107   add_compile_definitions(__COVERITY__)
 108 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 109   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 110   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 111 endif()
 112
 113 set(BUILD_TYPES release debug coverity gcov)
 114 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 115 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 116              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 117
 118 ##############################################################################
 119 # link time optimizations
 120 ##############################################################################
 121 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 122   check_ipo_supported(RESULT _result)
 123   if (_result)
 124     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 125   endif()
 126 endif()
 127
 128 if(VPP_USE_LTO)
 129   check_c_compiler_flag("-Wno-stringop-overflow"
 130                         compiler_flag_no_stringop_overflow)
 131 endif()
 132 ##############################################################################
 133 # sanitizers
 134 ##############################################################################
 135
 136 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 137 set(VPP_SANITIZE_ADDR_OPTIONS
 138   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 139   CACHE
 140   STRING "Address sanitizer arguments"
 141 )
 142
 143 if (VPP_ENABLE_SANITIZE_ADDR)
 144   add_compile_options(-fsanitize=address)
 145   add_compile_definitions(CLIB_SANITIZE_ADDR)
 146   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 147   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 148 endif (VPP_ENABLE_SANITIZE_ADDR)
 149
 150 ##############################################################################
 151 # trajectory trace
 152 ##############################################################################
 153
 154 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 155 if(VPP_ENABLE_TRAJECTORY_TRACE)
 156   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 157 endif()
 158
 159 ##############################################################################
 160 # unittest with clang ode coverage
 161 ##############################################################################
 162
 163 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 164   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 165 endif()
 166
 167 ##############################################################################
 168 # install config
 169 ##############################################################################
 170 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 171 if(VPP_SET_RPATH)
 172   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 173 endif()
 174 set(CMAKE_INSTALL_MESSAGE NEVER)
 175
 176 include_directories (
 177         ${CMAKE_SOURCE_DIR}
 178         ${VPP_BINARY_DIR}
 179 )
 180 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 181
 182 set(THREADS_PREFER_PTHREAD_FLAG ON)
 183 find_package(Threads REQUIRED)
 184
 185 include(cmake/syscall.cmake)
 186 include(cmake/api.cmake)
 187 include(cmake/library.cmake)
 188 include(cmake/exec.cmake)
 189 include(cmake/plugin.cmake)
 190
 191 ##############################################################################
 192 # subdirs - order matters
 193 ##############################################################################
 194 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 195 if(VPP_HOST_TOOLS_ONLY)
 196   set(SUBDIRS tools/vppapigen cmake)
 197 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 198   find_package(OpenSSL)
 199   set(SUBDIRS
 200     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 201     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 202     tools/appimage
 203   )
 204 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 205   set(SUBDIRS vppinfra)
 206 else()
 207   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 208 endif()
 209
 210 foreach(DIR ${SUBDIRS})
 211   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 212 endforeach()
 213
 214 ##############################################################################
 215 # detect if we are inside git repo and add configure dependency
 216 ##############################################################################
 217 execute_process(
 218   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 219   COMMAND git rev-parse --show-toplevel
 220   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 221   OUTPUT_STRIP_TRAILING_WHITESPACE
 222   ERROR_QUIET
 223 )
 224
 225 if (VPP_GIT_TOPLEVEL_DIR)
 226   set_property(
 227     DIRECTORY APPEND PROPERTY
 228     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 229   )
 230 endif()
 231
 232 ##############################################################################
 233 # custom targets
 234 ##############################################################################
 235
 236 add_custom_target(run
 237   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 238   COMMENT "Starting VPP..."
 239   USES_TERMINAL
 240 )
 241
 242 add_custom_target(debug
 243   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 244   COMMENT "Starting VPP in the debugger..."
 245   USES_TERMINAL
 246 )
 247
 248 add_custom_target(config
 249   COMMAND ccmake ${CMAKE_BINARY_DIR}
 250   COMMENT "Starting Configuration TUI..."
 251   USES_TERMINAL
 252 )
 253
 254 foreach(bt ${BUILD_TYPES})
 255   add_custom_target(set-build-type-${bt}
 256     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 257     COMMENT "Changing build type to ${bt}"
 258     USES_TERMINAL
 259   )
 260 endforeach()
 261
 262 mark_as_advanced(CLEAR
 263   CMAKE_C_FLAGS
 264   CMAKE_C_COMPILER
 265   CMAKE_EXPORT_COMPILE_COMMANDS
 266   CMAKE_INSTALL_PREFIX
 267   CMAKE_LINKER
 268   CMAKE_SHARED_LINKER_FLAGS
 269   CMAKE_VERBOSE_MAKEFILE
 270 )
 271
 272 ##############################################################################
 273 # print configuration
 274 ##############################################################################
 275 message(STATUS "Configuration:")
 276 pr("VPP version" ${VPP_VERSION})
 277 pr("VPP library version" ${VPP_LIB_VERSION})
 278 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 279 pr("Build type" ${CMAKE_BUILD_TYPE})
 280 pr("C compiler" ${CMAKE_C_COMPILER})
 281 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 282 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 283 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 284 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 285 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 286 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 287 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 288 pr("Library dir" ${VPP_LIBRARY_DIR})