src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT;DEV_COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;MULTIARCH_FORCE_ON;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES;VAT_AUTO_TEST"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_includes)
  23   if(NOT PLUGIN_COMPONENT)
  24     set(PLUGIN_COMPONENT vpp-plugin-core)
  25   endif()
  26   if(NOT PLUGIN_DEV_COMPONENT)
  27     if(NOT VPP_EXTERNAL_PROJECT)
  28       set(PLUGIN_DEV_COMPONENT vpp-dev)
  29     else()
  30       set(PLUGIN_DEV_COMPONENT ${PLUGIN_COMPONENT}-dev)
  31     endif()
  32   endif()
  33
  34   vpp_add_api_files(${plugin_name} plugins ${PLUGIN_COMPONENT} ${PLUGIN_API_FILES})
  35   foreach(f ${PLUGIN_API_FILES})
  36     get_filename_component(dir ${f} DIRECTORY)
  37     list(APPEND api_includes ${f}.h ${f}_enum.h ${f}_types.h ${f}.json)
  38     install(
  39       FILES
  40       ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  41       ${CMAKE_CURRENT_BINARY_DIR}/${f}_enum.h
  42       ${CMAKE_CURRENT_BINARY_DIR}/${f}_types.h
  43       DESTINATION include/vpp_plugins/${name}/${dir}
  44       COMPONENT ${PLUGIN_DEV_COMPONENT}
  45     )
  46   endforeach()
  47   add_library(${plugin_name} SHARED ${api_includes} ${PLUGIN_SOURCES})
  48   target_compile_options(${plugin_name} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
  49   set_target_properties(${plugin_name} PROPERTIES NO_SONAME 1)
  50   target_compile_options(${plugin_name} PRIVATE "-fvisibility=hidden")
  51   target_compile_options (${plugin_name} PRIVATE "-ffunction-sections")
  52   target_compile_options (${plugin_name} PRIVATE "-fdata-sections")
  53   target_link_libraries (${plugin_name} "-Wl,--gc-sections")
  54   set(deps "")
  55   if(NOT VPP_EXTERNAL_PROJECT)
  56     list(APPEND deps vpp_version_h api_headers)
  57   endif()
  58   if(PLUGIN_API_FILES)
  59     list(APPEND deps ${plugin_name}_api_headers)
  60   endif()
  61   if(deps)
  62     add_dependencies(${plugin_name} ${deps})
  63   endif()
  64   set_target_properties(${plugin_name} PROPERTIES
  65     PREFIX ""
  66     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  67   if(PLUGIN_MULTIARCH_SOURCES)
  68     vpp_library_set_multiarch_sources(${plugin_name}
  69       SOURCES ${PLUGIN_MULTIARCH_SOURCES}
  70       DEPENDS ${deps}
  71       FORCE_ON ${PLUGIN_MULTIARCH_FORCE_ON}
  72     )
  73   endif()
  74   if(PLUGIN_LINK_LIBRARIES)
  75     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  76   endif()
  77   if(PLUGIN_LINK_FLAGS)
  78     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  79   endif()
  80   if(PLUGIN_INSTALL_HEADERS)
  81     foreach(file ${PLUGIN_INSTALL_HEADERS})
  82       get_filename_component(dir ${file} DIRECTORY)
  83       install(
  84         FILES ${file}
  85         DESTINATION include/vpp_plugins/${name}/${dir}
  86         COMPONENT vpp-dev
  87       )
  88     endforeach()
  89   endif()
  90   if(PLUGIN_API_TEST_SOURCES)
  91     set(test_plugin_name ${name}_test_plugin)
  92     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES}
  93                 ${api_includes})
  94     target_compile_options(${test_plugin_name} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
  95     set_target_properties(${test_plugin_name} PROPERTIES NO_SONAME 1)
  96     if(NOT VPP_EXTERNAL_PROJECT)
  97       add_dependencies(${test_plugin_name} api_headers)
  98     endif()
  99     if(PLUGIN_API_FILES)
 100       add_dependencies(${test_plugin_name} ${plugin_name}_api_headers)
 101     endif()
 102     set_target_properties(${test_plugin_name} PROPERTIES
 103       PREFIX ""
 104       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
 105     install(
 106       TARGETS ${test_plugin_name}
 107       DESTINATION ${VPP_LIBRARY_DIR}/vpp_api_test_plugins
 108       COMPONENT ${PLUGIN_COMPONENT}
 109     )
 110   endif()
 111   if (PLUGIN_API_FILES AND NOT PLUGIN_VAT_AUTO_TEST STREQUAL OFF)
 112     add_vpp_test_library(${name}_test_plugin ${PLUGIN_API_FILES})
 113   endif()
 114
 115   install(
 116     TARGETS ${plugin_name}
 117     DESTINATION ${VPP_LIBRARY_DIR}/vpp_plugins
 118     COMPONENT ${PLUGIN_COMPONENT}
 119   )
 120 endmacro()
 121
 122 macro(vpp_plugin_find_library plugin var name)
 123   find_library(${var} NAMES ${name} ${ARGN})
 124   mark_as_advanced(${var})
 125 if (NOT ${var})
 126   message(WARNING "-- ${name} library not found - ${plugin} plugin disabled")
 127   return()
 128 endif()
 129     message(STATUS "${plugin} plugin needs ${name} library - found at ${${var}}")
 130 endmacro()