src/plugins/dpdk/CMakeLists.txt

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 ##############################################################################
  15 # Find lib and include files
  16 ##############################################################################
  17 find_path(DPDK_INCLUDE_DIR PATH_SUFFIXES dpdk NAMES rte_config.h)
  18 find_library(DPDK_LIB NAMES libdpdk.a)
  19
  20 ##############################################################################
  21 # Find DPDK Version
  22 ##############################################################################
  23 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  24 "
  25 #include <stdio.h>
  26 #include <rte_version.h>
  27 int main()
  28 {
  29   printf(\"VERSION=%s\\n\", strchr(rte_version(), ' ') + 1);
  30   printf(\"RTE_PKTMBUF_HEADROOM=%u\\n\", RTE_PKTMBUF_HEADROOM);
  31 #ifdef RTE_LIBRTE_PMD_AESNI_MB
  32   printf(\"RTE_LIBRTE_PMD_AESNI_MB=%u\\n\", RTE_LIBRTE_PMD_AESNI_MB);
  33 #endif
  34 #ifdef RTE_LIBRTE_PMD_AESNI_GCM
  35   printf(\"RTE_LIBRTE_PMD_AESNI_GCM=%u\\n\", RTE_LIBRTE_PMD_AESNI_GCM);
  36 #endif
  37 #ifdef RTE_LIBRTE_MLX4_PMD
  38   printf(\"RTE_LIBRTE_MLX4_PMD=%u\\n\", RTE_LIBRTE_MLX4_PMD);
  39 #endif
  40 #ifdef RTE_LIBRTE_MLX5_PMD
  41   printf(\"RTE_LIBRTE_MLX5_PMD=%u\\n\", RTE_LIBRTE_MLX5_PMD);
  42 #endif
  43   return 0;
  44 }
  45 ")
  46
  47 try_compile(DPDK_VARS_COMPILED
  48   ${CMAKE_CURRENT_BINARY_DIR}
  49   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  50   CMAKE_FLAGS
  51   -DINCLUDE_DIRECTORIES=${DPDK_INCLUDE_DIR}
  52   COPY_FILE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  53 )
  54
  55 if(DPDK_VARS_COMPILED)
  56   execute_process(
  57     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  58     COMMAND ./dpdk_vars.bin
  59     OUTPUT_VARIABLE DPDK_VARS
  60     OUTPUT_STRIP_TRAILING_WHITESPACE
  61   )
  62   string(REPLACE "\n" ";" DPDK_VARS ${DPDK_VARS})
  63   foreach(v ${DPDK_VARS})
  64     string(REPLACE "=" ";" v ${v})
  65     list(GET v 0 name)
  66     list(GET v 1 value)
  67     set(DPDK_${name} ${value})
  68   endforeach()
  69 endif()
  70
  71 file(REMOVE
  72   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  73   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  74 )
  75
  76 if(NOT ${DPDK_RTE_PKTMBUF_HEADROOM} EQUAL ${PRE_DATA_SIZE})
  77   message(
  78     FATAL_ERROR
  79     "DPDK RTE_PKTMBUF_HEADROOM (${DPDK_RTE_PKTMBUF_HEADROOM}) "
  80      "must be equal to PRE_DATA_SIZE (${PRE_DATA_SIZE})"
  81   )
  82 endif()
  83
  84 ##############################################################################
  85 # DPDK plugin
  86 ##############################################################################
  87 if(DPDK_INCLUDE_DIR AND DPDK_LIB)
  88   include_directories (${DPDK_INCLUDE_DIR})
  89
  90   message(STATUS "Found DPDK ${DPDK_VERSION} in ${DPDK_INCLUDE_DIR}")
  91   get_filename_component(DPDK_LIB_DIR ${DPDK_LIB} DIRECTORY)
  92   set(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR} -Wl,--whole-archive,${DPDK_LIB},--no-whole-archive")
  93   if(DPDK_RTE_LIBRTE_PMD_AESNI_MB OR DPDK_RTE_LIBRTE_PMD_AESNI_GCM)
  94     set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,--exclude-libs,libIPSec_MB.a,-l:libIPSec_MB.a")
  95     message(STATUS "DPDK depends on IPSec MB library")
  96   endif()
  97   if(DPDK_RTE_LIBRTE_MLX4_PMD OR DPDK_RTE_LIBRTE_MLX5_PMD)
  98     set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lmnl")
  99     message(STATUS "DPDK depends on libmnl (Mellanox PMD requirement)")
 100   endif()
 101   set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lnuma")
 102   add_vpp_plugin(dpdk
 103     SOURCES
 104     buffer.c
 105     main.c
 106     thread.c
 107     api/dpdk_api.c
 108     api/dpdk_test.c
 109     device/cli.c
 110     device/common.c
 111     device/device.c
 112     device/flow.c
 113     device/format.c
 114     device/init.c
 115     device/node.c
 116     hqos/hqos.c
 117     ipsec/cli.c
 118     ipsec/crypto_node.c
 119     ipsec/esp_decrypt.c
 120     ipsec/esp_encrypt.c
 121     ipsec/ipsec.c
 122
 123     MULTIARCH_SOURCES
 124     buffer.c
 125     device/device.c
 126     device/node.c
 127
 128     API_FILES
 129     api/dpdk.api
 130
 131     API_TEST_SOURCES
 132     api/dpdk_test.c
 133
 134     INSTALL_HEADERS
 135     device/dpdk.h
 136     api/dpdk_all_api_h.h
 137     ipsec/ipsec.h
 138
 139     LINK_FLAGS
 140     ${DPDK_LINK_FLAGS}
 141
 142     COMPONENT
 143     vpp-plugin-dpdk
 144   )
 145 else()
 146   message(WARNING "DPDK not found - dpdk disabled")
 147 endif()
 148