src/configure.ac

   1 AC_INIT([vpp], [18.01], [vpp-dev@fd.io])
   2 LT_INIT
   3 AC_CONFIG_AUX_DIR([.])
   4 AM_INIT_AUTOMAKE([subdir-objects])
   5 AM_SILENT_RULES([yes])
   6 AC_CONFIG_FILES([Makefile plugins/Makefile vpp-api/python/Makefile vpp-api/java/Makefile vpp-api/vapi/Makefile vpp-api/vom/Makefile])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_PROG_CC
  10 AC_PROG_CXX
  11 AC_PROG_CPP
  12 AM_PROG_AS
  13 AM_PROG_LIBTOOL
  14 AC_PROG_YACC
  15 AM_PATH_PYTHON
  16
  17 AM_CONDITIONAL([CROSSCOMPILE], [test "$cross_compiling" == "yes"])
  18
  19 ###############################################################################
  20 # Macros
  21 ###############################################################################
  22
  23 AC_DEFUN([ENABLE_ARG],
  24 [
  25   AC_ARG_ENABLE($1,
  26     AC_HELP_STRING(patsubst([--enable-$1],[_],[-]), $2),
  27     [enable_$1=yes n_enable_$1=1],
  28     [enable_$1=no n_enable_$1=0])
  29   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  30   m4_append([list_of_enabled], [$1], [, ])
  31 ])
  32
  33 AC_DEFUN([DISABLE_ARG],
  34 [
  35   AC_ARG_ENABLE($1,
  36     AC_HELP_STRING(patsubst([--disable-$1],[_],[-]), $2),
  37     [enable_$1=no n_enable_$1=0],
  38     [enable_$1=yes n_enable_$1=1])
  39   AM_CONDITIONAL(m4_toupper(ENABLE_$1), test "$enable_$1" = "yes")
  40   m4_append([list_of_enabled], [$1], [, ])
  41 ])
  42
  43 AC_DEFUN([WITH_ARG],
  44 [
  45   AC_ARG_WITH($1,
  46     AC_HELP_STRING(patsubst([--with-$1],[_],[-]), $2),
  47     [with_$1=yes n_with_$1=1],
  48     [with_$1=no n_with_$1=0])
  49   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  50   m4_append([list_of_with], [$1], [, ])
  51 ])
  52
  53 AC_DEFUN([WITHOUT_ARG],
  54 [
  55   AC_ARG_WITH($1,
  56     AC_HELP_STRING(patsubst([--without-$1],[_],[-]), $2),
  57     [with_$1=no n_with_$1=0],
  58     [with_$1=yes n_with_$1=1])
  59   AM_CONDITIONAL(m4_toupper(WITH_$1), test "$with_$1" = "yes")
  60   m4_append([list_of_with], [$1], [, ])
  61 ])
  62
  63 AC_DEFUN([PLUGIN_ENABLED],
  64 [
  65    AC_ARG_ENABLE($1_plugin,
  66      AC_HELP_STRING([--disable-$1-plugin], [Do not build $1 plugin]),
  67        [enable_$1_plugin=no],
  68        [enable_$1_plugin=yes ])
  69   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  70   m4_append([list_of_plugins], [$1], [, ])
  71 ])
  72
  73 AC_DEFUN([PLUGIN_DISABLED],
  74 [
  75    AC_ARG_ENABLE($1_plugin,
  76      AC_HELP_STRING([--enable-$1-plugin], [Build $1 plugin]),
  77        [enable_$1_plugin=yes ],
  78        [enable_$1_plugin=no])
  79   AM_CONDITIONAL(m4_toupper(ENABLE_$1_PLUGIN), test "$enable_$1_plugin" = "yes")
  80   m4_append([list_of_plugins], [$1], [, ])
  81 ])
  82
  83 AC_DEFUN([PRINT_VAL], [ AC_MSG_RESULT(AC_HELP_STRING($1,$2)) ])
  84
  85 AC_DEFUN([DPDK_IS_PMD_ENABLED],
  86 [
  87   AC_MSG_CHECKING([for $1 in rte_config.h])
  88   AC_COMPILE_IFELSE(
  89     [AC_LANG_PROGRAM(
  90       [[#include <rte_config.h>]],
  91       [[return RTE_$1;]],
  92     )],
  93     [with_$2=yes]
  94     [AC_MSG_RESULT([yes])],
  95     [with_$2=no]
  96     [AC_MSG_RESULT([no])]
  97   )
  98   AM_CONDITIONAL(m4_toupper(WITH_$2), test "$with_$2" = "yes")
  99   m4_append_uniq([list_of_with], [$2], [, ])
 100 ])
 101
 102 AC_DEFUN([DETECT_DPDK_IS_1702_OR_1705],
 103 [
 104   AC_MSG_CHECKING([for RTE_VERSION 17.02/17.05 in rte_version.h])
 105   AC_TRY_RUN(
 106     [
 107     #include <rte_version.h>
 108     int main()
 109     {
 110       return ((RTE_VER_YEAR != 17) ||
 111               (RTE_VER_MONTH != 2 && RTE_VER_MONTH != 5));
 112     }
 113     ],
 114     [dpdk_is_1702_or_1705=yes]
 115     [AC_MSG_RESULT([yes])],
 116     [dpdk_is_1702_or_1705=no]
 117     [AC_MSG_RESULT([no])]
 118   )
 119   AM_CONDITIONAL(DPDK_IS_1702_OR_1705, test "$dpdk_is_1702_or_1705" = "yes")
 120 ])
 121
 122 ###############################################################################
 123 # configure arguments
 124 ###############################################################################
 125
 126 # --enable-X
 127 ENABLE_ARG(tests,       [Enable unit tests])
 128 ENABLE_ARG(dpdk_shared, [Enable unit tests])
 129 ENABLE_ARG(perftool,    [Enable perftool])
 130 ENABLE_ARG(g2,          [Enable g2])
 131
 132 # --disable-X
 133 DISABLE_ARG(vlib,       [Disable vlib and dependant libs and binaries])
 134 DISABLE_ARG(svm,        [Disable svm and dependant libs and binaries])
 135 DISABLE_ARG(papi,       [Disable Python API bindings])
 136 DISABLE_ARG(japi,       [Disable Java API bindings])
 137 DISABLE_ARG(vom,        [Disable VPP object model bindings])
 138
 139 # --with-X
 140
 141 # --without-X
 142 WITHOUT_ARG(libssl,     [Disable libssl])
 143 WITHOUT_ARG(apicli,     [Disable binary api CLI])
 144
 145 AC_ARG_WITH(unix,
 146             AC_HELP_STRING([--with-unix],[Compile unix version of clib]),
 147             [],
 148             [case $host_os in
 149               darwin* | linux*) with_unix=yes;;
 150               *) with_unix=no;;
 151               esac])
 152
 153 AM_CONDITIONAL(WITH_UNIX, test "$with_unix" = "yes")
 154
 155 AC_ARG_WITH(pre-data,
 156             AC_HELP_STRING([--with-pre-data],[Set buffer rewrite space]),
 157             [case $with_pre_data in
 158                128) ;;
 159                256) ;;
 160                *) with_pre_data="pre-data-not-set" ;;
 161              esac], [with_pre_data=128])
 162
 163 ###############################################################################
 164 # Target CPU flags
 165 ###############################################################################
 166
 167 AS_CASE([$build_cpu],
 168         [x86_64], [CPU_FLAGS="-march=corei7 -mtune=corei7-avx"],
 169         [aarch64], [CPU_FLAGS="-march=armv8-a+crc"],
 170         [CPU_FLAGS=""],
 171 )
 172 AC_SUBST([CPU_FLAGS])
 173
 174 ###############################################################################
 175 # Substitutions and defines
 176 ###############################################################################
 177
 178 AC_SUBST(PRE_DATA_SIZE,         [$with_pre_data])
 179 AC_SUBST(APICLI,                [-DVPP_API_TEST_BUILTIN=${n_with_apicli}])
 180
 181 AC_DEFINE_UNQUOTED(DPDK_SHARED_LIB,     [${n_enable_dpdk_shared}])
 182 AC_DEFINE_UNQUOTED(WITH_LIBSSL,         [${n_with_libssl}])
 183
 184
 185 # Silence following noise:
 186 # ar: `u' modifier ignored since `D' is the default (see `U')
 187 AR_FLAGS=cr
 188 AC_SUBST(AR_FLAGS)
 189
 190 ###############################################################################
 191 # Plugins
 192 ###############################################################################
 193
 194 # Please keep alphabetical order
 195 PLUGIN_ENABLED(acl)
 196 PLUGIN_ENABLED(dpdk)
 197 PLUGIN_ENABLED(flowprobe)
 198 PLUGIN_ENABLED(gtpu)
 199 PLUGIN_ENABLED(ila)
 200 PLUGIN_ENABLED(ioam)
 201 PLUGIN_ENABLED(ixge)
 202 PLUGIN_ENABLED(lb)
 203 PLUGIN_ENABLED(memif)
 204 PLUGIN_ENABLED(pppoe)
 205 PLUGIN_ENABLED(sixrd)
 206 PLUGIN_ENABLED(nat)
 207 PLUGIN_ENABLED(stn)
 208
 209 ###############################################################################
 210 # Dependency checks
 211 ###############################################################################
 212
 213 AM_COND_IF([ENABLE_DPDK_SHARED],
 214 [
 215   AC_CHECK_HEADERS([rte_config.h],
 216     [],
 217     [AC_MSG_ERROR([DPDK header files not found])],)
 218   AC_CHECK_LIB( [dpdk], [rte_eal_init],
 219     [],
 220     [AC_MSG_ERROR([DPDK shared library not found])],)
 221 ])
 222
 223 with_aesni_mb_lib=no
 224 with_isa_l_crypto_lib=no
 225
 226 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_MB, dpdk_aesni_mb_pmd)
 227 DPDK_IS_PMD_ENABLED(LIBRTE_PMD_AESNI_GCM, dpdk_aesni_gcm_pmd)
 228
 229 DETECT_DPDK_IS_1702_OR_1705()
 230
 231 AM_COND_IF([WITH_DPDK_AESNI_MB_PMD],
 232 [
 233   AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 234                [with_aesni_mb_lib=yes],
 235                [AC_MSG_ERROR([IPSec_MB library not found])])
 236 ])
 237
 238 AM_COND_IF([WITH_DPDK_AESNI_GCM_PMD],
 239 [
 240   AM_COND_IF([DPDK_IS_1702_OR_1705],
 241   [
 242     AC_CHECK_LIB([isal_crypto], [aesni_gcm128_init],
 243                  [with_isa_l_crypto_lib=yes],
 244                  [AC_MSG_ERROR([isal_crypto library not found])])
 245   ],
 246   [
 247     AC_CHECK_LIB([IPSec_MB], [submit_job_sse],
 248                  [with_aesni_mb_lib=yes],
 249                  [AC_MSG_ERROR([IPSec_MB library not found])])
 250   ])
 251 ])
 252
 253 m4_append([list_of_with], [aesni_mb_lib], [, ])
 254 AM_CONDITIONAL(WITH_AESNI_MB_LIB, test "$with_aesni_mb_lib" = "yes")
 255
 256 m4_append([list_of_with], [isa_l_crypto_lib], [, ])
 257 AM_CONDITIONAL(WITH_ISA_L_CRYPTO_LIB, test "$with_isa_l_crypto_lib" = "yes")
 258
 259
 260 with_ibverbs_lib=no
 261 DPDK_IS_PMD_ENABLED(LIBRTE_MLX4_PMD, dpdk_mlx4_pmd)
 262 AM_COND_IF([WITH_DPDK_MLX4_PMD],
 263 [
 264   AC_CHECK_LIB([ibverbs], [ibv_fork_init],
 265                [with_ibverbs_lib=yes],
 266                [AC_MSG_ERROR([ibverbs library not found])])
 267 ])
 268
 269 DPDK_IS_PMD_ENABLED(LIBRTE_MLX5_PMD, dpdk_mlx5_pmd)
 270 AM_COND_IF([WITH_DPDK_MLX5_PMD],
 271 [
 272   AC_CHECK_LIB([ibverbs], [ibv_fork_init],
 273                [with_ibverbs_lib=yes],
 274                [AC_MSG_ERROR([ibverbs library not found])])
 275 ])
 276
 277 m4_append([list_of_with], [ibverbs_lib], [, ])
 278 AM_CONDITIONAL(WITH_IBVERBS_LIB, test "$with_ibverbs_lib" = "yes")
 279
 280
 281 AM_COND_IF([ENABLE_G2],
 282 [
 283   PKG_CHECK_MODULES(g2, gtk+-2.0)
 284 ])
 285
 286 # If cross-compiling, we need external vppapigen and we cannot continue without it
 287 # For native builds, we just set dependency on vpppaigen binary in top_builddir
 288 AM_COND_IF([CROSSCOMPILE],
 289 [
 290   AC_PATH_PROG([VPPAPIGEN], [vppapigen], [no])
 291   if test "$VPPAPIGEN" = "no"; then
 292     AC_MSG_ERROR([Externaly built vppapigen is needed when cross-compiling...])
 293   fi
 294 ],[
 295   VPPAPIGEN=\$\(top_builddir\)/vppapigen
 296 ])
 297 AC_SUBST([VPPAPIGEN])
 298
 299
 300 ###############################################################################
 301 # JAVA
 302 ###############################################################################
 303
 304 AM_COND_IF([ENABLE_JAPI],
 305 [
 306   AX_VPP_FIND_JDK8
 307   AC_SUBST(JAVA_HOME)
 308   AC_SUBST(JAVAC)
 309   AC_SUBST(JAVAH)
 310   AC_SUBST(JAR)
 311 ])
 312
 313 ###############################################################################
 314 # PYTHON
 315 ###############################################################################
 316
 317 AM_COND_IF([ENABLE_PAPI],
 318 [
 319   AM_PATH_PYTHON
 320 ])
 321
 322 ###############################################################################
 323 # Output
 324 ###############################################################################
 325
 326 AC_OUTPUT
 327
 328 AC_MSG_RESULT([==============================================================================])
 329 PRINT_VAL([version], $PACKAGE $VERSION)
 330 PRINT_VAL([prefix], ${prefix})
 331 PRINT_VAL([libdir], ${libdir})
 332 PRINT_VAL([includedir], ${includedir})
 333 PRINT_VAL([CFLAGS], ${CFLAGS})
 334 PRINT_VAL([CPPFLAGS], ${CPPFLAGS})
 335 PRINT_VAL([LDFLAGS], ${LDFLAGS})
 336 AM_COND_IF([ENABLE_JAPI],
 337 [
 338   PRINT_VAL([JAVA_VERSION], ${JAVA_VERSION})
 339   PRINT_VAL([JAVA_HOME], ${JAVA_HOME})
 340 ])
 341
 342 AC_MSG_RESULT([])
 343 AC_MSG_RESULT([with:])
 344 m4_foreach([x], m4_dquote(list_of_with), [
 345   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${with_], x, [}])))
 346 ])
 347
 348 AC_MSG_RESULT([])
 349 AC_MSG_RESULT([enabled:])
 350 m4_foreach([x], m4_dquote(list_of_enabled), [
 351   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [}])))
 352 ])
 353
 354 AC_MSG_RESULT([])
 355 AC_MSG_RESULT([plugins:])
 356 m4_foreach([x], m4_dquote(list_of_plugins), [
 357   AC_MSG_RESULT(AC_HELP_STRING(x, m4_join([], [${enable_], x, [_plugin}])))
 358 ])
 359 AC_MSG_RESULT([==============================================================================])
 360
 361