src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.13)
  15
  16 if(DEFINED VPP_PLATFORM AND VPP_PLATFORM STREQUAL "default")
  17   unset(VPP_PLATFORM)
  18   set(VPP_PLATFORM_NAME "default")
  19 elseif(DEFINED VPP_PLATFORM)
  20   set(platform_file ${CMAKE_SOURCE_DIR}/cmake/platform/${VPP_PLATFORM}.cmake)
  21   if(NOT EXISTS ${platform_file})
  22      message(FATAL_ERROR "unknown platform ${VPP_PLATFORM}")
  23   endif()
  24   include(${platform_file})
  25   set(VPP_PLATFORM_NAME ${VPP_PLATFORM})
  26 else()
  27   set(VPP_PLATFORM_NAME "default")
  28 endif()
  29
  30 if (DEFINED VPP_PLATFORM_C_COMPILER_NAMES)
  31   set(CMAKE_C_COMPILER_NAMES ${VPP_PLATFORM_C_COMPILER_NAME})
  32 else()
  33   set(CMAKE_C_COMPILER_NAMES clang gcc cc)
  34 endif()
  35
  36 project(vpp C)
  37
  38 if(NOT DEFINED CMAKE_INSTALL_LIBDIR AND EXISTS "/etc/debian_version")
  39   set(CMAKE_INSTALL_LIBDIR "lib/${CMAKE_LIBRARY_ARCHITECTURE}")
  40 endif()
  41
  42 include(CheckCCompilerFlag)
  43 include(CheckIPOSupported)
  44 include(GNUInstallDirs)
  45 include(cmake/misc.cmake)
  46 include(cmake/cpu.cmake)
  47 include(cmake/ccache.cmake)
  48
  49 ##############################################################################
  50 # VPP Version
  51 ##############################################################################
  52 execute_process(
  53   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  54   COMMAND scripts/version
  55   OUTPUT_VARIABLE VPP_VERSION
  56   OUTPUT_STRIP_TRAILING_WHITESPACE
  57 )
  58
  59 if (VPP_PLATFORM)
  60   set(VPP_VERSION ${VPP_VERSION}-${VPP_PLATFORM_NAME})
  61 endif()
  62
  63 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  64 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  65
  66 ##############################################################################
  67 # compiler specifics
  68 ##############################################################################
  69
  70 set(MIN_SUPPORTED_CLANG_C_COMPILER_VERSION 9.0.0)
  71 set(MIN_SUPPORTED_GNU_C_COMPILER_VERSION 9.0.0)
  72
  73 if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
  74   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_CLANG_C_COMPILER_VERSION)
  75     set(COMPILER_TOO_OLD TRUE)
  76   endif()
  77 elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU")
  78   if (CMAKE_C_COMPILER_VERSION VERSION_LESS MIN_SUPPORTED_GNU_C_COMPILER_VERSION)
  79     set(COMPILER_TOO_OLD TRUE)
  80   endif()
  81   set(GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION 10.0.0)
  82   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERFLOW_WARNING_DISABLE_VERSION)
  83     add_compile_options(-Wno-stringop-overflow)
  84   endif()
  85   set(GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION 12.0.0)
  86   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_STRING_OVERREAD_WARNING_DISABLE_VERSION)
  87     add_compile_options(-Wno-stringop-overread)
  88   endif()
  89   set(GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION 12.0.0)
  90   if (CMAKE_C_COMPILER_VERSION VERSION_GREATER_EQUAL GCC_ARRAY_BOUNDS_WARNING_DISABLE_VERSION)
  91     add_compile_options(-Wno-array-bounds)
  92   endif()
  93 else()
  94   message(WARNING "WARNING: Unsupported C compiler `${CMAKE_C_COMPILER_ID}` is used")
  95   set (PRINT_MIN_C_COMPILER_VER TRUE)
  96 endif()
  97 if (COMPILER_TOO_OLD)
  98   message(WARNING "WARNING: C compiler version is too old and it's usage may result")
  99   message(WARNING "         in sub-optimal binaries or lack of support for specific CPU types.")
 100   set (PRINT_MIN_C_COMPILER_VER TRUE)
 101 endif()
 102
 103 if (PRINT_MIN_C_COMPILER_VER)
 104   string (APPEND _t "Supported C compilers are ")
 105   string (APPEND _t "Clang ${MIN_SUPPORTED_CLANG_C_COMPILER_VERSION} or higher ")
 106   string (APPEND _t "and GNU ${MIN_SUPPORTED_GNU_C_COMPILER_VERSION} or higher.")
 107   message(WARNING "         ${_t}")
 108   unset (_t)
 109 endif()
 110
 111 ##############################################################################
 112 # cross compiling
 113 ##############################################################################
 114 if(CMAKE_CROSSCOMPILING)
 115   set(CMAKE_IGNORE_PATH
 116     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
 117     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
 118   )
 119 endif()
 120 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
 121
 122 ##############################################################################
 123 # build config
 124 ##############################################################################
 125 check_c_compiler_flag("-Wno-address-of-packed-member"
 126                       compiler_flag_no_address_of_packed_member)
 127 set(VPP_RUNTIME_DIR ${CMAKE_INSTALL_BINDIR} CACHE STRING "Relative runtime directory path")
 128 set(VPP_LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING "Relative library directory path")
 129
 130 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
 131 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
 132 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
 133 set(PYENV PYTHONPYCACHEPREFIX=${CMAKE_BINARY_DIR}/CMakeFiles/__pycache__)
 134
 135 if (CMAKE_BUILD_TYPE)
 136   add_compile_options(-g -Werror -Wall)
 137 endif()
 138
 139 if (compiler_flag_no_address_of_packed_member)
 140   add_compile_options(-Wno-address-of-packed-member)
 141 endif()
 142
 143 string(TOLOWER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_LC)
 144 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 145
 146 set(CMAKE_C_FLAGS_RELEASE "")
 147 set(CMAKE_C_FLAGS_DEBUG "")
 148
 149 if (${CMAKE_BUILD_TYPE_LC} MATCHES "release")
 150   add_compile_options(-O3 -fstack-protector -fno-common)
 151   add_compile_definitions(_FORTIFY_SOURCE=2)
 152 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "debug")
 153   add_compile_options(-O0 -fstack-protector -fno-common)
 154   add_compile_definitions(CLIB_DEBUG)
 155 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "coverity")
 156   add_compile_options(-O0)
 157   add_compile_definitions(__COVERITY__)
 158 elseif (${CMAKE_BUILD_TYPE_LC} MATCHES "gcov")
 159   add_compile_options(-O0 -fprofile-arcs -ftest-coverage)
 160   add_compile_definitions(CLIB_DEBUG CLIB_GCOV)
 161   link_libraries(gcov)
 162 endif()
 163
 164 set(BUILD_TYPES release debug coverity gcov)
 165 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 166 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 167              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 168
 169 ##############################################################################
 170 # link time optimizations
 171 ##############################################################################
 172 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 173   check_ipo_supported(RESULT _result)
 174   if (_result)
 175     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 176   endif()
 177 endif()
 178
 179 if(VPP_USE_LTO)
 180   check_c_compiler_flag("-Wno-stringop-overflow"
 181                         compiler_flag_no_stringop_overflow)
 182 endif()
 183 ##############################################################################
 184 # sanitizers
 185 ##############################################################################
 186
 187 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 188 set(VPP_SANITIZE_ADDR_OPTIONS
 189   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 190   CACHE
 191   STRING "Address sanitizer arguments"
 192 )
 193
 194 if (VPP_ENABLE_SANITIZE_ADDR)
 195   add_compile_options(-fsanitize=address)
 196   add_link_options(-fsanitize=address)
 197 endif (VPP_ENABLE_SANITIZE_ADDR)
 198
 199 ##############################################################################
 200 # trajectory trace
 201 ##############################################################################
 202
 203 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 204 if(VPP_ENABLE_TRAJECTORY_TRACE)
 205   add_compile_definitions(VLIB_BUFFER_TRACE_TRAJECTORY=1)
 206 endif()
 207
 208 ##############################################################################
 209 # unittest with clang code coverage
 210 ##############################################################################
 211
 212 if("${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.13" AND "${CMAKE_C_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
 213   option(VPP_BUILD_TESTS_WITH_COVERAGE "Build unit tests with code coverage" OFF)
 214 endif()
 215
 216 ##############################################################################
 217 # install config
 218 ##############################################################################
 219 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 220 if(VPP_SET_RPATH)
 221   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${VPP_LIBRARY_DIR}")
 222 endif()
 223 set(CMAKE_INSTALL_MESSAGE NEVER)
 224
 225 include_directories (
 226         ${CMAKE_SOURCE_DIR}
 227         ${VPP_BINARY_DIR}
 228 )
 229 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 230
 231 set(THREADS_PREFER_PTHREAD_FLAG ON)
 232 find_package(Threads REQUIRED)
 233
 234 include(cmake/syscall.cmake)
 235 include(cmake/api.cmake)
 236 include(cmake/library.cmake)
 237 include(cmake/exec.cmake)
 238 include(cmake/plugin.cmake)
 239
 240 ##############################################################################
 241 # subdirs - order matters
 242 ##############################################################################
 243 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 244 if(VPP_HOST_TOOLS_ONLY)
 245   set(SUBDIRS tools/vppapigen cmake)
 246   install(
 247     PROGRAMS
 248     vpp-api/vapi/vapi_c_gen.py
 249     vpp-api/vapi/vapi_cpp_gen.py
 250     vpp-api/vapi/vapi_json_parser.py
 251     DESTINATION ${VPP_RUNTIME_DIR}
 252     COMPONENT vpp-dev
 253   )
 254 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 255   find_package(OpenSSL)
 256   set(SUBDIRS
 257     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl vpp-api
 258     plugins tools/vppapigen tools/g2 tools/perftool cmake pkg
 259     tools/appimage
 260   )
 261 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 262   set(SUBDIRS vppinfra)
 263 else()
 264   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 265 endif()
 266
 267 foreach(DIR ${SUBDIRS})
 268   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 269 endforeach()
 270
 271 ##############################################################################
 272 # detect if we are inside git repo and add configure dependency
 273 ##############################################################################
 274 execute_process(
 275   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 276   COMMAND git rev-parse --show-toplevel
 277   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 278   OUTPUT_STRIP_TRAILING_WHITESPACE
 279   ERROR_QUIET
 280 )
 281
 282 if (VPP_GIT_TOPLEVEL_DIR)
 283   set_property(
 284     DIRECTORY APPEND PROPERTY
 285     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 286   )
 287 endif()
 288
 289 ##############################################################################
 290 # custom targets
 291 ##############################################################################
 292
 293 add_custom_target(run
 294   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 295   COMMENT "Starting VPP..."
 296   USES_TERMINAL
 297 )
 298
 299 add_custom_target(debug
 300   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 301   COMMENT "Starting VPP in the debugger..."
 302   USES_TERMINAL
 303 )
 304
 305 add_custom_target(config
 306   COMMAND ccmake ${CMAKE_BINARY_DIR}
 307   COMMENT "Starting Configuration TUI..."
 308   USES_TERMINAL
 309 )
 310
 311 foreach(bt ${BUILD_TYPES})
 312   add_custom_target(set-build-type-${bt}
 313     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 314     COMMENT "Changing build type to ${bt}"
 315     USES_TERMINAL
 316   )
 317 endforeach()
 318
 319 mark_as_advanced(CLEAR
 320   CMAKE_C_FLAGS
 321   CMAKE_C_COMPILER
 322   CMAKE_EXPORT_COMPILE_COMMANDS
 323   CMAKE_INSTALL_PREFIX
 324   CMAKE_LINKER
 325   CMAKE_SHARED_LINKER_FLAGS
 326   CMAKE_VERBOSE_MAKEFILE
 327 )
 328
 329 ##############################################################################
 330 # print configuration
 331 ##############################################################################
 332 message(STATUS "Configuration:")
 333 pr("VPP platform" ${VPP_PLATFORM_NAME})
 334 pr("VPP version" ${VPP_VERSION})
 335 pr("VPP library version" ${VPP_LIB_VERSION})
 336 pr("GIT toplevel dir" ${VPP_GIT_TOPLEVEL_DIR})
 337 pr("Build type" ${CMAKE_BUILD_TYPE})
 338 pr("C compiler" "${CMAKE_C_COMPILER} (${CMAKE_C_COMPILER_ID} ${CMAKE_C_COMPILER_VERSION})")
 339 pr("C flags" ${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 340 pr("Linker flags (apps)" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 341 pr("Linker flags (libs)" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}})
 342 pr("Host processor" ${CMAKE_HOST_SYSTEM_PROCESSOR})
 343 pr("Target processor" ${CMAKE_SYSTEM_PROCESSOR})
 344 pr("Prefix path" ${CMAKE_PREFIX_PATH})
 345 pr("Install prefix" ${CMAKE_INSTALL_PREFIX})
 346 pr("Library dir" ${VPP_LIBRARY_DIR})
 347 pr("Multiarch variants" ${MARCH_VARIANTS_NAMES})