src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.10)
  15
  16 set(CMAKE_C_COMPILER_NAMES
  17   clang-12
  18   clang-11
  19   clang-10
  20   clang-9
  21   gcc-10
  22   gcc-9
  23   cc
  24 )
  25
  26 project(vpp C)
  27
  28 set(CMAKE_EXPORT_COMPILE_COMMANDS on)
  29
  30 include(CheckCCompilerFlag)
  31 include(CheckIPOSupported)
  32 include(cmake/misc.cmake)
  33 include(cmake/cpu.cmake)
  34 include(cmake/ccache.cmake)
  35
  36 ##############################################################################
  37 # VPP Version
  38 ##############################################################################
  39 execute_process(
  40   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  41   COMMAND scripts/version
  42   OUTPUT_VARIABLE VPP_VERSION
  43   OUTPUT_STRIP_TRAILING_WHITESPACE
  44 )
  45 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  46 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  47
  48 ##############################################################################
  49 # cross compiling
  50 ##############################################################################
  51 if(CMAKE_CROSSCOMPILING)
  52   set(CMAKE_IGNORE_PATH
  53     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  54     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  55   )
  56 endif()
  57 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  58
  59 ##############################################################################
  60 # build config
  61 ##############################################################################
  62 check_c_compiler_flag("-Wno-address-of-packed-member"
  63                       compiler_flag_no_address_of_packed_member)
  64 set(VPP_RUNTIME_DIR "bin" CACHE STRING "Relative runtime directory path")
  65 set(VPP_LIBRARY_DIR "lib" CACHE STRING "Relative library directory path")
  66
  67 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_RUNTIME_DIR})
  68 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/${VPP_LIBRARY_DIR})
  69 set(VPP_BINARY_DIR ${CMAKE_BINARY_DIR}/CMakeFiles)
  70
  71 if (CMAKE_BUILD_TYPE)
  72   set(CMAKE_C_FLAGS "-g -fPIC -Werror -Wall ${CMAKE_C_FLAGS}")
  73 endif()
  74
  75 if (compiler_flag_no_address_of_packed_member)
  76   set(CMAKE_C_FLAGS "-Wno-address-of-packed-member ${CMAKE_C_FLAGS}")
  77 endif()
  78
  79 # release
  80 list(APPEND BUILD_TYPES "release")
  81 string(CONCAT CMAKE_C_FLAGS_RELEASE
  82   "-O3 "
  83   "-fstack-protector "
  84   "-D_FORTIFY_SOURCE=2 "
  85   "-fno-common "
  86 )
  87
  88 string(CONCAT CMAKE_EXE_LINKER_FLAGS_RELEASE "-pie")
  89
  90 # debug
  91 list(APPEND BUILD_TYPES "debug")
  92 string(CONCAT CMAKE_C_FLAGS_DEBUG
  93   "-O0 "
  94   "-DCLIB_DEBUG "
  95   "-fstack-protector "
  96   "-fno-common "
  97 )
  98
  99 # coverity
 100 list(APPEND BUILD_TYPES "coverity")
 101 string(CONCAT CMAKE_C_FLAGS_COVERITY "-O2 -D__COVERITY__")
 102
 103 # gcov
 104 list(APPEND BUILD_TYPES "gcov")
 105 string(CONCAT CMAKE_C_FLAGS_GCOV
 106   "-O0 "
 107   "-DCLIB_DEBUG "
 108   "-DCLIB_GCOV "
 109   "-fprofile-arcs "
 110   "-ftest-coverage ")
 111
 112 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UC)
 113
 114
 115 string(REPLACE ";" " " BUILD_TYPES_STR "${BUILD_TYPES}")
 116 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY
 117              HELPSTRING "Build type - valid options are: ${BUILD_TYPES_STR}")
 118
 119 ##############################################################################
 120 # link time optimizations
 121 ##############################################################################
 122 if (CMAKE_BUILD_TYPE_UC STREQUAL "RELEASE")
 123   check_ipo_supported(RESULT _result)
 124   if (_result)
 125     option(VPP_USE_LTO "Link time optimization of release binaries" ON)
 126   endif()
 127 endif()
 128
 129 ##############################################################################
 130 # sanitizers
 131 ##############################################################################
 132
 133 option(VPP_ENABLE_SANITIZE_ADDR "Enable Address Sanitizer" OFF)
 134 set(VPP_SANITIZE_ADDR_OPTIONS
 135   "unmap_shadow_on_exit=1:disable_coredump=0:abort_on_error=1:detect_leaks=0"
 136   CACHE
 137   STRING "Address sanitizer arguments"
 138 )
 139
 140 if (VPP_ENABLE_SANITIZE_ADDR)
 141   set(CMAKE_C_FLAGS "-fsanitize=address -DCLIB_SANITIZE_ADDR ${CMAKE_C_FLAGS}")
 142   set(CMAKE_EXE_LINKER_FLAGS "-fsanitize=address ${CMAKE_EXE_LINKER_FLAGS}")
 143   set(CMAKE_SHARED_LINKER_FLAGS "-fsanitize=address ${CMAKE_SHARED_LINKER_FLAGS}")
 144 endif (VPP_ENABLE_SANITIZE_ADDR)
 145
 146 ##############################################################################
 147 # trajectory trace
 148 ##############################################################################
 149
 150 option(VPP_ENABLE_TRAJECTORY_TRACE "Build vpp with trajectory tracing enabled" OFF)
 151 if(VPP_ENABLE_TRAJECTORY_TRACE)
 152   set(CMAKE_C_FLAGS "-DVLIB_BUFFER_TRACE_TRAJECTORY=1 ${CMAKE_C_FLAGS}")
 153 endif()
 154
 155 ##############################################################################
 156 # install config
 157 ##############################################################################
 158 option(VPP_SET_RPATH "Set rpath for resulting binaries and libraries." ON)
 159 if(VPP_SET_RPATH)
 160   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 161 endif()
 162 set(CMAKE_INSTALL_MESSAGE NEVER)
 163
 164 include_directories (
 165         ${CMAKE_SOURCE_DIR}
 166         ${VPP_BINARY_DIR}
 167 )
 168 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 169
 170 set(THREADS_PREFER_PTHREAD_FLAG ON)
 171 find_package(Threads REQUIRED)
 172
 173 include(cmake/syscall.cmake)
 174 include(cmake/api.cmake)
 175 include(cmake/library.cmake)
 176 include(cmake/exec.cmake)
 177 include(cmake/plugin.cmake)
 178
 179 ##############################################################################
 180 # subdirs - order matters
 181 ##############################################################################
 182 option(VPP_HOST_TOOLS_ONLY "Build only host tools" OFF)
 183 if(VPP_HOST_TOOLS_ONLY)
 184   set(SUBDIRS tools/vppapigen cmake)
 185 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
 186   find_package(OpenSSL REQUIRED)
 187   set(SUBDIRS
 188     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vat2 vcl plugins
 189     vpp-api tools/vppapigen tools/g2 tools/perftool cmake pkg
 190     tools/appimage
 191   )
 192 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
 193   set(SUBDIRS vppinfra)
 194 else()
 195   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
 196 endif()
 197
 198 foreach(DIR ${SUBDIRS})
 199   add_subdirectory(${DIR} ${VPP_BINARY_DIR}/${DIR})
 200 endforeach()
 201
 202 ##############################################################################
 203 # detect if we are inside git repo and add configure dependency
 204 ##############################################################################
 205 execute_process(
 206   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 207   COMMAND git rev-parse --show-toplevel
 208   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 209   OUTPUT_STRIP_TRAILING_WHITESPACE
 210   ERROR_QUIET
 211 )
 212
 213 if (VPP_GIT_TOPLEVEL_DIR)
 214   set_property(
 215     DIRECTORY APPEND PROPERTY
 216     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 217   )
 218 endif()
 219
 220 ##############################################################################
 221 # custom targets
 222 ##############################################################################
 223
 224 add_custom_target(run
 225   COMMAND ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 226   COMMENT "Starting VPP..."
 227   USES_TERMINAL
 228 )
 229
 230 add_custom_target(debug
 231   COMMAND gdb --args ./${VPP_RUNTIME_DIR}/vpp -c startup.conf
 232   COMMENT "Starting VPP in the debugger..."
 233   USES_TERMINAL
 234 )
 235
 236 add_custom_target(config
 237   COMMAND ccmake ${CMAKE_BINARY_DIR}
 238   COMMENT "Starting Configuration TUI..."
 239   USES_TERMINAL
 240 )
 241
 242 add_custom_target(compdb
 243   COMMAND ninja -C ${CMAKE_BINARY_DIR} -t compdb |
 244           ${CMAKE_SOURCE_DIR}/scripts/compdb_cleanup.py >
 245           ${CMAKE_BINARY_DIR}/compile_commands.json
 246   COMMENT "Generating compile_commands.json"
 247   USES_TERMINAL
 248 )
 249
 250 foreach(bt ${BUILD_TYPES})
 251   add_custom_target(set-build-type-${bt}
 252     COMMAND cmake -DCMAKE_BUILD_TYPE:STRING=${bt} .
 253     COMMENT "Changing build type to ${bt}"
 254     USES_TERMINAL
 255   )
 256 endforeach()
 257
 258 ##############################################################################
 259 # print configuration
 260 ##############################################################################
 261 message(STATUS "Configuration:")
 262 pr("VPP version" "${VPP_VERSION}")
 263 pr("VPP library version" "${VPP_LIB_VERSION}")
 264 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 265 pr("Build type" "${CMAKE_BUILD_TYPE}")
 266 pr("C flags" "${CMAKE_C_FLAGS}${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 267 pr("Linker flags (apps)" "${CMAKE_EXE_LINKER_FLAGS}${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 268 pr("Linker flags (libs)" "${CMAKE_SHARED_LINKER_FLAGS}${CMAKE_SHARED_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 269 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 270 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 271 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 272 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")