src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-14
  18   clang-13
  19   clang-12
  20   clang-11
  21   clang-10
  22   clang-9
  23   gcc-10
  24   gcc-9
  25   cc
  26 )
  27
  28 project(vpp C)
  29
  30 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  31   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  32 endif()
  33
  34 include(CheckCCompilerFlag)
  35 include(CheckIPOSupported)
  36 include(GNUInstallDirs)
  37 include(cmake/misc.cmake)
  38 include(cmake/cpu.cmake)
  39 include(cmake/ccache.cmake)
  40
  41 ##############################################################################
  42 # VPP Version
  43 ##############################################################################
  44 execute_process(
  45   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  46   COMMAND scripts/version
  47   OUTPUT_VARIABLE VPP_VERSION
  48   OUTPUT_STRIP_TRAILING_WHITESPACE
  49 )
  50 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  51 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  52
  53 ##############################################################################
  54 # cross compiling
  55 ##############################################################################
  56 if(CMAKE_CROSSCOMPILING)
  57   set(CMAKE_IGNORE_PATH
  58     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  59     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  60   )
  61 endif()
  62 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  63
  64 ##############################################################################
  65 # build config
  66 ##############################################################################
  67 check_c_compiler_flag("-Wno-address-of-packed-member"
  68                       compiler_flag_no_address_of_packed_member)
  69 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  70 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  71
  72 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  73 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  74 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  75 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
  76
  77 if (CMAKE_BUILD_TYPE)
  78   add_compile_options(-g -Werror -Wall)
  79 endif()
  80
  81 if (compiler_flag_no_address_of_packed_member)
  82   add_compile_options(-Wno-address-of-packed-member)
  83 endif()
  84
  85 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  86 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  87
  88 set(CMAKE_C_FLAGS_RELEASE "")
  89 set(CMAKE_C_FLAGS_DEBUG "")
  90
  91 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  92   add_compile_options(-O3 -fstack-protector -fno-common)
  93   add_compile_definitions(_FORTIFY_SOURCE=2)
  94 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
  95   add_compile_options(-O0 -fstack-protector -fno-common)
  96   add_compile_definitions(CLIB_DEBUG)
  97 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
  98   add_compile_options(-O0)
  99   add_compile_definitions(__COVERITY__)
 100 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 101   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 102   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 103 endif()
 104
 105 set(BUILD_TYPES release debug coverity gcov)
 106 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 107 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 108              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 109
 110 ##############################################################################
 111 # link time optimizations
 112 ##############################################################################
 113 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 114   check_ipo_supported(RESULT _result)
 115   if (_result)
 116     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 117   endif()
 118 endif()
 119
 120 if(VPP_USE_LTO)
 121   check_c_compiler_flag("-Wno-stringop-overflow"
 122                         compiler_flag_no_stringop_overflow)
 123 endif()
 124 ##############################################################################
 125 # sanitizers
 126 ##############################################################################
 127
 128 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 129 set(VPP_SANITIZE_ADDR_OPTIONS
 130   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 131   CACHE
 132   STRING "Address sanitizer arguments"
 133 )
 134
 135 if (VPP_ENABLE_SANITIZE_ADDR)
 136   add_compile_options(-fsanitize=address)
 137   add_link_options(-fsanitize=address)
 138 endif (VPP_ENABLE_SANITIZE_ADDR)
 139
 140 ##############################################################################
 141 # trajectory trace
 142 ##############################################################################
 143
 144 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 145 if(VPP_ENABLE_TRAJECTORY_TRACE)
 146   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 147 endif()
 148
 149 ##############################################################################
 150 # unittest with clang ode coverage
 151 ##############################################################################
 152
 153 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 154   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 155 endif()
 156
 157 ##############################################################################
 158 # install config
 159 ##############################################################################
 160 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 161 if(VPP_SET_RPATH)
 162   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 163 endif()
 164 set(CMAKE_INSTALL_MESSAGE NEVER)
 165
 166 include_directories (
 167         ${CMAKE_SOURCE_DIR}
 168         ${VPP_BINARY_DIR}
 169 )
 170 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 171
 172 set(THREADS_PREFER_PTHREAD_FLAG ON)
 173 find_package(Threads REQUIRED)
 174
 175 include(cmake/syscall.cmake)
 176 include(cmake/api.cmake)
 177 include(cmake/library.cmake)
 178 include(cmake/exec.cmake)
 179 include(cmake/plugin.cmake)
 180
 181 ##############################################################################
 182 # subdirs - order matters
 183 ##############################################################################
 184 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 185 if(VPP_HOST_TOOLS_ONLY)
 186   set(SUBDIRS tools/vppapigen cmake)
 187 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 188   find_package(OpenSSL)
 189   set(SUBDIRS
 190     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 191     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 192     tools/appimage
 193   )
 194 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 195   set(SUBDIRS vppinfra)
 196 else()
 197   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 198 endif()
 199
 200 foreach(DIR ${SUBDIRS})
 201   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 202 endforeach()
 203
 204 ##############################################################################
 205 # detect if we are inside git repo and add configure dependency
 206 ##############################################################################
 207 execute_process(
 208   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 209   COMMAND git rev-parse --show-toplevel
 210   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 211   OUTPUT_STRIP_TRAILING_WHITESPACE
 212   ERROR_QUIET
 213 )
 214
 215 if (VPP_GIT_TOPLEVEL_DIR)
 216   set_property(
 217     DIRECTORY APPEND PROPERTY
 218     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 219   )
 220 endif()
 221
 222 ##############################################################################
 223 # custom targets
 224 ##############################################################################
 225
 226 add_custom_target(run
 227   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 228   COMMENT "Starting VPP..."
 229   USES_TERMINAL
 230 )
 231
 232 add_custom_target(debug
 233   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 234   COMMENT "Starting VPP in the debugger..."
 235   USES_TERMINAL
 236 )
 237
 238 add_custom_target(config
 239   COMMAND ccmake ${CMAKE_BINARY_DIR}
 240   COMMENT "Starting Configuration TUI..."
 241   USES_TERMINAL
 242 )
 243
 244 foreach(bt ${BUILD_TYPES})
 245   add_custom_target(set-build-type-${bt}
 246     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 247     COMMENT "Changing build type to ${bt}"
 248     USES_TERMINAL
 249   )
 250 endforeach()
 251
 252 mark_as_advanced(CLEAR
 253   CMAKE_C_FLAGS
 254   CMAKE_C_COMPILER
 255   CMAKE_EXPORT_COMPILE_COMMANDS
 256   CMAKE_INSTALL_PREFIX
 257   CMAKE_LINKER
 258   CMAKE_SHARED_LINKER_FLAGS
 259   CMAKE_VERBOSE_MAKEFILE
 260 )
 261
 262 ##############################################################################
 263 # print configuration
 264 ##############################################################################
 265 message(STATUS "Configuration:")
 266 pr("VPP version" ${VPP_VERSION})
 267 pr("VPP library version" ${VPP_LIB_VERSION})
 268 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 269 pr("Build type" ${CMAKE_BUILD_TYPE})
 270 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 271 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 272 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 273 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 274 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 275 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 276 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 277 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 278 pr("Library dir" ${VPP_LIBRARY_DIR})