src/plugins/crypto_native/CMakeLists.txt

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 if(CMAKE_SYSTEM_PROCESSOR MATCHES "amd64.*|x86_64.*|AMD64.*")
  15   list(APPEND VARIANTS "slm\;-march=silvermont -maes")
  16   list(APPEND VARIANTS "hsw\;-march=haswell -maes")
  17   if(compiler_flag_march_skylake_avx512 AND compiler_flag_mprefer_vector_width_256)
  18     list(APPEND VARIANTS "skx\;-march=skylake-avx512 -mprefer-vector-width=256")
  19   endif()
  20   if(compiler_flag_march_icelake_client AND compiler_flag_mprefer_vector_width_512)
  21     list(APPEND VARIANTS "icl\;-march=icelake-client -mprefer-vector-width=512")
  22   endif()
  23   if(compiler_flag_march_alderlake)
  24     list(APPEND VARIANTS "adl\;-march=alderlake -mprefer-vector-width=256")
  25   endif()
  26 endif()
  27
  28 if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(aarch64.*|AARCH64.*)")
  29   list(APPEND VARIANTS "armv8\;-march=armv8.1-a+crc+crypto")
  30 endif()
  31
  32 set (COMPILE_FILES aes_cbc.c aes_gcm.c aes_ctr.c sha2.c)
  33 set (COMPILE_OPTS -Wall -fno-common)
  34
  35 if (NOT VARIANTS)
  36   return()
  37 endif()
  38
  39 add_vpp_plugin(crypto_native SOURCES main.c)
  40
  41 foreach(VARIANT ${VARIANTS})
  42   list(GET VARIANT 0 v)
  43   list(GET VARIANT 1 f)
  44   set(l crypto_native_${v})
  45   add_library(${l} OBJECT ${COMPILE_FILES})
  46   set_target_properties(${l} PROPERTIES POSITION_INDEPENDENT_CODE ON)
  47   separate_arguments(f)
  48   target_compile_options(${l} PUBLIC ${f} ${COMPILE_OPTS})
  49   target_sources(crypto_native_plugin PRIVATE $<TARGET_OBJECTS:${l}>)
  50 endforeach()