src/cmake/library.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_library lib)
  15   cmake_parse_arguments(ARG
  16     "LTO"
  17     "COMPONENT"
  18     "SOURCES;MULTIARCH_SOURCES;API_FILES;LINK_LIBRARIES;INSTALL_HEADERS;DEPENDS"
  19     ${ARGN}
  20   )
  21
  22   set (lo ${lib}_objs)
  23   add_library(${lo} OBJECT ${ARG_SOURCES})
  24   set_target_properties(${lo} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  25
  26   add_library(${lib} SHARED)
  27   target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${lo}>)
  28
  29   if(VPP_LIB_VERSION)
  30     set_target_properties(${lib} PROPERTIES SOVERSION ${VPP_LIB_VERSION})
  31   endif()
  32
  33   # library deps
  34   if(ARG_LINK_LIBRARIES)
  35     target_link_libraries(${lib} ${ARG_LINK_LIBRARIES})
  36   endif()
  37   # install .so
  38   if(NOT ARG_COMPONENT)
  39     set(ARG_COMPONENT vpp)
  40   endif()
  41   install(
  42     TARGETS ${lib}
  43     DESTINATION ${VPP_LIBRARY_DIR}
  44     COMPONENT ${ARG_COMPONENT}
  45   )
  46
  47   if (ARG_LTO AND VPP_USE_LTO)
  48      set_property(TARGET ${lo} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
  49      set_property(TARGET ${lib} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
  50      target_compile_options (${lib} PRIVATE "-ffunction-sections")
  51      target_compile_options (${lib} PRIVATE "-fdata-sections")
  52      target_link_libraries (${lib} "-Wl,--gc-sections")
  53   endif()
  54
  55   if(ARG_MULTIARCH_SOURCES)
  56     vpp_library_set_multiarch_sources(${lib} DEPENDS ${ARG_DEPENDS} SOURCES ${ARG_MULTIARCH_SOURCES})
  57   endif()
  58
  59   if(ARG_API_FILES)
  60     vpp_add_api_files(${lib} core vpp ${ARG_API_FILES})
  61     foreach(file ${ARG_API_FILES})
  62       get_filename_component(dir ${file} DIRECTORY)
  63       install(
  64         FILES ${file} ${CMAKE_CURRENT_BINARY_DIR}/${file}.h
  65         ${CMAKE_CURRENT_BINARY_DIR}/${file}_enum.h
  66         ${CMAKE_CURRENT_BINARY_DIR}/${file}_types.h
  67         ${CMAKE_CURRENT_BINARY_DIR}/${file}_tojson.h
  68         ${CMAKE_CURRENT_BINARY_DIR}/${file}_fromjson.h
  69         DESTINATION include/${lib}/${dir}
  70         COMPONENT vpp-dev
  71       )
  72     endforeach()
  73   endif()
  74
  75   if(NOT VPP_EXTERNAL_PROJECT)
  76     add_dependencies(${lo} api_headers)
  77   endif()
  78
  79   if(ARG_DEPENDS)
  80     add_dependencies(${lo} ${ARG_DEPENDS})
  81   endif()
  82
  83   # install headers
  84   if(ARG_INSTALL_HEADERS)
  85     foreach(file ${ARG_INSTALL_HEADERS})
  86       get_filename_component(dir ${file} DIRECTORY)
  87       install(
  88         FILES ${file}
  89         DESTINATION include/${lib}/${dir}
  90         COMPONENT ${ARG_COMPONENT}-dev
  91       )
  92     endforeach()
  93   endif()
  94 endmacro()
  95
  96 ##############################################################################
  97 # header files
  98 ##############################################################################
  99 function (add_vpp_headers path)
 100   foreach(file ${ARGN})
 101     get_filename_component(dir ${file} DIRECTORY)
 102     install(
 103       FILES ${file}
 104       DESTINATION include/${path}/${dir}
 105       COMPONENT vpp-dev
 106     )
 107   endforeach()
 108 endfunction()
 109
 110 macro(add_vpp_test_library lib)
 111   cmake_parse_arguments(TEST
 112     ""
 113     ""
 114     ${ARGN}
 115   )
 116
 117   foreach(file ${ARGN})
 118     get_filename_component(name ${file} NAME_WE)
 119     set(test_lib ${lib}_${name}_plugin)
 120     add_library(${test_lib} SHARED ${file}_test2.c)
 121     if(NOT VPP_EXTERNAL_PROJECT)
 122       add_dependencies(${test_lib} api_headers)
 123     endif()
 124     include_directories(${CMAKE_CURRENT_BINARY_DIR})
 125     set_target_properties(${test_lib} PROPERTIES NO_SONAME 1)
 126     set_target_properties(${test_lib} PROPERTIES
 127       PREFIX ""
 128       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vat2_plugins)
 129
 130     # Later: Install and package
 131     # install .so
 132     #install(
 133     #  TARGETS ${test_lib}
 134     #  DESTINATION ${VPP_LIBRARY_DIR}/vat2_plugins
 135     #  #COMPONENT ${ARG_COMPONENT}
 136     #  )
 137   endforeach()
 138 endmacro()