src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19 include(cmake/message.cmake)
  20 include(cmake/cpu.cmake)
  21 include(cmake/ccache.cmake)
  22
  23 ##############################################################################
  24 # VPP Version
  25 ##############################################################################
  26 execute_process(
  27   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  28   COMMAND scripts/version
  29   OUTPUT_VARIABLE VPP_VERSION
  30   OUTPUT_STRIP_TRAILING_WHITESPACE
  31 )
  32 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  33 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  34
  35 ##############################################################################
  36 # cross compiling
  37 ##############################################################################
  38 if(CMAKE_CROSSCOMPILING)
  39   set(CMAKE_IGNORE_PATH
  40     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  41     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  42   )
  43 endif()
  44 set(CMAKE_C_COMPILER_TARGET ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  45
  46 ##############################################################################
  47 # build config
  48 ##############################################################################
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  51 set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
  52 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
  53 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
  54
  55 check_c_compiler_flag("-Wno-address-of-packed-member" compiler_flag_no_address_of_packed_member)
  56 if (compiler_flag_no_address_of_packed_member)
  57   add_definitions(-Wno-address-of-packed-member)
  58 endif()
  59
  60 ##############################################################################
  61 # install config
  62 ##############################################################################
  63 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
  64 set(CMAKE_INSTALL_MESSAGE NEVER)
  65
  66 include_directories (
  67         ${CMAKE_SOURCE_DIR}
  68         ${CMAKE_BINARY_DIR}
  69         ${CMAKE_BINARY_DIR}/include
  70 )
  71 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
  72
  73 set(THREADS_PREFER_PTHREAD_FLAG ON)
  74 find_package(Threads REQUIRED)
  75
  76 include(cmake/memfd.cmake)
  77 include(cmake/api.cmake)
  78 include(cmake/library.cmake)
  79 include(cmake/exec.cmake)
  80 include(cmake/plugin.cmake)
  81
  82 ##############################################################################
  83 # subdirs - order matters
  84 ##############################################################################
  85 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  86   find_package(OpenSSL REQUIRED)
  87   set(SUBDIRS
  88     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
  89     vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool cmake
  90   )
  91 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  92   set(SUBDIRS vppinfra)
  93 else()
  94   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
  95 endif()
  96
  97 foreach(DIR ${SUBDIRS})
  98   add_subdirectory(${DIR})
  99 endforeach()
 100
 101 ##############################################################################
 102 # packaging
 103 ##############################################################################
 104 include(cmake/pack.cmake)
 105 add_vpp_packaging(
 106   NAME "vpp"
 107   VENDOR "fd.io"
 108   DESCRIPTION "Vector Packet Processor"
 109 )
 110
 111 ##############################################################################
 112 # detect if we are inside git repo and add configure dependency
 113 ##############################################################################
 114 execute_process(
 115   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 116   COMMAND git rev-parse --show-toplevel
 117   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 118   OUTPUT_STRIP_TRAILING_WHITESPACE
 119 )
 120
 121 if (VPP_GIT_TOPLEVEL_DIR)
 122   set_property(
 123     DIRECTORY APPEND PROPERTY
 124     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 125   )
 126 endif()
 127
 128 ##############################################################################
 129 # print configuration
 130 ##############################################################################
 131 message(STATUS "Configuration:")
 132 pr("VPP version" "${VPP_VERSION}")
 133 pr("VPP library version" "${VPP_LIB_VERSION}")
 134 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 135 pr("C flags" "${CMAKE_C_FLAGS}")
 136 pr("Linker flags" "${CMAKE_LINKER_FLAGS}")
 137 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 138 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 139 pr("Build type" "${CMAKE_BUILD_TYPE}")
 140 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 141 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")
 142