src/plugins/dpdk/CMakeLists.txt

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 if (CMAKE_CROSSCOMPILING)
  15   # not supported yet
  16   return()
  17 endif()
  18
  19 ##############################################################################
  20 # Find lib and include files
  21 ##############################################################################
  22 find_path(DPDK_INCLUDE_DIR PATH_SUFFIXES dpdk NAMES rte_config.h)
  23 find_library(DPDK_LIB NAMES libdpdk.a)
  24
  25 if (NOT DPDK_INCLUDE_DIR)
  26   message(WARNING "-- DPDK not found - dpdk_plugin disabled")
  27   return()
  28 endif()
  29
  30 ##############################################################################
  31 # Find DPDK Version
  32 ##############################################################################
  33 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  34 "
  35 #include <stdio.h>
  36 #include <rte_version.h>
  37 int main()
  38 {
  39   printf(\"VERSION=%s\\n\", strchr(rte_version(), ' ') + 1);
  40   printf(\"RTE_PKTMBUF_HEADROOM=%u\\n\", RTE_PKTMBUF_HEADROOM);
  41 #ifdef RTE_LIBRTE_PMD_AESNI_MB
  42   printf(\"RTE_LIBRTE_PMD_AESNI_MB=%u\\n\", RTE_LIBRTE_PMD_AESNI_MB);
  43 #endif
  44 #ifdef RTE_LIBRTE_PMD_AESNI_GCM
  45   printf(\"RTE_LIBRTE_PMD_AESNI_GCM=%u\\n\", RTE_LIBRTE_PMD_AESNI_GCM);
  46 #endif
  47 #ifdef RTE_LIBRTE_MLX4_PMD
  48   printf(\"RTE_LIBRTE_MLX4_PMD=%u\\n\", RTE_LIBRTE_MLX4_PMD);
  49 #endif
  50 #ifdef RTE_LIBRTE_MLX5_PMD
  51   printf(\"RTE_LIBRTE_MLX5_PMD=%u\\n\", RTE_LIBRTE_MLX5_PMD);
  52 #ifdef RTE_LIBRTE_MLX5_DLOPEN_DEPS
  53   printf(\"RTE_LIBRTE_MLX5_DLOPEN_DEPS=%u\\n\", RTE_LIBRTE_MLX5_DLOPEN_DEPS);
  54 #endif
  55 #endif
  56   return 0;
  57 }
  58 ")
  59
  60 try_compile(DPDK_VARS_COMPILED
  61   ${CMAKE_CURRENT_BINARY_DIR}
  62   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  63   CMAKE_FLAGS
  64   -DINCLUDE_DIRECTORIES=${DPDK_INCLUDE_DIR}
  65   COPY_FILE ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  66 )
  67
  68 if(DPDK_VARS_COMPILED)
  69   execute_process(
  70     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  71     COMMAND ./dpdk_vars.bin
  72     OUTPUT_VARIABLE DPDK_VARS
  73     OUTPUT_STRIP_TRAILING_WHITESPACE
  74   )
  75   string(REPLACE "\n" ";" DPDK_VARS ${DPDK_VARS})
  76   foreach(v ${DPDK_VARS})
  77     string(REPLACE "=" ";" v ${v})
  78     list(GET v 0 name)
  79     list(GET v 1 value)
  80     set(DPDK_${name} ${value})
  81   endforeach()
  82 endif()
  83
  84 file(REMOVE
  85   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.c
  86   ${CMAKE_CURRENT_BINARY_DIR}/dpdk_vars.bin
  87 )
  88
  89 if(NOT ${DPDK_RTE_PKTMBUF_HEADROOM} EQUAL ${PRE_DATA_SIZE})
  90   message(
  91     FATAL_ERROR
  92     "DPDK RTE_PKTMBUF_HEADROOM (${DPDK_RTE_PKTMBUF_HEADROOM}) "
  93      "must be equal to PRE_DATA_SIZE (${PRE_DATA_SIZE})"
  94   )
  95 endif()
  96
  97 ##############################################################################
  98 # DPDK plugin
  99 ##############################################################################
 100 if(DPDK_INCLUDE_DIR AND DPDK_LIB)
 101   include_directories (${DPDK_INCLUDE_DIR})
 102
 103   message(STATUS "Found DPDK ${DPDK_VERSION} in ${DPDK_INCLUDE_DIR}")
 104   get_filename_component(DPDK_LIB_DIR ${DPDK_LIB} DIRECTORY)
 105   set(DPDK_LINK_FLAGS "-L${DPDK_LIB_DIR} -Wl,--whole-archive,${DPDK_LIB},--no-whole-archive")
 106   if(DPDK_RTE_LIBRTE_PMD_AESNI_MB OR DPDK_RTE_LIBRTE_PMD_AESNI_GCM)
 107     set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,--exclude-libs,libIPSec_MB.a,-l:libIPSec_MB.a")
 108     message(STATUS "DPDK depends on IPSec MB library")
 109   endif()
 110   if(DPDK_RTE_LIBRTE_MLX4_PMD OR DPDK_RTE_LIBRTE_MLX5_PMD)
 111     if (DPDK_RTE_LIBRTE_MLX5_DLOPEN_DEPS)
 112       set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lmnl")
 113       message(STATUS "DPDK depends on libmnl (Mellanox PMD requirement)")
 114     else()
 115       set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lmnl,-libverbs,-lmlx5")
 116       message(STATUS "DPDK depends on libmnl, libibverbs, libmlx5 (Mellanox PMD requirement)")
 117     endif()
 118   endif()
 119   set(DPDK_LINK_FLAGS "${DPDK_LINK_FLAGS} -Wl,-lnuma")
 120   add_vpp_plugin(dpdk
 121     SOURCES
 122     buffer.c
 123     main.c
 124     thread.c
 125     api/dpdk_api.c
 126     api/dpdk_test.c
 127     device/cli.c
 128     device/common.c
 129     device/device.c
 130     device/flow.c
 131     device/format.c
 132     device/init.c
 133     device/node.c
 134     hqos/hqos.c
 135     ipsec/cli.c
 136     ipsec/crypto_node.c
 137     ipsec/esp_decrypt.c
 138     ipsec/esp_encrypt.c
 139     ipsec/ipsec.c
 140
 141     MULTIARCH_SOURCES
 142     buffer.c
 143     device/device.c
 144     device/node.c
 145     ipsec/crypto_node.c
 146     ipsec/esp_decrypt.c
 147     ipsec/esp_encrypt.c
 148
 149     API_FILES
 150     api/dpdk.api
 151
 152     API_TEST_SOURCES
 153     api/dpdk_test.c
 154
 155     INSTALL_HEADERS
 156     device/dpdk.h
 157     api/dpdk_all_api_h.h
 158     ipsec/ipsec.h
 159
 160     LINK_FLAGS
 161     ${DPDK_LINK_FLAGS}
 162
 163     COMPONENT
 164     vpp-plugin-dpdk
 165   )
 166 else()
 167   message(WARNING "DPDK not found - dpdk disabled")
 168 endif()
 169