src/cmake/plugin.cmake

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 macro(add_vpp_plugin name)
  15   cmake_parse_arguments(PLUGIN
  16     ""
  17     "LINK_FLAGS;COMPONENT;DEV_COMPONENT"
  18     "SOURCES;API_FILES;MULTIARCH_SOURCES;MULTIARCH_FORCE_ON;LINK_LIBRARIES;INSTALL_HEADERS;API_TEST_SOURCES;VAT_AUTO_TEST;SUPPORTED_OS_LIST"
  19     ${ARGN}
  20   )
  21   if (PLUGIN_SUPPORTED_OS_LIST AND NOT ${CMAKE_SYSTEM_NAME} IN_LIST PLUGIN_SUPPORTED_OS_LIST)
  22     message(WARNING "unsupported OS - ${name} plugin disabled")
  23     return()
  24   endif()
  25   set(plugin_name ${name}_plugin)
  26   set(api_includes)
  27   if(NOT PLUGIN_COMPONENT)
  28     set(PLUGIN_COMPONENT vpp-plugin-core)
  29   endif()
  30   if(NOT PLUGIN_DEV_COMPONENT)
  31     if(NOT VPP_EXTERNAL_PROJECT)
  32       set(PLUGIN_DEV_COMPONENT vpp-dev)
  33     else()
  34       set(PLUGIN_DEV_COMPONENT ${PLUGIN_COMPONENT}-dev)
  35     endif()
  36   endif()
  37
  38   vpp_add_api_files(${plugin_name} plugins ${PLUGIN_COMPONENT} ${PLUGIN_API_FILES})
  39   foreach(f ${PLUGIN_API_FILES})
  40     get_filename_component(dir ${f} DIRECTORY)
  41     list(APPEND api_includes ${f}.h ${f}_enum.h ${f}_types.h ${f}.json)
  42     install(
  43       FILES
  44       ${CMAKE_CURRENT_BINARY_DIR}/${f}.h
  45       ${CMAKE_CURRENT_BINARY_DIR}/${f}_enum.h
  46       ${CMAKE_CURRENT_BINARY_DIR}/${f}_types.h
  47       DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/vpp_plugins/${name}/${dir}
  48       COMPONENT ${PLUGIN_DEV_COMPONENT}
  49     )
  50   endforeach()
  51   add_library(${plugin_name} SHARED ${api_includes} ${PLUGIN_SOURCES})
  52   target_compile_options(${plugin_name} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
  53   set_target_properties(${plugin_name} PROPERTIES NO_SONAME 1)
  54   target_compile_options(${plugin_name} PRIVATE "-fvisibility=hidden")
  55   target_compile_options (${plugin_name} PRIVATE "-ffunction-sections")
  56   target_compile_options (${plugin_name} PRIVATE "-fdata-sections")
  57   target_link_libraries (${plugin_name} "-Wl,--gc-sections")
  58   set(deps "")
  59   if(NOT VPP_EXTERNAL_PROJECT)
  60     list(APPEND deps vpp_version_h api_headers)
  61   endif()
  62   if(PLUGIN_API_FILES)
  63     list(APPEND deps ${plugin_name}_api_headers)
  64   endif()
  65   if(deps)
  66     add_dependencies(${plugin_name} ${deps})
  67   endif()
  68   set_target_properties(${plugin_name} PROPERTIES
  69     PREFIX ""
  70     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  71   if(PLUGIN_MULTIARCH_SOURCES)
  72     vpp_library_set_multiarch_sources(${plugin_name}
  73       SOURCES ${PLUGIN_MULTIARCH_SOURCES}
  74       DEPENDS ${deps}
  75       FORCE_ON ${PLUGIN_MULTIARCH_FORCE_ON}
  76     )
  77   endif()
  78   if(PLUGIN_LINK_LIBRARIES)
  79     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  80   endif()
  81   if(PLUGIN_LINK_FLAGS)
  82     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  83   endif()
  84   if(PLUGIN_INSTALL_HEADERS)
  85     foreach(file ${PLUGIN_INSTALL_HEADERS})
  86       get_filename_component(dir ${file} DIRECTORY)
  87       install(
  88         FILES ${file}
  89         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/vpp_plugins/${name}/${dir}
  90         COMPONENT vpp-dev
  91       )
  92     endforeach()
  93   endif()
  94   if(PLUGIN_API_TEST_SOURCES)
  95     set(test_plugin_name ${name}_test_plugin)
  96     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES}
  97                 ${api_includes})
  98     target_compile_options(${test_plugin_name} PUBLIC ${VPP_DEFAULT_MARCH_FLAGS})
  99     set_target_properties(${test_plugin_name} PROPERTIES NO_SONAME 1)
 100     if(NOT VPP_EXTERNAL_PROJECT)
 101       add_dependencies(${test_plugin_name} api_headers)
 102     endif()
 103     if(PLUGIN_API_FILES)
 104       add_dependencies(${test_plugin_name} ${plugin_name}_api_headers)
 105     endif()
 106     set_target_properties(${test_plugin_name} PROPERTIES
 107       PREFIX ""
 108       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
 109     install(
 110       TARGETS ${test_plugin_name}
 111       DESTINATION ${VPP_LIBRARY_DIR}/vpp_api_test_plugins
 112       COMPONENT ${PLUGIN_COMPONENT}
 113     )
 114   endif()
 115   if (PLUGIN_API_FILES AND NOT PLUGIN_VAT_AUTO_TEST STREQUAL OFF)
 116     add_vpp_test_library(${name}_test_plugin ${PLUGIN_API_FILES})
 117   endif()
 118
 119   install(
 120     TARGETS ${plugin_name}
 121     DESTINATION ${VPP_LIBRARY_DIR}/vpp_plugins
 122     COMPONENT ${PLUGIN_COMPONENT}
 123   )
 124 endmacro()
 125
 126 macro(vpp_plugin_find_library plugin var name)
 127   find_library(${var} NAMES ${name} ${ARGN})
 128   mark_as_advanced(${var})
 129 if (NOT ${var})
 130   message(WARNING "-- ${name} library not found - ${plugin} plugin disabled")
 131   return()
 132 endif()
 133     message(STATUS "${plugin} plugin needs ${name} library - found at ${${var}}")
 134 endmacro()