src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 set(CMAKE_C_COMPILER_NAMES clang gcc cc)
  17
  18 project(vpp C)
  19
  20 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  21   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  22 endif()
  23
  24 include(CheckCCompilerFlag)
  25 include(CheckIPOSupported)
  26 include(GNUInstallDirs)
  27 include(cmake/misc.cmake)
  28 include(cmake/cpu.cmake)
  29 include(cmake/ccache.cmake)
  30
  31 ##############################################################################
  32 # VPP Version
  33 ##############################################################################
  34 execute_process(
  35   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  36   COMMAND scripts/version
  37   OUTPUT_VARIABLE VPP_VERSION
  38   OUTPUT_STRIP_TRAILING_WHITESPACE
  39 )
  40 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  41 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  42
  43 ##############################################################################
  44 # compiler specifics
  45 ##############################################################################
  46
  47 set(MIN_SUPPORTED_CLANG_C_COMPILER_VERSION 9.0.0)
  48 set(MIN_SUPPORTED_GNU_C_COMPILER_VERSION 9.0.0)
  49
  50 if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
  51   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_CLANG_C_COMPILER_VERSION)
  52     set(COMPILER_TOO_OLD TRUE)
  53   endif()
  54 elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU")
  55   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_GNU_C_COMPILER_VERSION)
  56     set(COMPILER_TOO_OLD TRUE)
  57   endif()
  58   set(GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION 10.0.0)
  59   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION)
  60     add_compile_options(-Wno-stringop-overflow)
  61   endif()
  62 else()
  63   message(WARNING "WARNING: Unsupported C compiler `${CMAKE_C_COMPILER_ID}` is used")
  64   set (PRINT_MIN_C_COMPILER_VER TRUE)
  65 endif()
  66 if (COMPILER_TOO_OLD)
  67   message(WARNING "WARNING: C compiler version is too old and it's usage may result")
  68   message(WARNING "         in sub-optimal binaries or lack of support for specific CPU types.")
  69   set (PRINT_MIN_C_COMPILER_VER TRUE)
  70 endif()
  71
  72 if (PRINT_MIN_C_COMPILER_VER)
  73   string (APPEND _t "Supported C compilers are ")
  74   string (APPEND _t "Clang ${MIN_SUPPORTED_CLANG_C_COMPILER_VERSION} or higher ")
  75   string (APPEND _t "and GNU ${MIN_SUPPORTED_GNU_C_COMPILER_VERSION} or higher.")
  76   message(WARNING "         ${_t}")
  77   unset (_t)
  78 endif()
  79
  80 ##############################################################################
  81 # cross compiling
  82 ##############################################################################
  83 if(CMAKE_CROSSCOMPILING)
  84   set(CMAKE_IGNORE_PATH
  85     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  86     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  87   )
  88 endif()
  89 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  90
  91 ##############################################################################
  92 # build config
  93 ##############################################################################
  94 check_c_compiler_flag("-Wno-address-of-packed-member"
  95                       compiler_flag_no_address_of_packed_member)
  96 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
  97 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
  98
  99 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
 100 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
 101 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
 102 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
 103
 104 if (CMAKE_BUILD_TYPE)
 105   add_compile_options(-g -Werror -Wall)
 106 endif()
 107
 108 if (compiler_flag_no_address_of_packed_member)
 109   add_compile_options(-Wno-address-of-packed-member)
 110 endif()
 111
 112 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
 113 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 114
 115 set(CMAKE_C_FLAGS_RELEASE "")
 116 set(CMAKE_C_FLAGS_DEBUG "")
 117
 118 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
 119   add_compile_options(-O3 -fstack-protector -fno-common)
 120   add_compile_definitions(_FORTIFY_SOURCE=2)
 121 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 122   add_compile_options(-O0 -fstack-protector -fno-common)
 123   add_compile_definitions(CLIB_DEBUG)
 124 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 125   add_compile_options(-O0)
 126   add_compile_definitions(__COVERITY__)
 127 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 128   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 129   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 130   link_libraries(gcov)
 131 endif()
 132
 133 set(BUILD_TYPES release debug coverity gcov)
 134 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 135 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 136              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 137
 138 ##############################################################################
 139 # link time optimizations
 140 ##############################################################################
 141 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 142   check_ipo_supported(RESULT _result)
 143   if (_result)
 144     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 145   endif()
 146 endif()
 147
 148 if(VPP_USE_LTO)
 149   check_c_compiler_flag("-Wno-stringop-overflow"
 150                         compiler_flag_no_stringop_overflow)
 151 endif()
 152 ##############################################################################
 153 # sanitizers
 154 ##############################################################################
 155
 156 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 157 set(VPP_SANITIZE_ADDR_OPTIONS
 158   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 159   CACHE
 160   STRING "Address sanitizer arguments"
 161 )
 162
 163 if (VPP_ENABLE_SANITIZE_ADDR)
 164   add_compile_options(-fsanitize=address)
 165   add_link_options(-fsanitize=address)
 166 endif (VPP_ENABLE_SANITIZE_ADDR)
 167
 168 ##############################################################################
 169 # trajectory trace
 170 ##############################################################################
 171
 172 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 173 if(VPP_ENABLE_TRAJECTORY_TRACE)
 174   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 175 endif()
 176
 177 ##############################################################################
 178 # unittest with clang ode coverage
 179 ##############################################################################
 180
 181 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 182   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 183 endif()
 184
 185 ##############################################################################
 186 # install config
 187 ##############################################################################
 188 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 189 if(VPP_SET_RPATH)
 190   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 191 endif()
 192 set(CMAKE_INSTALL_MESSAGE NEVER)
 193
 194 include_directories (
 195         ${CMAKE_SOURCE_DIR}
 196         ${VPP_BINARY_DIR}
 197 )
 198 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 199
 200 set(THREADS_PREFER_PTHREAD_FLAG ON)
 201 find_package(Threads REQUIRED)
 202
 203 include(cmake/syscall.cmake)
 204 include(cmake/api.cmake)
 205 include(cmake/library.cmake)
 206 include(cmake/exec.cmake)
 207 include(cmake/plugin.cmake)
 208
 209 ##############################################################################
 210 # subdirs - order matters
 211 ##############################################################################
 212 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 213 if(VPP_HOST_TOOLS_ONLY)
 214   set(SUBDIRS tools/vppapigen cmake)
 215 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 216   find_package(OpenSSL)
 217   set(SUBDIRS
 218     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 219     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 220     tools/appimage
 221   )
 222 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 223   set(SUBDIRS vppinfra)
 224 else()
 225   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 226 endif()
 227
 228 foreach(DIR ${SUBDIRS})
 229   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 230 endforeach()
 231
 232 ##############################################################################
 233 # detect if we are inside git repo and add configure dependency
 234 ##############################################################################
 235 execute_process(
 236   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 237   COMMAND git rev-parse --show-toplevel
 238   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 239   OUTPUT_STRIP_TRAILING_WHITESPACE
 240   ERROR_QUIET
 241 )
 242
 243 if (VPP_GIT_TOPLEVEL_DIR)
 244   set_property(
 245     DIRECTORY APPEND PROPERTY
 246     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 247   )
 248 endif()
 249
 250 ##############################################################################
 251 # custom targets
 252 ##############################################################################
 253
 254 add_custom_target(run
 255   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 256   COMMENT "Starting VPP..."
 257   USES_TERMINAL
 258 )
 259
 260 add_custom_target(debug
 261   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 262   COMMENT "Starting VPP in the debugger..."
 263   USES_TERMINAL
 264 )
 265
 266 add_custom_target(config
 267   COMMAND ccmake ${CMAKE_BINARY_DIR}
 268   COMMENT "Starting Configuration TUI..."
 269   USES_TERMINAL
 270 )
 271
 272 foreach(bt ${BUILD_TYPES})
 273   add_custom_target(set-build-type-${bt}
 274     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 275     COMMENT "Changing build type to ${bt}"
 276     USES_TERMINAL
 277   )
 278 endforeach()
 279
 280 mark_as_advanced(CLEAR
 281   CMAKE_C_FLAGS
 282   CMAKE_C_COMPILER
 283   CMAKE_EXPORT_COMPILE_COMMANDS
 284   CMAKE_INSTALL_PREFIX
 285   CMAKE_LINKER
 286   CMAKE_SHARED_LINKER_FLAGS
 287   CMAKE_VERBOSE_MAKEFILE
 288 )
 289
 290 ##############################################################################
 291 # print configuration
 292 ##############################################################################
 293 message(STATUS "Configuration:")
 294 pr("VPP version" ${VPP_VERSION})
 295 pr("VPP library version" ${VPP_LIB_VERSION})
 296 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 297 pr("Build type" ${CMAKE_BUILD_TYPE})
 298 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 299 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 300 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 301 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 302 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 303 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 304 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 305 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 306 pr("Library dir" ${VPP_LIBRARY_DIR})
 307 pr("Multiarch variants" ${MARCH_VARIANTS_NAMES})