src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT;DEV_COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES;"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_includes)
  23   if(NOT PLUGIN_COMPONENT)
  24     set(PLUGIN_COMPONENT vpp-plugin-core)
  25   endif()
  26   if(NOT PLUGIN_DEV_COMPONENT)
  27     if(NOT VPP_EXTERNAL_PROJECT)
  28       set(PLUGIN_DEV_COMPONENT vpp-dev)
  29     else()
  30       set(PLUGIN_DEV_COMPONENT ${PLUGIN_COMPONENT}-dev)
  31     endif()
  32   endif()
  33
  34   vpp_add_api_files(${plugin_name} plugins ${PLUGIN_COMPONENT} ${PLUGIN_API_FILES})
  35   foreach(f ${PLUGIN_API_FILES})
  36     get_filename_component(dir ${f} DIRECTORY)
  37     list(APPEND api_includes ${f}.h ${f}_enum.h ${f}_types.h ${f}.json)
  38     install(
  39       FILES
  40       ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  41       ${CMAKE_CURRENT_BINARY_DIR}/${f}_enum.h
  42       ${CMAKE_CURRENT_BINARY_DIR}/${f}_types.h
  43       DESTINATION include/vpp_plugins/${name}/${dir}
  44       COMPONENT ${PLUGIN_DEV_COMPONENT}
  45     )
  46   endforeach()
  47   add_library(${plugin_name} SHARED ${api_includes} ${PLUGIN_SOURCES})
  48   set_target_properties(${plugin_name} PROPERTIES NO_SONAME 1)
  49   target_compile_options(${plugin_name} PRIVATE "-fvisibility=hidden")
  50   target_compile_options (${plugin_name} PRIVATE "-ffunction-sections")
  51   target_compile_options (${plugin_name} PRIVATE "-fdata-sections")
  52   target_link_libraries (${plugin_name} "-Wl,--gc-sections")
  53   set(deps "")
  54   if(NOT VPP_EXTERNAL_PROJECT)
  55     list(APPEND deps vpp_version_h api_headers)
  56   endif()
  57   if(PLUGIN_API_FILES)
  58     list(APPEND deps ${plugin_name}_api_headers)
  59   endif()
  60   if(deps)
  61     add_dependencies(${plugin_name} ${deps})
  62   endif()
  63   set_target_properties(${plugin_name} PROPERTIES
  64     PREFIX ""
  65     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  66   if(PLUGIN_MULTIARCH_SOURCES)
  67     vpp_library_set_multiarch_sources(${plugin_name} SOURCES ${PLUGIN_MULTIARCH_SOURCES} DEPENDS ${deps})
  68   endif()
  69   if(PLUGIN_LINK_LIBRARIES)
  70     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  71   endif()
  72   if(PLUGIN_LINK_FLAGS)
  73     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  74   endif()
  75   if(PLUGIN_INSTALL_HEADERS)
  76     foreach(file ${PLUGIN_INSTALL_HEADERS})
  77       get_filename_component(dir ${file} DIRECTORY)
  78       install(
  79         FILES ${file}
  80         DESTINATION include/vpp_plugins/${name}/${dir}
  81         COMPONENT vpp-dev
  82       )
  83     endforeach()
  84   endif()
  85   if(PLUGIN_API_TEST_SOURCES)
  86     set(test_plugin_name ${name}_test_plugin)
  87     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES}
  88                 ${api_includes})
  89     set_target_properties(${test_plugin_name} PROPERTIES NO_SONAME 1)
  90     if(NOT VPP_EXTERNAL_PROJECT)
  91       add_dependencies(${test_plugin_name} api_headers)
  92     endif()
  93     if(PLUGIN_API_FILES)
  94       add_dependencies(${test_plugin_name} ${plugin_name}_api_headers)
  95     endif()
  96     set_target_properties(${test_plugin_name} PROPERTIES
  97       PREFIX ""
  98       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  99     install(
 100       TARGETS ${test_plugin_name}
 101       DESTINATION ${VPP_LIBRARY_DIR}/vpp_api_test_plugins
 102       COMPONENT ${PLUGIN_COMPONENT}
 103     )
 104   endif()
 105   if (PLUGIN_API_FILES)
 106     add_vpp_test_library(${name}_test_plugin ${PLUGIN_API_FILES})
 107   endif()
 108
 109   install(
 110     TARGETS ${plugin_name}
 111     DESTINATION ${VPP_LIBRARY_DIR}/vpp_plugins
 112     COMPONENT ${PLUGIN_COMPONENT}
 113   )
 114 endmacro()
 115
 116 macro(vpp_plugin_find_library plugin var name)
 117   find_library(${var} NAMES ${name} ${ARGN})
 118   mark_as_advanced(${var})
 119 if (NOT ${var})
 120   message(WARNING "-- ${name} library not found - ${plugin} plugin disabled")
 121   return()
 122 endif()
 123     message(STATUS "${plugin} plugin needs ${name} library - found at ${${var}}")
 124 endmacro()