src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT;DEV_COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_includes)
  23   if(NOT PLUGIN_COMPONENT)
  24     set(PLUGIN_COMPONENT vpp-plugin-core)
  25   endif()
  26   if(NOT PLUGIN_DEV_COMPONENT)
  27     if(NOT VPP_EXTERNAL_PROJECT)
  28       set(PLUGIN_DEV_COMPONENT vpp-dev)
  29     else()
  30       set(PLUGIN_DEV_COMPONENT ${PLUGIN_COMPONENT}-dev)
  31     endif()
  32   endif()
  33
  34   vpp_add_api_files(${plugin_name} plugins ${PLUGIN_COMPONENT} ${PLUGIN_API_FILES})
  35   foreach(f ${PLUGIN_API_FILES})
  36     get_filename_component(dir ${f} DIRECTORY)
  37     list(APPEND api_includes ${f}.h ${f}.json)
  38     install(
  39       FILES ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  40       ${CMAKE_CURRENT_BINARY_DIR}/${f}_enum.h
  41       ${CMAKE_CURRENT_BINARY_DIR}/${f}_types.h
  42       DESTINATION include/vpp_plugins/${name}/${dir}
  43       COMPONENT ${PLUGIN_DEV_COMPONENT}
  44     )
  45   endforeach()
  46   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_includes})
  47   set_target_properties(${plugin_name} PROPERTIES NO_SONAME 1)
  48   target_compile_options(${plugin_name} PRIVATE "-fvisibility=hidden")
  49   set(deps "")
  50   if(PLUGIN_API_FILES)
  51     list(APPEND deps ${plugin_name}_api_headers)
  52   endif()
  53   if(NOT VPP_EXTERNAL_PROJECT)
  54     list(APPEND deps vpp_version_h api_headers)
  55   endif()
  56   add_dependencies(${plugin_name} ${deps})
  57   set_target_properties(${plugin_name} PROPERTIES
  58     PREFIX ""
  59     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  60   if(PLUGIN_MULTIARCH_SOURCES)
  61     vpp_library_set_multiarch_sources(${plugin_name} "${deps}" ${PLUGIN_MULTIARCH_SOURCES})
  62   endif()
  63   if(PLUGIN_LINK_LIBRARIES)
  64     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  65   endif()
  66   if(PLUGIN_LINK_FLAGS)
  67     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  68   endif()
  69   if(PLUGIN_INSTALL_HEADERS)
  70     foreach(file ${PLUGIN_INSTALL_HEADERS})
  71       get_filename_component(dir ${file} DIRECTORY)
  72       install(
  73         FILES ${file}
  74         DESTINATION include/vpp_plugins/${name}/${dir}
  75         COMPONENT vpp-dev
  76       )
  77     endforeach()
  78   endif()
  79   if(PLUGIN_API_TEST_SOURCES)
  80     set(test_plugin_name ${name}_test_plugin)
  81     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES}
  82                 ${api_includes})
  83     set_target_properties(${test_plugin_name} PROPERTIES NO_SONAME 1)
  84     if(PLUGIN_API_FILES)
  85       add_dependencies(${test_plugin_name} ${plugin_name}_api_headers)
  86     endif()
  87     if(NOT VPP_EXTERNAL_PROJECT)
  88       add_dependencies(${test_plugin_name} api_headers)
  89     endif()
  90     set_target_properties(${test_plugin_name} PROPERTIES
  91       PREFIX ""
  92       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  93     install(
  94       TARGETS ${test_plugin_name}
  95       DESTINATION ${VPP_LIBRARY_DIR}/vpp_api_test_plugins
  96       COMPONENT ${PLUGIN_COMPONENT}
  97     )
  98   endif()
  99   install(
 100     TARGETS ${plugin_name}
 101     DESTINATION ${VPP_LIBRARY_DIR}/vpp_plugins
 102     COMPONENT ${PLUGIN_COMPONENT}
 103   )
 104 endmacro()
 105
 106 macro(vpp_plugin_find_library plugin var name)
 107   find_library(${var} NAMES ${name} ${ARGN})
 108 if (NOT ${var})
 109   message(WARNING "-- ${name} library not found - ${plugin} plugin disabled")
 110   return()
 111 endif()
 112     message(STATUS "${plugin} plugin needs ${name} library - found at ${${var}}")
 113 endmacro()