src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19
  20 ##############################################################################
  21 # Highlight WARNING and ERROR messages
  22 ##############################################################################
  23 function(message)
  24   list(GET ARGV 0 type)
  25   string(ASCII 27 esc)
  26   set(red "${esc}[1;31m")
  27   set(yellow "${esc}[1;33m")
  28   set(reset "${esc}[m")
  29   if(type STREQUAL FATAL_ERROR OR type STREQUAL SEND_ERROR)
  30     list(REMOVE_AT ARGV 0)
  31     _message(${type} "${red}${ARGV}${reset}")
  32   elseif(type STREQUAL WARNING)
  33     list(REMOVE_AT ARGV 0)
  34     _message(STATUS "${yellow}${ARGV}${reset}")
  35   elseif(type STREQUAL STATUS)
  36     list(REMOVE_AT ARGV 0)
  37     _message(STATUS "${ARGV}")
  38   else()
  39     _message(${ARGV})
  40   endif()
  41 endfunction()
  42
  43 ##############################################################################
  44 # CPU optimizations and multiarch support
  45 ##############################################################################
  46 if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  47   set(CMAKE_C_FLAGS "-march=corei7 -mtune=corei7-avx ${CMAKE_C_FLAGS}")
  48   check_c_compiler_flag("-march=core-avx2" AVX2)
  49   if(AVX2)
  50     list(APPEND MARCH_VARIANTS "avx2\;-march=core-avx2 -mtune=core-avx2")
  51   endif()
  52   check_c_compiler_flag("-march=skylake-avx512" AVX512)
  53   if(AVX512)
  54     list(APPEND MARCH_VARIANTS "avx512\;-march=skylake-avx512 -mtune=skylake-avx512")
  55   endif()
  56 elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  57   set(CMAKE_C_FLAGS "-march=armv8-a+crc ${CMAKE_C_FLAGS}")
  58 endif()
  59
  60 macro(vpp_library_set_multiarch_sources lib)
  61   foreach(V ${MARCH_VARIANTS})
  62     list(GET V 0 VARIANT)
  63     list(GET V 1 VARIANT_FLAGS)
  64     set(l ${lib}_${VARIANT})
  65     add_library(${l} OBJECT ${ARGN})
  66     set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  67     target_compile_options(${l} PUBLIC "-DCLIB_MARCH_VARIANT=${VARIANT}")
  68     separate_arguments(VARIANT_FLAGS)
  69     target_compile_options(${l} PUBLIC ${VARIANT_FLAGS})
  70     target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${l}>)
  71   endforeach()
  72 endmacro()
  73
  74 ##############################################################################
  75 # build config
  76 ##############################################################################
  77 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  78 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  79 set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
  80 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
  81 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
  82
  83 ##############################################################################
  84 # ccache
  85 ##############################################################################
  86 option(VPP_USE_CCACHE "Use ccache compiler cache." ON)
  87 if(VPP_USE_CCACHE)
  88   find_program(CCACHE_FOUND ccache)
  89   message(STATUS "Looking for ccache")
  90   if(CCACHE_FOUND)
  91     message(STATUS "Looking for ccache - found")
  92     set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  93     set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  94   else(CCACHE_FOUND)
  95     message(STATUS "Looking for ccache - not found")
  96   endif(CCACHE_FOUND)
  97 endif(VPP_USE_CCACHE)
  98
  99 ##############################################################################
 100 # install config
 101 ##############################################################################
 102 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
 103 set(CMAKE_INSTALL_MESSAGE NEVER)
 104
 105 message(STATUS "CMAKE_C_FLAGS: ${CMAKE_C_FLAGS}")
 106 message(STATUS "We are on a ${CMAKE_SYSTEM_NAME} system")
 107 message(STATUS "The host processor is ${CMAKE_HOST_SYSTEM_PROCESSOR}")
 108
 109 include_directories (
 110         ${CMAKE_SOURCE_DIR}
 111         ${CMAKE_BINARY_DIR}
 112         ${CMAKE_BINARY_DIR}/include
 113 )
 114 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
 115
 116 set(THREADS_PREFER_PTHREAD_FLAG ON)
 117 find_package(Threads REQUIRED)
 118 find_package(OpenSSL REQUIRED)
 119 include_directories(${OPENSSL_INCLUDE_DIR})
 120
 121 ##############################################################################
 122 # Check for memfd_create headers and libs
 123 ##############################################################################
 124 check_c_source_compiles("
 125   #define _GNU_SOURCE
 126   #include <sys/mman.h>
 127   int main() { return memfd_create (\"/dev/false\", 0); }
 128 " HAVE_MEMFD_CREATE)
 129
 130 if (HAVE_MEMFD_CREATE)
 131     add_definitions(-DHAVE_MEMFD_CREATE)
 132 endif()
 133
 134 ##############################################################################
 135 # API
 136 ##############################################################################
 137 function(vpp_generate_api_c_header file)
 138   set (output_name ${CMAKE_CURRENT_BINARY_DIR}/${file}.h)
 139   get_filename_component(output_dir ${output_name} DIRECTORY)
 140   add_custom_command (OUTPUT ${output_name}
 141     COMMAND mkdir -p ${output_dir}
 142     COMMAND ${CMAKE_SOURCE_DIR}/tools/vppapigen/vppapigen
 143     ARGS --includedir ${CMAKE_SOURCE_DIR} --input ${CMAKE_CURRENT_SOURCE_DIR}/${file} --output ${output_name}
 144     DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${file}
 145     COMMENT "Generating API header ${output_name}"
 146   )
 147 endfunction()
 148
 149 function(vpp_generate_api_json_header file dir)
 150   set (output_name ${CMAKE_CURRENT_BINARY_DIR}/${file}.json)
 151   get_filename_component(output_dir ${output_name} DIRECTORY)
 152   add_custom_command (OUTPUT ${output_name}
 153     COMMAND mkdir -p ${output_dir}
 154     COMMAND ${CMAKE_SOURCE_DIR}/tools/vppapigen/vppapigen
 155     ARGS --includedir ${CMAKE_SOURCE_DIR} --input ${CMAKE_CURRENT_SOURCE_DIR}/${file} JSON --output ${output_name}
 156     DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${file}
 157     COMMENT "Generating API header ${output_name}"
 158   )
 159   install(FILES ${output_name} DESTINATION share/vpp/api/${dir}/)
 160 endfunction()
 161
 162 ##############################################################################
 163 # generate the .h and .json files for a .api file
 164 #  @param file - the name of the .api
 165 #  @param dir  - the install directory under ROOT/share/vpp/api to place the
 166 #                generated .json file
 167 ##############################################################################
 168 function(vpp_generate_api_header file dir)
 169     vpp_generate_api_c_header (${file})
 170     vpp_generate_api_json_header (${file} ${dir})
 171 endfunction()
 172
 173 function(vpp_add_api_files target)
 174   unset(header_files)
 175   foreach(file ${ARGN})
 176     vpp_generate_api_header (${file} core)
 177     list (APPEND header_files ${file}.h ${file}.json)
 178   endforeach()
 179   add_custom_target(${target} DEPENDS ${header_files})
 180 endfunction()
 181
 182 add_custom_target(api_headers
 183   DEPENDS vlibmemory_api_headers vnet_api_headers vpp_api_headers
 184 )
 185
 186 ##############################################################################
 187 # header files
 188 ##############################################################################
 189 function (vpp_add_header_files path)
 190   foreach(file ${ARGN})
 191     get_filename_component(dir ${file} DIRECTORY)
 192     install(FILES ${file} DESTINATION include/${path}/${dir})
 193   endforeach()
 194 endfunction()
 195
 196 ##############################################################################
 197 # subdirs
 198 ##############################################################################
 199 foreach (DIR vppinfra svm vlib vlibmemory vnet vpp vpp-api vat vcl plugins)
 200   add_subdirectory(${DIR})
 201 endforeach ()
 202
 203 ##############################################################################
 204 # DEB Packaging
 205 ##############################################################################
 206 set(CPACK_GENERATOR "DEB")
 207 set(CPACK_DEBIAN_PACKAGE_MAINTAINER "VPP Team")
 208 set(CPACK_PACKAGE_NAME "vpp")
 209 set(CPACK_PACKAGE_VENDOR "fd.io")
 210 set(CPACK_PACKAGE_VERSION "18.08")
 211 set(CPACK_DEB_COMPONENT_INSTALL ON)
 212 set(CPACK_COMPONENTS_IGNORE_GROUPS 1)
 213 set(CPACK_DEBIAN_VPP_PACKAGE_NAME "vpp")
 214 set(CPACK_DEBIAN_VPP_FILE_NAME "vpp.deb")
 215 set(CPACK_DEBIAN_DEV_PACKAGE_NAME "vpp-dev")
 216 set(CPACK_DEBIAN_DEV_FILE_NAME "vpp-dev.deb")
 217 set(CPACK_DEBIAN_PLUGINS_PACKAGE_NAME "vpp-plugins")
 218 set(CPACK_DEBIAN_PLUGINS_FILE_NAME "vpp-plugins.deb")
 219 include(CPack)