src/cmake/api.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # API
  16 ##############################################################################
  17 function(vpp_generate_api_c_header file)
  18   set (output_name ${CMAKE_CURRENT_BINARY_DIR}/${file}.h)
  19   get_filename_component(output_dir ${output_name} DIRECTORY)
  20   if(NOT VPP_APIGEN)
  21      set(VPP_APIGEN ${CMAKE_SOURCE_DIR}/tools/vppapigen/vppapigen)
  22   endif()
  23   if (VPP_INCLUDE_DIR)
  24     set(includedir "--includedir" ${VPP_INCLUDE_DIR})
  25   endif()
  26
  27   set(OUTPUT_HEADERS
  28     "${CMAKE_CURRENT_BINARY_DIR}/${file}.h"
  29     "${CMAKE_CURRENT_BINARY_DIR}/${file}_fromjson.h"
  30     "${CMAKE_CURRENT_BINARY_DIR}/${file}_tojson.h"
  31     "${CMAKE_CURRENT_BINARY_DIR}/${file}_enum.h"
  32     "${CMAKE_CURRENT_BINARY_DIR}/${file}_types.h"
  33     "${CMAKE_CURRENT_BINARY_DIR}/${file}.c"
  34     "${CMAKE_CURRENT_BINARY_DIR}/${file}_test.c"
  35     "${CMAKE_CURRENT_BINARY_DIR}/${file}_test2.c"
  36   )
  37
  38   add_custom_command (
  39     OUTPUT ${OUTPUT_HEADERS}
  40     COMMAND mkdir -p ${output_dir}
  41     COMMAND ${VPP_APIGEN}
  42     ARGS ${includedir} --includedir ${CMAKE_SOURCE_DIR} --input ${CMAKE_CURRENT_SOURCE_DIR}/${file} --outputdir ${output_dir} --output ${output_name}
  43     DEPENDS ${VPP_APIGEN} ${CMAKE_CURRENT_SOURCE_DIR}/${file}
  44     COMMENT "Generating API header ${output_name}"
  45   )
  46   get_filename_component(barename ${file} NAME)
  47   set(t ${barename}_deps)
  48   if (NOT TARGET ${t})
  49     add_custom_target(${t} ALL DEPENDS ${OUTPUT_HEADERS})
  50     add_dependencies(api_headers ${t})
  51   endif()
  52
  53 endfunction()
  54
  55 function(vpp_generate_api_json_header file dir component)
  56   set (output_name ${CMAKE_CURRENT_BINARY_DIR}/${file}.json)
  57   get_filename_component(output_dir ${output_name} DIRECTORY)
  58   if(NOT VPP_APIGEN)
  59      set(VPP_APIGEN ${CMAKE_SOURCE_DIR}/tools/vppapigen/vppapigen)
  60   endif()
  61   if (VPP_INCLUDE_DIR)
  62     set(includedir "--includedir" ${VPP_INCLUDE_DIR})
  63   endif()
  64   add_custom_command (OUTPUT ${output_name}
  65     COMMAND mkdir -p ${output_dir}
  66     COMMAND ${VPP_APIGEN}
  67     ARGS ${includedir} --includedir ${CMAKE_SOURCE_DIR} --input ${CMAKE_CURRENT_SOURCE_DIR}/${file} JSON --output ${output_name}
  68     DEPENDS ${VPP_APIGEN} ${CMAKE_CURRENT_SOURCE_DIR}/${file}
  69     COMMENT "Generating API header ${output_name}"
  70   )
  71   install(
  72     FILES ${output_name}
  73     DESTINATION share/vpp/api/${dir}/
  74     COMPONENT ${component}
  75   )
  76 endfunction()
  77
  78 ##############################################################################
  79 # VPP-API
  80 ##############################################################################
  81 function(vpp_generate_vapi_c_header f)
  82   get_filename_component(output ${f}.vapi.h NAME)
  83   set (output_name ${VPP_BINARY_DIR}/vpp-api/vapi/${output})
  84   if(NOT VPP_VAPI_C_GEN)
  85     set(VPP_VAPI_C_GEN ${CMAKE_SOURCE_DIR}/vpp-api/vapi/vapi_c_gen.py)
  86     set(VPP_VAPI_C_GEN_DEPENDS
  87         ${CMAKE_SOURCE_DIR}/vpp-api/vapi/vapi_c_gen.py
  88         ${CMAKE_SOURCE_DIR}/vpp-api/vapi/vapi_json_parser.py
  89     )
  90   endif()
  91
  92   # C VAPI Headers
  93   set(input ${CMAKE_CURRENT_BINARY_DIR}/${f}.json)
  94   add_custom_command(
  95     OUTPUT ${output_name}
  96     WORKING_DIRECTORY ${VPP_BINARY_DIR}/vpp-api/vapi
  97     COMMAND ${VPP_VAPI_C_GEN}
  98     ARGS --remove-path ${input}
  99     DEPENDS ${input} ${VPP_VAPI_C_GEN_DEPENDS}
 100     COMMENT "Generating VAPI C header ${output_name}"
 101   )
 102   install(
 103     FILES ${output_name}
 104     DESTINATION include/vapi
 105     COMPONENT vpp-dev
 106   )
 107 endfunction ()
 108
 109 function (vpp_generate_vapi_cpp_header f)
 110   get_filename_component(output ${f}.vapi.hpp NAME)
 111   set (output_name ${VPP_BINARY_DIR}/vpp-api/vapi/${output})
 112   if(NOT VPP_VAPI_CPP_GEN)
 113     set(VPP_VAPI_CPP_GEN ${CMAKE_SOURCE_DIR}/vpp-api/vapi/vapi_cpp_gen.py)
 114     set(VPP_VAPI_CPP_GEN_DEPENDS
 115         ${CMAKE_SOURCE_DIR}/vpp-api/vapi/vapi_cpp_gen.py
 116         ${CMAKE_SOURCE_DIR}/vpp-api/vapi/vapi_json_parser.py
 117     )
 118   endif()
 119   # C++ VAPI Headers
 120   set(input ${CMAKE_CURRENT_BINARY_DIR}/${f}.json)
 121   add_custom_command(
 122     OUTPUT ${output_name}
 123     WORKING_DIRECTORY ${VPP_BINARY_DIR}/vpp-api/vapi
 124     COMMAND ${VPP_VAPI_CPP_GEN}
 125     ARGS --gen-h-prefix=vapi --remove-path ${input}
 126     DEPENDS ${input} ${VPP_VAPI_CPP_GEN_DEPENDS}
 127     COMMENT "Generating VAPI C++ header ${output_name}"
 128   )
 129   install(
 130     FILES ${output_name}
 131     DESTINATION include/vapi
 132     COMPONENT vpp-dev
 133   )
 134 endfunction ()
 135
 136
 137 ##############################################################################
 138 # generate the .h and .json files for a .api file
 139 #  @param file - the name of the .api
 140 #  @param dir  - the install directory under ROOT/share/vpp/api to place the
 141 #                generated .json file
 142 ##############################################################################
 143 function(vpp_generate_api_header file dir component)
 144   vpp_generate_api_c_header (${file})
 145   vpp_generate_api_json_header (${file} ${dir} ${component})
 146   vpp_generate_vapi_c_header (${file})
 147   vpp_generate_vapi_cpp_header (${file})
 148 endfunction()
 149
 150 function(vpp_add_api_files name dir component)
 151   unset(header_files)
 152   set(target ${name}_api_headers)
 153   file(RELATIVE_PATH rpath ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
 154   foreach(file ${ARGN})
 155     vpp_generate_api_header (${file} ${dir} ${component})
 156     # Basic api headers get installed in a subdirectory according to
 157     # their component name, but vapi is expected to be found directly under
 158     # "vapi". Both by in-source components (e.g. vpp-api/vapi/vapi.c), and
 159     # out-of-tree plugins use #include <vapi/component.api.vapi.h>.
 160     # ${file} contains the subdirectory, so strip it here.
 161     get_filename_component(name ${file} NAME)
 162     list(APPEND header_files
 163       ${file}.h
 164       ${file}_enum.h
 165       ${file}_types.h
 166       ${file}.json
 167       ${VPP_BINARY_DIR}/vpp-api/vapi/${name}.vapi.h
 168       ${VPP_BINARY_DIR}/vpp-api/vapi/${name}.vapi.hpp
 169     )
 170   endforeach()
 171   add_custom_target(${target} DEPENDS ${header_files})
 172   add_dependencies(api_headers ${target})
 173 endfunction()
 174
 175 add_custom_target(api_headers
 176   DEPENDS vlibmemory_api_headers vnet_api_headers vpp_api_headers vlib_api_headers
 177 )