src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-13
  18   clang-12
  19   clang-11
  20   clang-10
  21   clang-9
  22   gcc-10
  23   gcc-9
  24   cc
  25 )
  26
  27 project(vpp C)
  28
  29 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  30   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  31 endif()
  32
  33 include(CheckCCompilerFlag)
  34 include(CheckIPOSupported)
  35 include(GNUInstallDirs)
  36 include(cmake/misc.cmake)
  37 include(cmake/cpu.cmake)
  38 include(cmake/ccache.cmake)
  39
  40 ##############################################################################
  41 # VPP Version
  42 ##############################################################################
  43 execute_process(
  44   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  45   COMMAND scripts/version
  46   OUTPUT_VARIABLE VPP_VERSION
  47   OUTPUT_STRIP_TRAILING_WHITESPACE
  48 )
  49 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  50 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  51
  52 ##############################################################################
  53 # cross compiling
  54 ##############################################################################
  55 if(CMAKE_CROSSCOMPILING)
  56   set(CMAKE_IGNORE_PATH
  57     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  58     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  59   )
  60 endif()
  61 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  62
  63 ##############################################################################
  64 # build config
  65 ##############################################################################
  66 check_c_compiler_flag("-Wno-address-of-packed-member"
  67                       compiler_flag_no_address_of_packed_member)
  68 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  69 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  70
  71 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  72 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  73 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  74 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
  75
  76 if (CMAKE_BUILD_TYPE)
  77   add_compile_options(-g -Werror -Wall)
  78 endif()
  79
  80 if (compiler_flag_no_address_of_packed_member)
  81   add_compile_options(-Wno-address-of-packed-member)
  82 endif()
  83
  84 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
  85 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
  86
  87 set(CMAKE_C_FLAGS_RELEASE "")
  88 set(CMAKE_C_FLAGS_DEBUG "")
  89
  90 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
  91   add_compile_options(-O3 -fstack-protector -fno-common)
  92   add_compile_definitions(_FORTIFY_SOURCE=2)
  93 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
  94   add_compile_options(-O0 -fstack-protector -fno-common)
  95   add_compile_definitions(CLIB_DEBUG)
  96 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
  97   add_compile_options(-O0)
  98   add_compile_definitions(__COVERITY__)
  99 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 100   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 101   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 102 endif()
 103
 104 set(BUILD_TYPES release debug coverity gcov)
 105 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 106 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 107              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 108
 109 ##############################################################################
 110 # link time optimizations
 111 ##############################################################################
 112 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 113   check_ipo_supported(RESULT _result)
 114   if (_result)
 115     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 116   endif()
 117 endif()
 118
 119 if(VPP_USE_LTO)
 120   check_c_compiler_flag("-Wno-stringop-overflow"
 121                         compiler_flag_no_stringop_overflow)
 122 endif()
 123 ##############################################################################
 124 # sanitizers
 125 ##############################################################################
 126
 127 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 128 set(VPP_SANITIZE_ADDR_OPTIONS
 129   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 130   CACHE
 131   STRING "Address sanitizer arguments"
 132 )
 133
 134 if (VPP_ENABLE_SANITIZE_ADDR)
 135   add_compile_options(-fsanitize=address)
 136   add_link_options(-fsanitize=address)
 137 endif (VPP_ENABLE_SANITIZE_ADDR)
 138
 139 ##############################################################################
 140 # trajectory trace
 141 ##############################################################################
 142
 143 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 144 if(VPP_ENABLE_TRAJECTORY_TRACE)
 145   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 146 endif()
 147
 148 ##############################################################################
 149 # unittest with clang ode coverage
 150 ##############################################################################
 151
 152 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 153   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 154 endif()
 155
 156 ##############################################################################
 157 # install config
 158 ##############################################################################
 159 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 160 if(VPP_SET_RPATH)
 161   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 162 endif()
 163 set(CMAKE_INSTALL_MESSAGE NEVER)
 164
 165 include_directories (
 166         ${CMAKE_SOURCE_DIR}
 167         ${VPP_BINARY_DIR}
 168 )
 169 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 170
 171 set(THREADS_PREFER_PTHREAD_FLAG ON)
 172 find_package(Threads REQUIRED)
 173
 174 include(cmake/syscall.cmake)
 175 include(cmake/api.cmake)
 176 include(cmake/library.cmake)
 177 include(cmake/exec.cmake)
 178 include(cmake/plugin.cmake)
 179
 180 ##############################################################################
 181 # subdirs - order matters
 182 ##############################################################################
 183 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 184 if(VPP_HOST_TOOLS_ONLY)
 185   set(SUBDIRS tools/vppapigen cmake)
 186 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 187   find_package(OpenSSL)
 188   set(SUBDIRS
 189     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 190     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 191     tools/appimage
 192   )
 193 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 194   set(SUBDIRS vppinfra)
 195 else()
 196   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 197 endif()
 198
 199 foreach(DIR ${SUBDIRS})
 200   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 201 endforeach()
 202
 203 ##############################################################################
 204 # detect if we are inside git repo and add configure dependency
 205 ##############################################################################
 206 execute_process(
 207   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 208   COMMAND git rev-parse --show-toplevel
 209   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 210   OUTPUT_STRIP_TRAILING_WHITESPACE
 211   ERROR_QUIET
 212 )
 213
 214 if (VPP_GIT_TOPLEVEL_DIR)
 215   set_property(
 216     DIRECTORY APPEND PROPERTY
 217     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 218   )
 219 endif()
 220
 221 ##############################################################################
 222 # custom targets
 223 ##############################################################################
 224
 225 add_custom_target(run
 226   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 227   COMMENT "Starting VPP..."
 228   USES_TERMINAL
 229 )
 230
 231 add_custom_target(debug
 232   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 233   COMMENT "Starting VPP in the debugger..."
 234   USES_TERMINAL
 235 )
 236
 237 add_custom_target(config
 238   COMMAND ccmake ${CMAKE_BINARY_DIR}
 239   COMMENT "Starting Configuration TUI..."
 240   USES_TERMINAL
 241 )
 242
 243 foreach(bt ${BUILD_TYPES})
 244   add_custom_target(set-build-type-${bt}
 245     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 246     COMMENT "Changing build type to ${bt}"
 247     USES_TERMINAL
 248   )
 249 endforeach()
 250
 251 mark_as_advanced(CLEAR
 252   CMAKE_C_FLAGS
 253   CMAKE_C_COMPILER
 254   CMAKE_EXPORT_COMPILE_COMMANDS
 255   CMAKE_INSTALL_PREFIX
 256   CMAKE_LINKER
 257   CMAKE_SHARED_LINKER_FLAGS
 258   CMAKE_VERBOSE_MAKEFILE
 259 )
 260
 261 ##############################################################################
 262 # print configuration
 263 ##############################################################################
 264 message(STATUS "Configuration:")
 265 pr("VPP version" ${VPP_VERSION})
 266 pr("VPP library version" ${VPP_LIB_VERSION})
 267 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 268 pr("Build type" ${CMAKE_BUILD_TYPE})
 269 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 270 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 271 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 272 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 273 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 274 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 275 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 276 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 277 pr("Library dir" ${VPP_LIBRARY_DIR})