src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_includes)
  23   if(NOT PLUGIN_COMPONENT)
  24     set(PLUGIN_COMPONENT vpp-plugin-misc)
  25   endif()
  26   file(RELATIVE_PATH rpath ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  27   foreach(f ${PLUGIN_API_FILES})
  28     get_filename_component(dir ${f} DIRECTORY)
  29     vpp_generate_api_header(${f} plugins ${PLUGIN_COMPONENT})
  30     list(APPEND api_includes ${f}.h ${f}.json)
  31     set_property(GLOBAL APPEND PROPERTY VPP_API_FILES ${rpath}/${f})
  32     install(
  33       FILES ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  34       DESTINATION include/vpp_plugins/${name}/${dir}
  35       COMPONENT vpp-dev
  36     )
  37   endforeach()
  38   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_includes})
  39   target_compile_options(${plugin_name} PRIVATE -Wall)
  40   if(NOT VPP_EXTERNAL_PROJECT)
  41     add_dependencies(${plugin_name} vpp_version_h api_headers)
  42   endif()
  43   set_target_properties(${plugin_name} PROPERTIES
  44     PREFIX ""
  45     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  46   if(PLUGIN_MULTIARCH_SOURCES)
  47     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  48   endif()
  49   if(PLUGIN_LINK_LIBRARIES)
  50     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  51   endif()
  52   if(PLUGIN_LINK_FLAGS)
  53     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  54   endif()
  55   if(PLUGIN_INSTALL_HEADERS)
  56     foreach(file ${PLUGIN_INSTALL_HEADERS})
  57       get_filename_component(dir ${file} DIRECTORY)
  58       install(
  59         FILES ${file}
  60         DESTINATION include/vpp_plugins/${name}/${dir}
  61         COMPONENT vpp-dev
  62       )
  63     endforeach()
  64   endif()
  65   if(PLUGIN_API_TEST_SOURCES)
  66     set(test_plugin_name ${name}_test_plugin)
  67     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES}
  68                 ${api_includes})
  69     if(NOT VPP_EXTERNAL_PROJECT)
  70       add_dependencies(${test_plugin_name} api_headers)
  71     endif()
  72     set_target_properties(${test_plugin_name} PROPERTIES
  73       PREFIX ""
  74       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  75     install(
  76       TARGETS ${test_plugin_name}
  77       DESTINATION lib/vpp_api_test_plugins
  78       COMPONENT ${PLUGIN_COMPONENT}
  79     )
  80   endif()
  81   install(
  82     TARGETS ${plugin_name}
  83     DESTINATION lib/vpp_plugins
  84     COMPONENT ${PLUGIN_COMPONENT}
  85   )
  86 endmacro()
  87