src/cmake/library.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_library lib)
  15   cmake_parse_arguments(ARG
  16     "LTO"
  17     "COMPONENT"
  18     "SOURCES;MULTIARCH_SOURCES;API_FILES;LINK_LIBRARIES;INSTALL_HEADERS;DEPENDS"
  19     ${ARGN}
  20   )
  21
  22   set (lo ${lib}_objs)
  23   add_library(${lo} OBJECT ${ARG_SOURCES})
  24   set_target_properties(${lo} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  25   target_compile_options(${lo} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
  26
  27   add_library(${lib} SHARED)
  28   target_sources(${lib} PRIVATE $<TARGET_OBJECTS:${lo}>)
  29
  30   if(VPP_LIB_VERSION)
  31     set_target_properties(${lib} PROPERTIES SOVERSION ${VPP_LIB_VERSION})
  32   endif()
  33
  34   # library deps
  35   if(ARG_LINK_LIBRARIES)
  36     target_link_libraries(${lib} ${ARG_LINK_LIBRARIES})
  37   endif()
  38   # install .so
  39   if(NOT ARG_COMPONENT)
  40     set(ARG_COMPONENT vpp)
  41   endif()
  42   install(
  43     TARGETS ${lib}
  44     LIBRARY
  45       DESTINATION ${VPP_LIBRARY_DIR}
  46       COMPONENT ${ARG_COMPONENT}
  47       NAMELINK_COMPONENT ${ARG_COMPONENT}-dev
  48   )
  49
  50   if (ARG_LTO AND VPP_USE_LTO)
  51      set_property(TARGET ${lo} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
  52      set_property(TARGET ${lib} PROPERTY INTERPROCEDURAL_OPTIMIZATION TRUE)
  53      target_compile_options (${lib} PRIVATE "-ffunction-sections")
  54      target_compile_options (${lib} PRIVATE "-fdata-sections")
  55      target_link_libraries (${lib} "-Wl,--gc-sections")
  56      if(compiler_flag_no_stringop_overflow)
  57        target_link_libraries (${lib} "-Wno-stringop-overflow")
  58      endif()
  59   endif()
  60
  61   if(ARG_MULTIARCH_SOURCES)
  62     vpp_library_set_multiarch_sources(${lib} DEPENDS ${ARG_DEPENDS} SOURCES ${ARG_MULTIARCH_SOURCES})
  63   endif()
  64
  65   if(ARG_API_FILES)
  66     vpp_add_api_files(${lib} core vpp ${ARG_API_FILES})
  67     foreach(file ${ARG_API_FILES})
  68       get_filename_component(dir ${file} DIRECTORY)
  69       install(
  70         FILES ${file} ${CMAKE_CURRENT_BINARY_DIR}/${file}.h
  71         ${CMAKE_CURRENT_BINARY_DIR}/${file}_enum.h
  72         ${CMAKE_CURRENT_BINARY_DIR}/${file}_types.h
  73         ${CMAKE_CURRENT_BINARY_DIR}/${file}_tojson.h
  74         ${CMAKE_CURRENT_BINARY_DIR}/${file}_fromjson.h
  75         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${lib}/${dir}
  76         COMPONENT vpp-dev
  77       )
  78     endforeach()
  79   endif()
  80
  81   if(NOT VPP_EXTERNAL_PROJECT)
  82     add_dependencies(${lo} api_headers)
  83   endif()
  84
  85   if(VPP_EXTERNAL_PROJECT AND ARG_API_FILES)
  86     add_dependencies(${lo} ${lib}_api_headers)
  87   endif()
  88
  89   if(ARG_DEPENDS)
  90     add_dependencies(${lo} ${ARG_DEPENDS})
  91   endif()
  92
  93   # install headers
  94   if(ARG_INSTALL_HEADERS)
  95     foreach(file ${ARG_INSTALL_HEADERS})
  96       get_filename_component(dir ${file} DIRECTORY)
  97       install(
  98         FILES ${file}
  99         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${lib}/${dir}
 100         COMPONENT ${ARG_COMPONENT}-dev
 101       )
 102     endforeach()
 103   endif()
 104 endmacro()
 105
 106 ##############################################################################
 107 # header files
 108 ##############################################################################
 109 function (add_vpp_headers path)
 110   foreach(file ${ARGN})
 111     get_filename_component(dir ${file} DIRECTORY)
 112     install(
 113       FILES ${file}
 114       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${path}/${dir}
 115       COMPONENT vpp-dev
 116     )
 117   endforeach()
 118 endfunction()
 119
 120 macro(add_vat_test_library lib)
 121   cmake_parse_arguments(TEST
 122     ""
 123     ""
 124     ${ARGN}
 125   )
 126
 127   foreach(file ${ARGN})
 128     get_filename_component(name ${file} NAME_WE)
 129     set(test_lib ${lib}_${name}_plugin)
 130     add_library(${test_lib} SHARED ${file})
 131     target_compile_options(${test_lib} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
 132     if(NOT VPP_EXTERNAL_PROJECT)
 133       add_dependencies(${test_lib} api_headers)
 134     endif()
 135     include_directories(${CMAKE_CURRENT_BINARY_DIR})
 136     set_target_properties(${test_lib} PROPERTIES NO_SONAME 1)
 137     set_target_properties(${test_lib} PROPERTIES
 138       PREFIX ""
 139       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
 140
 141     # install .so
 142     install(
 143       TARGETS ${test_lib}
 144       DESTINATION ${VPP_LIBRARY_DIR}/vpp_api_test_plugins
 145       COMPONENT ${ARG_COMPONENT}
 146     )
 147   endforeach()
 148 endmacro()
 149
 150 macro(add_vpp_test_library lib)
 151   cmake_parse_arguments(TEST
 152     ""
 153     ""
 154     ${ARGN}
 155   )
 156
 157   foreach(file ${ARGN})
 158     get_filename_component(name ${file} NAME_WE)
 159     set(test_lib ${lib}_${name}_plugin)
 160     add_library(${test_lib} SHARED ${file}_test2.c)
 161     target_compile_options(${test_lib} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
 162     if(NOT VPP_EXTERNAL_PROJECT)
 163       add_dependencies(${test_lib} api_headers)
 164     endif()
 165     include_directories(${CMAKE_CURRENT_BINARY_DIR})
 166     set_target_properties(${test_lib} PROPERTIES NO_SONAME 1)
 167     set_target_properties(${test_lib} PROPERTIES
 168       PREFIX ""
 169       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vat2_plugins)
 170
 171     # install .so
 172     install(
 173       TARGETS ${test_lib}
 174       DESTINATION ${VPP_LIBRARY_DIR}/vat2_plugins
 175       COMPONENT ${ARG_COMPONENT}
 176     )
 177   endforeach()
 178 endmacro()
 179
 180 macro(vpp_find_library var)
 181   find_library(${var} ${ARGN})
 182   mark_as_advanced(${var})
 183 endmacro()
 184 macro(vpp_find_path var)
 185   find_path(${var} ${ARGN})
 186   mark_as_advanced(${var})
 187 endmacro()