src/plugins/dpdk/CMakeLists.txt

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # macros
  16 ##############################################################################
  17 macro(dpdk_find_library var name)
  18   find_library(${var} NAMES ${name} ${ARGN})
  19 if (NOT ${var})
  20   message(WARNING "-- ${name} library not found - dpdk_plugin disabled")
  21   return()
  22 endif()
  23     message(STATUS "DPDK plugin needs ${name} library - found at ${${var}}")
  24 endmacro()
  25
  26 ##############################################################################
  27 # Find lib and include files
  28 ##############################################################################
  29 find_path(DPDK_INCLUDE_DIR PATH_SUFFIXES dpdk NAMES rte_config.h)
  30 find_library(DPDK_LIB NAMES libdpdk.a)
  31
  32 if (NOT DPDK_INCLUDE_DIR)
  33   message(WARNING "-- DPDK headers not found - dpdk_plugin disabled")
  34   return()
  35 endif()
  36
  37 if (NOT DPDK_LIB)
  38   dpdk_find_library(DPDK_SHLIB "libdpdk.so")
  39   set(DPDK_IS_SHARED_LIB 1)
  40   message(WARNING "-- linking dpdk plugin against DPDK shared libs")
  41 endif()
  42
  43 ##############################################################################
  44 # Parse DPDK config and version header files
  45 ##############################################################################
  46
  47 file(STRINGS ${DPDK_INCLUDE_DIR}/rte_config.h rte_config)
  48 file(STRINGS ${DPDK_INCLUDE_DIR}/rte_version.h rte_version)
  49
  50 foreach(l ${rte_config} ${rte_version})
  51   if (l MATCHES "^#define[\t ]*RTE_")
  52     STRING(REGEX REPLACE "^#define[\t ]*([A-Z1-9_]+)[\t ]*(.+)" "\\1;\\2" v "${l}")
  53     list(GET v 0 name)
  54     list(GET v 1 value)
  55     set(DPDK_${name} ${value})
  56   endif()
  57 endforeach()
  58
  59 set(DPDK_VERSION
  60     "${DPDK_RTE_VER_YEAR}.${DPDK_RTE_VER_MONTH}.${DPDK_RTE_VER_MINOR}")
  61
  62 ##############################################################################
  63 # verify headroom size
  64 ##############################################################################
  65 if(NOT ${DPDK_RTE_PKTMBUF_HEADROOM} EQUAL ${PRE_DATA_SIZE})
  66   message(
  67     FATAL_ERROR
  68     "DPDK RTE_PKTMBUF_HEADROOM (${DPDK_RTE_PKTMBUF_HEADROOM}) "
  69      "must be equal to PRE_DATA_SIZE (${PRE_DATA_SIZE})"
  70   )
  71 endif()
  72
  73 ##############################################################################
  74 # static or dynamic linking
  75 ##############################################################################
  76 unset(DPDK_LINK_LIBRARIES)
  77 unset(DPDK_LINK_FLAGS)
  78 message(STATUS "Found DPDK ${DPDK_VERSION} in ${DPDK_INCLUDE_DIR}")
  79 include_directories (${DPDK_INCLUDE_DIR})
  80
  81 if(DPDK_IS_SHARED_LIB)
  82   get_filename_component(DPDK_LIB_DIR ${DPDK_SHLIB} DIRECTORY)
  83   string_append(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR}")
  84   list(APPEND DPDK_LINK_LIBRARIES ${DPDK_SHLIB})
  85 else()
  86   get_filename_component(DPDK_LIB_DIR ${DPDK_LIB} DIRECTORY)
  87   string_append(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR}")
  88   string_append(DPDK_LINK_FLAGS "-Wl,--whole-archive,${DPDK_LIB},--no-whole-archive")
  89 endif()
  90
  91 ##############################################################################
  92 # libnuma
  93 ##############################################################################
  94 dpdk_find_library(NUMA_LIB "numa")
  95 list(APPEND DPDK_LINK_LIBRARIES ${NUMA_LIB})
  96
  97 ##############################################################################
  98 # AESNI libraries
  99 ##############################################################################
 100 if(DPDK_RTE_LIBRTE_PMD_AESNI_MB OR DPDK_RTE_LIBRTE_PMD_AESNI_GCM)
 101   if(DPDK_IS_SHARED_LIB)
 102     dpdk_find_library(IPSECMB_LIB "libIPSec_MB.so")
 103     list(APPEND DPDK_LINK_LIBRARIES "${IPSECMB_LIB}")
 104   else()
 105     dpdk_find_library(IPSECMB_LIB "libIPSec_MB.a")
 106     get_filename_component(IPSECMB_LIB_DIR ${IPSECMB_LIB} DIRECTORY)
 107     string_append(DPDK_LINK_FLAGS "-L${IPSECMB_LIB_DIR}")
 108     string_append(DPDK_LINK_FLAGS "-Wl,--exclude-libs,libIPSec_MB.a,-l:libIPSec_MB.a")
 109   endif()
 110 endif()
 111
 112 ##############################################################################
 113 # Mellanox libraries
 114 ##############################################################################
 115 if(DPDK_RTE_LIBRTE_MLX4_PMD OR DPDK_RTE_LIBRTE_MLX5_PMD)
 116   dpdk_find_library(MNL_LIB "mnl")
 117   list(APPEND DPDK_LINK_LIBRARIES "${MNL_LIB}")
 118   if (DPDK_RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 119     message(STATUS "DPDK depends on libmnl (Mellanox PMD requirement)")
 120   else()
 121     dpdk_find_library(IBVERBS_LIB "ibverbs")
 122     list(APPEND DPDK_LINK_LIBRARIES "${IBVERBS_LIB}")
 123     dpdk_find_library(MLX5_LIB "mlx5")
 124     list(APPEND DPDK_LINK_LIBRARIES "${MLX5_LIB}")
 125     message(STATUS "DPDK depends on libmnl, libibverbs, libmlx5 (Mellanox PMD requirement)")
 126   endif()
 127 endif()
 128
 129 ##############################################################################
 130 # DPDK plugin
 131 ##############################################################################
 132 add_vpp_plugin(dpdk
 133   SOURCES
 134   buffer.c
 135   main.c
 136   thread.c
 137 #  api/dpdk_api.c
 138 #  api/dpdk_test.c
 139   device/cli.c
 140   device/common.c
 141   device/device.c
 142   device/flow.c
 143   device/format.c
 144   device/init.c
 145   device/node.c
 146 #   hqos/hqos.c
 147   ipsec/cli.c
 148   ipsec/crypto_node.c
 149   ipsec/esp_decrypt.c
 150   ipsec/esp_encrypt.c
 151   ipsec/ipsec.c
 152
 153   MULTIARCH_SOURCES
 154   buffer.c
 155   device/device.c
 156   device/node.c
 157   ipsec/crypto_node.c
 158   ipsec/esp_decrypt.c
 159   ipsec/esp_encrypt.c
 160
 161 #  API_FILES
 162 #  api/dpdk.api
 163
 164 #  API_TEST_SOURCES
 165 #  api/dpdk_test.c
 166
 167   INSTALL_HEADERS
 168   device/dpdk.h
 169 #  api/dpdk_all_api_h.h
 170   ipsec/ipsec.h
 171
 172   LINK_FLAGS
 173   "${DPDK_LINK_FLAGS}"
 174
 175   LINK_LIBRARIES
 176   ${DPDK_LINK_LIBRARIES}
 177
 178   COMPONENT
 179   vpp-plugin-dpdk
 180 )
 181