src/cmake/library.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_library lib)
  15   cmake_parse_arguments(ARG
  16     "LTO"
  17     "COMPONENT"
  18     "SOURCES;MULTIARCH_SOURCES;API_FILES;LINK_LIBRARIES;INSTALL_HEADERS;DEPENDS"
  19     ${ARGN}
  20   )
  21
  22   set (lo ${lib}_objs)
  23   add_library(${lo} OBJECT ${ARG_SOURCES})
  24   set_target_properties(${lo} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  25   target_compile_options(${lo} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
  26
  27   add_library(${lib} SHARED)
  28   target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${lo}>)
  29
  30   if(VPP_LIB_VERSION)
  31     set_target_properties(${lib} PROPERTIES SOVERSION ${VPP_LIB_VERSION})
  32   endif()
  33
  34   # library deps
  35   if(ARG_LINK_LIBRARIES)
  36     target_link_libraries(${lib} ${ARG_LINK_LIBRARIES})
  37   endif()
  38   # install .so
  39   if(NOT ARG_COMPONENT)
  40     set(ARG_COMPONENT vpp)
  41   endif()
  42   install(
  43     TARGETS ${lib}
  44     DESTINATION ${VPP_LIBRARY_DIR}
  45     COMPONENT ${ARG_COMPONENT}
  46   )
  47
  48   if (ARG_LTO AND VPP_USE_LTO)
  49      set_property(TARGET ${lo} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
  50      set_property(TARGET ${lib} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
  51      target_compile_options (${lib} PRIVATE "-ffunction-sections")
  52      target_compile_options (${lib} PRIVATE "-fdata-sections")
  53      target_link_libraries (${lib} "-Wl,--gc-sections")
  54      if(compiler_flag_no_stringop_overflow)
  55        target_link_libraries (${lib} "-Wno-stringop-overflow")
  56      endif()
  57   endif()
  58
  59   if(ARG_MULTIARCH_SOURCES)
  60     vpp_library_set_multiarch_sources(${lib} DEPENDS ${ARG_DEPENDS} SOURCES ${ARG_MULTIARCH_SOURCES})
  61   endif()
  62
  63   if(ARG_API_FILES)
  64     vpp_add_api_files(${lib} core vpp ${ARG_API_FILES})
  65     foreach(file ${ARG_API_FILES})
  66       get_filename_component(dir ${file} DIRECTORY)
  67       install(
  68         FILES ${file} ${CMAKE_CURRENT_BINARY_DIR}/${file}.h
  69         ${CMAKE_CURRENT_BINARY_DIR}/${file}_enum.h
  70         ${CMAKE_CURRENT_BINARY_DIR}/${file}_types.h
  71         ${CMAKE_CURRENT_BINARY_DIR}/${file}_tojson.h
  72         ${CMAKE_CURRENT_BINARY_DIR}/${file}_fromjson.h
  73         DESTINATION include/${lib}/${dir}
  74         COMPONENT vpp-dev
  75       )
  76     endforeach()
  77   endif()
  78
  79   if(NOT VPP_EXTERNAL_PROJECT)
  80     add_dependencies(${lo} api_headers)
  81   endif()
  82
  83   if(ARG_DEPENDS)
  84     add_dependencies(${lo} ${ARG_DEPENDS})
  85   endif()
  86
  87   # install headers
  88   if(ARG_INSTALL_HEADERS)
  89     foreach(file ${ARG_INSTALL_HEADERS})
  90       get_filename_component(dir ${file} DIRECTORY)
  91       install(
  92         FILES ${file}
  93         DESTINATION include/${lib}/${dir}
  94         COMPONENT ${ARG_COMPONENT}-dev
  95       )
  96     endforeach()
  97   endif()
  98 endmacro()
  99
 100 ##############################################################################
 101 # header files
 102 ##############################################################################
 103 function (add_vpp_headers path)
 104   foreach(file ${ARGN})
 105     get_filename_component(dir ${file} DIRECTORY)
 106     install(
 107       FILES ${file}
 108       DESTINATION include/${path}/${dir}
 109       COMPONENT vpp-dev
 110     )
 111   endforeach()
 112 endfunction()
 113
 114 macro(add_vat_test_library lib)
 115   cmake_parse_arguments(TEST
 116     ""
 117     ""
 118     ${ARGN}
 119   )
 120
 121   foreach(file ${ARGN})
 122     get_filename_component(name ${file} NAME_WE)
 123     set(test_lib ${lib}_${name}_plugin)
 124     add_library(${test_lib} SHARED ${file})
 125     target_compile_options(${test_lib} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
 126     if(NOT VPP_EXTERNAL_PROJECT)
 127       add_dependencies(${test_lib} api_headers)
 128     endif()
 129     include_directories(${CMAKE_CURRENT_BINARY_DIR})
 130     set_target_properties(${test_lib} PROPERTIES NO_SONAME 1)
 131     set_target_properties(${test_lib} PROPERTIES
 132       PREFIX ""
 133       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
 134
 135     # install .so
 136     install(
 137       TARGETS ${test_lib}
 138       DESTINATION ${VPP_LIBRARY_DIR}/vpp_api_test_plugins
 139       COMPONENT ${ARG_COMPONENT}
 140     )
 141   endforeach()
 142 endmacro()
 143
 144 macro(add_vpp_test_library lib)
 145   cmake_parse_arguments(TEST
 146     ""
 147     ""
 148     ${ARGN}
 149   )
 150
 151   foreach(file ${ARGN})
 152     get_filename_component(name ${file} NAME_WE)
 153     set(test_lib ${lib}_${name}_plugin)
 154     add_library(${test_lib} SHARED ${file}_test2.c)
 155     target_compile_options(${test_lib} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
 156     if(NOT VPP_EXTERNAL_PROJECT)
 157       add_dependencies(${test_lib} api_headers)
 158     endif()
 159     include_directories(${CMAKE_CURRENT_BINARY_DIR})
 160     set_target_properties(${test_lib} PROPERTIES NO_SONAME 1)
 161     set_target_properties(${test_lib} PROPERTIES
 162       PREFIX ""
 163       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vat2_plugins)
 164
 165     # install .so
 166     install(
 167       TARGETS ${test_lib}
 168       DESTINATION ${VPP_LIBRARY_DIR}/vat2_plugins
 169       COMPONENT ${ARG_COMPONENT}
 170     )
 171   endforeach()
 172 endmacro()
 173
 174 macro(vpp_find_library var)
 175   find_library(${var} ${ARGN})
 176   mark_as_advanced(${var})
 177 endmacro()
 178 macro(vpp_find_path var)
 179   find_path(${var} ${ARGN})
 180   mark_as_advanced(${var})
 181 endmacro()