src/plugins/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 include_directories (
  15   ${CMAKE_CURRENT_SOURCE_DIR}
  16   ${CMAKE_CURRENT_BINARY_DIR}
  17 )
  18
  19 macro(add_vpp_plugin name)
  20   cmake_parse_arguments(PLUGIN
  21     ""
  22     "LINK_FLAGS"
  23     "SOURCES;API_FILES;MULTIARCH_SOURCES;LINK_LIBRARIES;API_TEST_SOURCES"
  24     ${ARGN}
  25   )
  26   set(plugin_name ${name}_plugin)
  27   set(api_headers)
  28   foreach(f ${PLUGIN_API_FILES})
  29      vpp_generate_api_header(${f} plugins)
  30      list(APPEND api_headers ${f}.h ${f}.json)
  31   endforeach()
  32   add_library(${plugin_name} SHARED ${PLUGIN_SOURCES} ${api_headers})
  33   add_dependencies(${plugin_name} vpp_version_h api_headers)
  34   set_target_properties(${plugin_name} PROPERTIES
  35     PREFIX ""
  36     LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_plugins)
  37   if(PLUGIN_MULTIARCH_SOURCES)
  38     vpp_library_set_multiarch_sources(${plugin_name} ${PLUGIN_MULTIARCH_SOURCES})
  39   endif()
  40   if(PLUGIN_LINK_LIBRARIES)
  41     target_link_libraries(${plugin_name} ${PLUGIN_LINK_LIBRARIES})
  42   endif()
  43   if(PLUGIN_LINK_FLAGS)
  44     set_target_properties(${plugin_name} PROPERTIES LINK_FLAGS "${PLUGIN_LINK_FLAGS}")
  45   endif()
  46   if(PLUGIN_API_TEST_SOURCES)
  47     set(test_plugin_name ${name}_test_plugin)
  48     add_library(${test_plugin_name} SHARED ${PLUGIN_API_TEST_SOURCES} ${api_headers})
  49     add_dependencies(${test_plugin_name} api_headers)
  50     set_target_properties(${test_plugin_name} PROPERTIES
  51       PREFIX ""
  52       LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/vpp_api_test_plugins)
  53     install(TARGETS ${test_plugin_name} DESTINATION lib/vpp_api_test_plugins COMPONENT
  54             plugins)
  55   endif()
  56   install(TARGETS ${plugin_name} DESTINATION lib/vpp_plugins COMPONENT plugins)
  57 endmacro()
  58
  59 ##############################################################################
  60 # find and add all plugin subdirs
  61 ############################################################################
  62 FILE(GLOB files RELATIVE
  63   ${CMAKE_CURRENT_SOURCE_DIR}
  64   ${CMAKE_CURRENT_SOURCE_DIR}/*/CMakeLists.txt
  65 )
  66 foreach (f ${files})
  67   get_filename_component(dir ${f} DIRECTORY)
  68   add_subdirectory(${dir})
  69 endforeach()