src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19
  20 ##############################################################################
  21 # Highlight WARNING and ERROR messages
  22 ##############################################################################
  23 function(message)
  24   list(GET ARGV 0 type)
  25   string(ASCII 27 esc)
  26   set(red "${esc}[1;31m")
  27   set(yellow "${esc}[1;33m")
  28   set(reset "${esc}[m")
  29   if(type STREQUAL FATAL_ERROR OR type STREQUAL SEND_ERROR)
  30     list(REMOVE_AT ARGV 0)
  31     _message(${type} "${red}${ARGV}${reset}")
  32   elseif(type STREQUAL WARNING)
  33     list(REMOVE_AT ARGV 0)
  34     _message(STATUS "${yellow}${ARGV}${reset}")
  35   elseif(type STREQUAL STATUS)
  36     list(REMOVE_AT ARGV 0)
  37     _message(STATUS "${ARGV}")
  38   else()
  39     _message(${ARGV})
  40   endif()
  41 endfunction()
  42
  43 ##############################################################################
  44 # CPU optimizations and multiarch support
  45 ##############################################################################
  46 if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  47   set(CMAKE_C_FLAGS "-march=corei7 -mtune=corei7-avx ${CMAKE_C_FLAGS}")
  48   check_c_compiler_flag("-march=core-avx2" AVX2)
  49   if(AVX2)
  50     list(APPEND MARCH_VARIANTS "avx2\;-march=core-avx2 -mtune=core-avx2")
  51   endif()
  52   check_c_compiler_flag("-march=skylake-avx512" AVX512)
  53   if(AVX512)
  54     list(APPEND MARCH_VARIANTS "avx512\;-march=skylake-avx512 -mtune=skylake-avx512")
  55   endif()
  56 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  57   set(CMAKE_C_FLAGS "-march=armv8-a+crc ${CMAKE_C_FLAGS}")
  58 endif()
  59
  60 macro(vpp_library_set_multiarch_sources lib)
  61   foreach(V ${MARCH_VARIANTS})
  62     list(GET V 0 VARIANT)
  63     list(GET V 1 VARIANT_FLAGS)
  64     set(l ${lib}_${VARIANT})
  65     add_library(${l} OBJECT ${ARGN})
  66     set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  67     target_compile_options(${l} PUBLIC "-DCLIB_MARCH_VARIANT=${VARIANT}")
  68     separate_arguments(VARIANT_FLAGS)
  69     target_compile_options(${l} PUBLIC ${VARIANT_FLAGS})
  70     target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${l}>)
  71   endforeach()
  72 endmacro()
  73
  74 ##############################################################################
  75 # build config
  76 ##############################################################################
  77 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  78 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  79 set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
  80 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
  81 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
  82
  83 ##############################################################################
  84 # ccache
  85 ##############################################################################
  86 option(VPP_USE_CCACHE "Use ccache compiler cache." ON)
  87 if(VPP_USE_CCACHE)
  88   find_program(CCACHE_FOUND ccache)
  89   message(STATUS "Looking for ccache")
  90   if(CCACHE_FOUND)
  91     message(STATUS "Looking for ccache - found")
  92     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  93     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  94   else(CCACHE_FOUND)
  95     message(STATUS "Looking for ccache - not found")
  96   endif(CCACHE_FOUND)
  97 endif(VPP_USE_CCACHE)
  98
  99 ##############################################################################
 100 # install config
 101 ##############################################################################
 102 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 103 set(CMAKE_INSTALL_MESSAGE NEVER)
 104
 105 message(STATUS "CMAKE_C_FLAGS: ${CMAKE_C_FLAGS}")
 106 message(STATUS "We are on a ${CMAKE_SYSTEM_NAME} system")
 107 message(STATUS "The host processor is ${CMAKE_HOST_SYSTEM_PROCESSOR}")
 108
 109 include_directories (
 110         ${CMAKE_SOURCE_DIR}
 111         ${CMAKE_BINARY_DIR}
 112         ${CMAKE_BINARY_DIR}/include
 113 )
 114 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 115
 116 set(THREADS_PREFER_PTHREAD_FLAG ON)
 117 find_package(Threads REQUIRED)
 118 find_package(OpenSSL REQUIRED)
 119 include_directories(${OPENSSL_INCLUDE_DIR})
 120
 121 add_definitions(-DHAVE_MEMFD_CREATE -DVPP_API_TEST_BUILTIN=1)
 122
 123 ##############################################################################
 124 # API
 125 ##############################################################################
 126 function(vpp_generate_api_header file)
 127   set (output_name ${CMAKE_CURRENT_BINARY_DIR}/${file}.h)
 128   get_filename_component(output_dir ${output_name} DIRECTORY)
 129   add_custom_command (OUTPUT ${output_name}
 130     COMMAND mkdir -p ${output_dir}
 131     COMMAND ${CMAKE_SOURCE_DIR}/tools/vppapigen/vppapigen
 132     ARGS --includedir ${CMAKE_SOURCE_DIR} --input ${CMAKE_CURRENT_SOURCE_DIR}/${file} --output ${output_name}
 133     DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${file}
 134     COMMENT "Generating API header ${file}.h"
 135   )
 136 endfunction()
 137
 138 function(vpp_add_api_files target)
 139   unset(header_files)
 140   foreach(file ${ARGN})
 141     vpp_generate_api_header (${file})
 142     list (APPEND header_files ${file}.h)
 143   endforeach()
 144   add_custom_target(${target} DEPENDS ${header_files})
 145 endfunction()
 146
 147 add_custom_target(api_headers
 148   DEPENDS vlibmemory_api_headers vnet_api_headers vpp_api_headers
 149 )
 150
 151 ##############################################################################
 152 # header files
 153 ##############################################################################
 154 function (vpp_add_header_files path)
 155   foreach(file ${ARGN})
 156     get_filename_component(dir ${file} DIRECTORY)
 157     install(FILES ${file} DESTINATION include/${path}/${dir})
 158   endforeach()
 159 endfunction()
 160
 161 ##############################################################################
 162 # subdirs
 163 ##############################################################################
 164 foreach (DIR vppinfra svm vlib vlibmemory vnet vpp vpp-api vcl plugins)
 165   add_subdirectory(${DIR})
 166 endforeach ()
 167
 168 ##############################################################################
 169 # DEB Packaging
 170 ##############################################################################
 171 set(CPACK_GENERATOR "DEB")
 172 set(CPACK_DEBIAN_PACKAGE_MAINTAINER "VPP Team")
 173 set(CPACK_PACKAGE_NAME "vpp")
 174 set(CPACK_PACKAGE_VENDOR "fd.io")
 175 set(CPACK_PACKAGE_VERSION "18.08")
 176 set(CPACK_DEB_COMPONENT_INSTALL ON)
 177 set(CPACK_COMPONENTS_IGNORE_GROUPS 1)
 178 set(CPACK_DEBIAN_VPP_PACKAGE_NAME "vpp")
 179 set(CPACK_DEBIAN_VPP_FILE_NAME "vpp.deb")
 180 set(CPACK_DEBIAN_DEV_PACKAGE_NAME "vpp-dev")
 181 set(CPACK_DEBIAN_DEV_FILE_NAME "vpp-dev.deb")
 182 set(CPACK_DEBIAN_PLUGINS_PACKAGE_NAME "vpp-plugins")
 183 set(CPACK_DEBIAN_PLUGINS_FILE_NAME "vpp-plugins.deb")
 184 include(CPack)