src/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 cmake_minimum_required(VERSION 3.5 FATAL_ERROR)
  15
  16 project(vpp C)
  17
  18 include(CheckCCompilerFlag)
  19 include(cmake/message.cmake)
  20 include(cmake/cpu.cmake)
  21 include(cmake/ccache.cmake)
  22
  23 ##############################################################################
  24 # VPP Version
  25 ##############################################################################
  26 execute_process(
  27   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  28   COMMAND scripts/version
  29   OUTPUT_VARIABLE VPP_VERSION
  30   OUTPUT_STRIP_TRAILING_WHITESPACE
  31 )
  32 string(REPLACE "-" ";" VPP_LIB_VERSION ${VPP_VERSION})
  33 list(GET VPP_LIB_VERSION 0 VPP_LIB_VERSION)
  34
  35 ##############################################################################
  36 # cross compiling
  37 ##############################################################################
  38 if(CMAKE_CROSSCOMPILING)
  39   set(CMAKE_IGNORE_PATH
  40     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/
  41     /usr/lib/${CMAKE_HOST_SYSTEM_PROCESSOR}-linux-gnu/lib/
  42   )
  43 endif()
  44
  45 ##############################################################################
  46 # build config
  47 ##############################################################################
  48 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  49 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  50 set(CMAKE_C_FLAGS_COMMON "-DFORTIFY_SOURCE=2 -fstack-protector-all -Werror")
  51 set(CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} ${CMAKE_C_FLAGS_COMMON} -DCLIB_DEBUG")
  52 set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} ${CMAKE_C_FLAGS_COMMON}")
  53
  54 check_c_compiler_flag("-Wno-address-of-packed-member" compiler_flag_no_address_of_packed_member)
  55 if (compiler_flag_no_address_of_packed_member)
  56   add_definitions(-Wno-address-of-packed-member)
  57 endif()
  58
  59 ##############################################################################
  60 # install config
  61 ##############################################################################
  62 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib")
  63 set(CMAKE_INSTALL_MESSAGE NEVER)
  64
  65 include_directories (
  66         ${CMAKE_SOURCE_DIR}
  67         ${CMAKE_BINARY_DIR}
  68         ${CMAKE_BINARY_DIR}/include
  69 )
  70 set(CMAKE_INSTALL_DEFAULT_COMPONENT_NAME "vpp")
  71
  72 set(THREADS_PREFER_PTHREAD_FLAG ON)
  73 find_package(Threads REQUIRED)
  74
  75 include(cmake/memfd.cmake)
  76 include(cmake/api.cmake)
  77 include(cmake/library.cmake)
  78 include(cmake/exec.cmake)
  79 include(cmake/plugin.cmake)
  80
  81 ##############################################################################
  82 # subdirs - order matters
  83 ##############################################################################
  84 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  85   find_package(OpenSSL REQUIRED)
  86   set(SUBDIRS
  87     vppinfra svm vlib vlibmemory vlibapi vnet vpp vat vcl plugins
  88     vpp-api tools/vppapigen tools/g2 tools/elftool tools/perftool cmake
  89   )
  90 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  91   set(SUBDIRS vppinfra)
  92 else()
  93   message(FATAL_ERROR "Unsupported system: ${CMAKE_SYSTEM_NAME}")
  94 endif()
  95
  96 foreach(DIR ${SUBDIRS})
  97   add_subdirectory(${DIR})
  98 endforeach()
  99
 100 ##############################################################################
 101 # packaging
 102 ##############################################################################
 103 include(cmake/pack.cmake)
 104 add_vpp_packaging(
 105   NAME "vpp"
 106   VENDOR "fd.io"
 107   DESCRIPTION "Vector Packet Processor"
 108 )
 109
 110 ##############################################################################
 111 # detect if we are inside git repo and add configure dependency
 112 ##############################################################################
 113 execute_process(
 114   WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 115   COMMAND git rev-parse --show-toplevel
 116   OUTPUT_VARIABLE VPP_GIT_TOPLEVEL_DIR
 117   OUTPUT_STRIP_TRAILING_WHITESPACE
 118 )
 119
 120 if (VPP_GIT_TOPLEVEL_DIR)
 121   set_property(
 122     DIRECTORY APPEND PROPERTY
 123     CMAKE_CONFIGURE_DEPENDS ${VPP_GIT_TOPLEVEL_DIR}/.git/index
 124   )
 125 endif()
 126
 127 ##############################################################################
 128 # print configuration
 129 ##############################################################################
 130 message(STATUS "Configuration:")
 131 pr("VPP version" "${VPP_VERSION}")
 132 pr("VPP library version" "${VPP_LIB_VERSION}")
 133 pr("GIT toplevel dir" "${VPP_GIT_TOPLEVEL_DIR}")
 134 pr("C flags" "${CMAKE_C_FLAGS}")
 135 pr("Linker flags" "${CMAKE_LINKER_FLAGS}")
 136 pr("Host processor" "${CMAKE_HOST_SYSTEM_PROCESSOR}")
 137 pr("Target processor" "${CMAKE_SYSTEM_PROCESSOR}")
 138 pr("Build type" "${CMAKE_BUILD_TYPE}")
 139 pr("Prefix path" "${CMAKE_PREFIX_PATH}")
 140 pr("Install prefix" "${CMAKE_INSTALL_PREFIX}")
 141