src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES"
  19     ${ARGN}
  20   )
  21   set(plugin_name ${name}_plugin)
  22   set(api_headers)
  23   file(RELATIVE_PATH rpath ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  24   foreach(f ${PLUGIN_API_FILES})
  25     get_filename_component(dir ${f} DIRECTORY)
  26     vpp_generate_api_header(${f} plugins)
  27     list(APPEND api_headers ${f}.h ${f}.json)
  28     set_property(GLOBAL APPEND PROPERTY VPP_API_FILES ${rpath}/${f})
  29     install(
  30       FILES ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  31       DESTINATION include/vpp_plugins/${name}/${dir}
  32       COMPONENT vpp-dev
  33     )
  34   endforeach()
  35   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_headers})
  36   target_compile_options(${plugin_name} PRIVATE -Wall)
  37   add_dependencies(${plugin_name} vpp_version_h api_headers)
  38   set_target_properties(${plugin_name} PROPERTIES
  39     PREFIX ""
  40     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  41   if(PLUGIN_MULTIARCH_SOURCES)
  42     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  43   endif()
  44   if(PLUGIN_LINK_LIBRARIES)
  45     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  46   endif()
  47   if(PLUGIN_LINK_FLAGS)
  48     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  49   endif()
  50   if(PLUGIN_INSTALL_HEADERS)
  51     foreach(file ${PLUGIN_INSTALL_HEADERS})
  52       get_filename_component(dir ${file} DIRECTORY)
  53       install(
  54         FILES ${file}
  55         DESTINATION include/vpp_plugins/${name}/${dir}
  56         COMPONENT vpp-dev
  57       )
  58     endforeach()
  59   endif()
  60   if(NOT PLUGIN_COMPONENT)
  61     set(PLUGIN_COMPONENT vpp-plugin-misc)
  62   endif()
  63   if(PLUGIN_API_TEST_SOURCES)
  64     set(test_plugin_name ${name}_test_plugin)
  65     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES} ${api_headers})
  66     add_dependencies(${test_plugin_name} api_headers)
  67     set_target_properties(${test_plugin_name} PROPERTIES
  68       PREFIX ""
  69       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  70     install(
  71       TARGETS ${test_plugin_name}
  72       DESTINATION ${VPP_LIB_DIR_NAME}/vpp_api_test_plugins
  73       COMPONENT ${PLUGIN_COMPONENT}
  74     )
  75   endif()
  76   install(
  77     TARGETS ${plugin_name}
  78     DESTINATION ${VPP_LIB_DIR_NAME}/vpp_plugins
  79     COMPONENT ${PLUGIN_COMPONENT}
  80   )
  81 endmacro()
  82