+| | ... | - count - Number of memif pairs (containers). Type: integer
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 xconnect with memif pairs \| ${1} \|
+| | ...
+| | [Arguments] | ${count}=${1}
+| | ...
+| | ${duts}= | Get Matches | ${nodes} | DUT*
+| | :FOR | ${dut} | IN | @{duts}
+| | | Initialize L2 xconnect with memif pairs on DUT node | ${dut} | ${count}
+| | Set interfaces in path up
+| | Show Memif on all DUTs | ${nodes}
+| | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
+
+| Initialize L2 Bridge Domain with memif pairs on DUT node
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces on DUT node. Put each Memif interface
+| | ... | to separate L2 bridge domain with one physical or memif interface
+| | ... | to create a chain accross DUT node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - dut - DUT node. Type: dictionary
+| | ... | - nf_chain - NF chain. Type: integer
+| | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
+| | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
+| | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
+| | ...
+| | ... | *Note:*
+| | ... | Socket paths for Memif are defined in following format:
+| | ... | - /tmp/memif-\${dut}_CNF\${nf_id}-\${sid}
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 Bridge Domain with memif pairs on DUT node \
+| | ... | \| ${dut} \| 1 \| 1 \|
+| | ...
+| | [Arguments] | ${dut} | ${nf_chain}=${1} | ${nf_nodes}=${1}
+| | ... | ${auto_scale}=${True}
+| | ...
+| | ${rxq}= | Run Keyword If | ${auto_scale} == ${True}
+| | ... | Set Variable | ${rxq_count_int}
+| | ... | ELSE | Set Variable | ${1}
+| | ${bd_id2}= | Evaluate | ${nf_nodes}+1
+| | Add interface to bridge domain | ${nodes['${dut}']} | ${${dut}_if1} | ${1}
+| | Add interface to bridge domain | ${nodes['${dut}']} | ${${dut}_if2}
+| | ... | ${bd_id2}
+| | :FOR | ${nf_node} | IN RANGE | 1 | ${nf_nodes}+1
+| | | ${nf_id}= | Evaluate | (${nf_chain} - ${1}) * ${nf_nodes} + ${nf_node}
+| | | ${sock1}= | Set Variable | memif-${dut}_CNF
+| | | ${sock2}= | Set Variable | memif-${dut}_CNF
+| | | Set up memif interfaces on DUT node | ${nodes['${dut}']}
+| | | ... | ${sock1} | ${sock2} | ${nf_id} | ${dut}-memif-${nf_id}-if1
+| | | ... | ${dut}-memif-${nf_id}-if2 | ${rxq} | ${rxq}
+| | | ${bd_id2}= | Evaluate | ${nf_node}+1
+| | | Add interface to bridge domain | ${nodes['${dut}']}
+| | | ... | ${${dut}-memif-${nf_id}-if1} | ${nf_node}
+| | | Add interface to bridge domain | ${nodes['${dut}']}
+| | | ... | ${${dut}-memif-${nf_id}-if2} | ${bd_id2}
+
+| Initialize L2 Bridge Domain with memif pairs
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
+| | ... | Memif interface to separate L2 bridge domain with one physical or
+| | ... | virtual interface to create a chain accross DUT node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - nf_chain - NF chain. Type: integer
+| | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
+| | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
+| | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 Bridge Domain with memif pairs \| 1 \| 1 \|
+| | ...
+| | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
+| | ...
+| | ${duts}= | Get Matches | ${nodes} | DUT*
+| | :FOR | ${dut} | IN | @{duts}
+| | | Initialize L2 Bridge Domain with memif pairs on DUT node | ${dut}
+| | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
+| | | ... | auto_scale=${auto_scale}
+
+| Initialize L2 Bridge Domain for multiple chains with memif pairs
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces for defined number of NF chains
+| | ... | with defined number of NF nodes on all defined VPP nodes. Add each
+| | ... | Memif interface into L2 bridge domains with learning enabled
+| | ... | with physical inteface or Memif interface of another NF.
+| | ...
+| | ... | *Arguments:*
+| | ... | - nf_chains - Number of chains of NFs. Type: integer
+| | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
+| | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
+| | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 Bridge Domain for multiple chains with memif pairs \
+| | ... | \| 1 \| 1 \|
+| | ...
+| | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
+| | ...
+| | :FOR | ${nf_chain} | IN RANGE | 1 | ${nf_chains}+1
+| | | Initialize L2 Bridge Domain with memif pairs | nf_chain=${nf_chain}
+| | | ... | nf_nodes=${nf_nodes} | auto_scale=${auto_scale}
+| | Set interfaces in path up
+| | Show Memif on all DUTs | ${nodes}
+| | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
+
+| Initialize L2 Bridge Domain for pipeline with memif pairs
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
+| | ... | Memif interface to separate L2 bridge domain with one physical or
+| | ... | virtual interface to create a service pipeline on DUT node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - nf_chain - NF pipe. Type: integer
+| | ... | - nf_nodes - Number of NFs nodes per pipeline. Type: integer
+| | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
+| | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 Bridge Domain for pipeline with memif pairs \
+| | ... | \| 1 \| 1 \|
+| | ...
+| | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
+| | ...
+| | ${rxq}= | Run Keyword If | ${auto_scale} == ${True}
+| | ... | Set Variable | ${rxq_count_int}
+| | ... | ELSE | Set Variable | ${1}
+| | ${duts}= | Get Matches | ${nodes} | DUT*
+| | :FOR | ${dut} | IN | @{duts}
+| | | Add interface to bridge domain | ${nodes['${dut}']} | ${${dut}_if1} | ${1}
+| | | Add interface to bridge domain | ${nodes['${dut}']} | ${${dut}_if2} | ${2}
+| | | ${nf_id_frst}= | Evaluate | (${nf_chain}-${1}) * ${nf_nodes} + ${1}
+| | | ${nf_id_last}= | Evaluate | (${nf_chain}-${1}) * ${nf_nodes} + ${nf_nodes}
+| | | ${sid_frst}= | Evaluate | ${nf_id_frst} * ${2} - ${1}
+| | | ${sid_last}= | Evaluate | ${nf_id_last} * ${2}
+| | | Set up single memif interface on DUT node | ${nodes['${dut}']}
+| | | ... | memif-${dut}_CNF | mid=${nf_id_frst} | sid=${sid_frst}
+| | | ... | memif_if=${dut}-memif-${nf_id_frst}-if1
+| | | ... | rxq=${rxq} | txq=${rxq}
+| | | Set up single memif interface on DUT node | ${nodes['${dut}']}
+| | | ... | memif-${dut}_CNF | mid=${nf_id_last} | sid=${sid_last}
+| | | ... | memif_if=${dut}-memif-${nf_id_last}-if2
+| | | ... | rxq=${rxq} | txq=${rxq}
+| | | Add interface to bridge domain | ${nodes['${dut}']}
+| | | ... | ${${dut}-memif-${nf_id_frst}-if1} | ${1}
+| | | Add interface to bridge domain | ${nodes['${dut}']}
+| | | ... | ${${dut}-memif-${nf_id_last}-if2} | ${2}
+
+| Initialize L2 Bridge Domain for multiple pipelines with memif pairs
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces for defined number of NF pipelines
+| | ... | with defined number of NF nodes on all defined VPP nodes. Add each
+| | ... | Memif interface into L2 bridge domains with learning enabled
+| | ... | with physical inteface or Memif interface of another NF.
+| | ...
+| | ... | *Arguments:*
+| | ... | - nf_chains - Number of pipelines of NFs. Type: integer
+| | ... | - nf_nodes - Number of NFs nodes per pipeline. Type: integer
+| | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
+| | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 Bridge Domain for multiple pipelines with memif \
+| | ... | pairs \| 1 \| 1 \|
+| | ...
+| | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
+| | ...
+| | :FOR | ${nf_chain} | IN RANGE | 1 | ${nf_chains}+1
+| | | Initialize L2 Bridge Domain for pipeline with memif pairs
+| | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
+| | | ... | auto_scale=${auto_scale}
+| | Set interfaces in path up
+| | Show Memif on all DUTs | ${nodes}
+| | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
+
+| Initialize L2 Bridge Domain with memif pairs and VLAN in circular topology
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
+| | ... | Memif interface to separate L2 bridge domain with one physical or
+| | ... | virtual interface to create a chain accross DUT node. In case of
+| | ... | 3-node topology create VLAN sub-interfaces between DUTs. In case of
+| | ... | 2-node topology create VLAN sub-interface on dut1-if2 interface. All
+| | ... | interfaces are brought up.
+| | ...
+| | ... | *Arguments:*
+| | ... | - bd_id1 - Bridge domain ID. Type: integer
+| | ... | - bd_id2 - Bridge domain ID. Type: integer
+| | ... | - subid - ID of the sub-interface to be created. Type: string
+| | ... | - tag_rewrite - Method of tag rewrite. Type: string
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 Bridge Domain with memif pairs and VLAN in circular\
+| | ... | topology \| 1 \| 2 \| 10 \| pop-1 \|
+| | ...
+| | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
+| | ...
+| | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
+| | ... | Variable Should Exist | ${dut2}
+| | ...
+| | Set interfaces in path up
+| | ...
+| | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Initialize VLAN dot1q sub-interfaces in circular topology
+| | ... | ${dut1} | ${dut1_if2} | ${dut2} | ${dut2_if1} | ${subid}
+| | ... | ELSE | Initialize VLAN dot1q sub-interfaces in circular topology
+| | ... | ${dut1} | ${dut1_if2} | SUB_ID=${subid}
+| | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Configure L2 tag rewrite method on interfaces | ${dut1}
+| | ... | ${subif_index_1} | ${dut2} | ${subif_index_2} | ${tag_rewrite}
+| | ... | ELSE | Configure L2 tag rewrite method on interfaces
+| | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
+| | ...
+| | ${number}= | Set Variable | ${1}
+| | ${sock1}= | Set Variable | memif-DUT1_CNF
+| | ${sock2}= | Set Variable | memif-DUT1_CNF
+| | ${memif_if1_name}= | Set Variable | DUT1-memif-${number}-if1
+| | ${memif_if2_name}= | Set Variable | DUT1-memif-${number}-if2
+| | Set up memif interfaces on DUT node | ${dut1} | ${sock1} | ${sock2}
+| | ... | ${number} | ${memif_if1_name} | ${memif_if2_name} | ${rxq_count_int}
+| | ... | ${rxq_count_int}
+| | Add interface to bridge domain | ${dut1} | ${dut1_if1} | ${bd_id1}
+| | Add interface to bridge domain | ${dut1} | ${${memif_if1_name}} | ${bd_id1}
+| | Add interface to bridge domain | ${dut1} | ${${memif_if2_name}} | ${bd_id2}
+| | Add interface to bridge domain | ${dut1} | ${subif_index_1} | ${bd_id2}
+| | ${sock1}= | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Set Variable | memif-DUT2_CNF
+| | ${sock2}= | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Set Variable | memif-DUT2_CNF
+| | ${memif_if1_name}= | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Set Variable | DUT2-memif-${number}-if1
+| | ${memif_if2_name}= | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Set Variable | DUT2-memif-${number}-if2
+| | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Set up memif interfaces on DUT node | ${dut2} | ${sock1} | ${sock2}
+| | ... | ${number} | ${memif_if1_name} | ${memif_if2_name} | ${rxq_count_int}
+| | ... | ${rxq_count_int}
+| | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Add interface to bridge domain | ${dut2} | ${subif_index_2}
+| | ... | ${bd_id1}
+| | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Add interface to bridge domain | ${dut2} | ${${memif_if1_name}}
+| | ... | ${bd_id1}
+| | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Add interface to bridge domain | ${dut2} | ${${memif_if2_name}}
+| | ... | ${bd_id2}
+| | Run Keyword If | '${dut2_status}' == 'PASS'
+| | ... | Add interface to bridge domain | ${dut2} | ${dut2_if2} | ${bd_id2}
+| | ...
+| | Show Memif on all DUTs | ${nodes}
+| | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
+
+| Initialize IPv4 routing with memif pairs on DUT node
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces on DUT node. Put each Memif interface
+| | ... | to separate IPv4 VRF with one physical or virtual interface
+| | ... | to create a chain accross DUT node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - dut - DUT node. Type: dictionary
+| | ... | - count - Number of memif pairs (containers). Type: integer
+| | ...
+| | ... | *Note:*
+| | ... | Socket paths for Memif are defined in following format:
+| | ... | - /tmp/memif-\${dut}_CNF\${number}-\${sid}
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize IPv4 routing with memif pairs on DUT node \
+| | ... | \| ${dut} \| ${1} \|
+| | ...
+| | [Arguments] | ${dut} | ${count}
+| | ...
+| | ${dut_index}= | Get Index From List | ${duts} | ${dut}
+| | ${last_dut_index}= | Evaluate | ${duts_count} - ${1}
+| | ...
+| | ${tg_if1_net}= | Set Variable | 10.10.10.0
+| | ${tg_if2_net}= | Set Variable | 20.20.20.0
+| | ...
+| | ${fib_table_1}= | Set Variable | ${10}
+| | Run Keyword If | ${fib_table_1} > ${0}
+| | ... | Add Fib Table | ${nodes['${dut}']} | ${fib_table_1}
+| | ${ip_base_if1}= | Evaluate | ${dut_index} + ${1}
+| | ${ip_net_if1}= | Set Variable
+| | ... | ${ip_base_if1}.${ip_base_if1}.${ip_base_if1}
+| | Vpp Route Add | ${nodes['${dut}']} | ${tg_if1_net} | 24
+| | ... | vrf=${fib_table_1} | gateway=${ip_net_if1}.1
+| | ... | interface=${${dut}_if1} | multipath=${TRUE}
+| | Assign Interface To Fib Table | ${nodes['${dut}']} | ${${dut}_if1}
+| | ... | ${fib_table_1}
+| | Configure IP addresses on interfaces | ${nodes['${dut}']} | ${${dut}_if1}
+| | ... | ${ip_net_if1}.2 | 30
+| | ${prev_node}= | Run Keyword If | ${dut_index} == ${0}
+| | ... | Set Variable | TG
+| | ... | ELSE | Get From List | ${duts} | ${dut_index-${1}}
+| | ${prev_if}= | Run Keyword If | ${dut_index} == ${0}
+| | ... | Set Variable | if1
+| | ... | ELSE | Set Variable | if2
+| | ${prev_if_mac}= | Get Interface MAC | ${nodes['${prev_node}']}
+| | ... | ${${prev_node}_${prev_if}}
+| | VPP Add IP Neighbor
+| | ... | ${nodes['${dut}']} | ${${dut}_if1} | ${ip_net_if1}.1 | ${prev_if_mac}
+| | ...
+| | ${fib_table_2}= | Evaluate | ${fib_table_1} + ${count}
+| | Add Fib Table | ${nodes['${dut}']} | ${fib_table_2}
+| | ${ip_base_if2}= | Evaluate | ${ip_base_if1} + ${1}
+| | ${ip_net_if2}= | Set Variable
+| | ... | ${ip_base_if2}.${ip_base_if2}.${ip_base_if2}
+| | Vpp Route Add | ${nodes['${dut}']} | ${tg_if2_net} | 24
+| | ... | vrf=${fib_table_2} | gateway=${ip_net_if2}.2
+| | ... | interface=${${dut}_if2} | multipath=${TRUE}
+| | Assign Interface To Fib Table | ${nodes['${dut}']} | ${${dut}_if2}
+| | ... | ${fib_table_2}
+| | Configure IP addresses on interfaces | ${nodes['${dut}']} | ${${dut}_if2}
+| | ... | ${ip_net_if2}.1 | 30
+| | ${next_node}= | Run Keyword If | ${dut_index} == ${last_dut_index}
+| | ... | Set Variable | TG
+| | ... | ELSE | Get From List | ${duts} | ${dut_index+${1}}
+| | ${next_if}= | Run Keyword If | ${dut_index} == ${last_dut_index}
+| | ... | Set Variable | if2
+| | ... | ELSE | Set Variable | if1
+| | ${next_if_mac}= | Get Interface MAC | ${nodes['${next_node}']}
+| | ... | ${${next_node}_${next_if}}
+| | VPP Add IP Neighbor
+| | ... | ${nodes['${dut}']} | ${${dut}_if2} | ${ip_net_if2}.2 | ${next_if_mac}
+| | ...
+| | ${fib_table_1}= | Evaluate | ${fib_table_1} - ${1}
+| | ${ip_base_start}= | Set Variable | ${31}
+| | :FOR | ${number} | IN RANGE | 1 | ${count+${1}}
+| | | ${sock1}= | Set Variable | memif-${dut}_CNF
+| | | ${sock2}= | Set Variable | memif-${dut}_CNF
+| | | Set up memif interfaces on DUT node | ${nodes['${dut}']}
+| | | ... | ${sock1} | ${sock2} | ${number} | ${dut}-memif-${number}-if1
+| | | ... | ${dut}-memif-${number}-if2 | ${rxq_count_int} | ${rxq_count_int}
+| | | ${memif1}= | Set Variable | ${${dut}-memif-${number}-if1}
+| | | ${memif2}= | Set Variable | ${${dut}-memif-${number}-if2}
+| | | ${fib_table_1}= | Evaluate | ${fib_table_1} + ${1}
+| | | ${fib_table_2}= | Evaluate | ${fib_table_1} + ${1}
+| | | Run Keyword Unless | ${number} == ${count}
+| | | ... | Add Fib Table | ${nodes['${dut}']} | ${fib_table_2}
+| | | Assign Interface To Fib Table | ${nodes['${dut}']}
+| | | ... | ${memif1} | ${fib_table_1}
+| | | Assign Interface To Fib Table | ${nodes['${dut}']}
+| | | ... | ${memif2} | ${fib_table_2}
+| | | ${ip_base_memif1}= | Evaluate
+| | | ... | ${ip_base_start} + (${number} - ${1}) * ${2}
+| | | ${ip_base_memif2}= | Evaluate | ${ip_base_memif1} + ${1}
+| | | ${ip_net_memif1}= | Set Variable
+| | | ... | ${ip_base_memif1}.${ip_base_memif1}.${ip_base_memif1}
+| | | ${ip_net_memif2}= | Set Variable
+| | | ... | ${ip_base_memif2}.${ip_base_memif2}.${ip_base_memif2}
+| | | Configure IP addresses on interfaces
+| | | ... | ${nodes['${dut}']} | ${memif1} | ${ip_net_memif1}.1 | 30
+| | | ... | ${nodes['${dut}']} | ${memif2} | ${ip_net_memif2}.1 | 30
+| | | Vpp Route Add | ${nodes['${dut}']} | ${tg_if2_net} | 24
+| | | ... | vrf=${fib_table_1} | gateway=${ip_net_memif2}.1
+| | | ... | interface=${memif1}
+| | | Vpp Route Add | ${nodes['${dut}']} | ${tg_if1_net} | 24
+| | | ... | vrf=${fib_table_2} | gateway=${ip_net_memif1}.1
+| | | ... | interface=${memif2}
+| | | ${memif_if1_key}= | Get interface by sw index | ${nodes['${dut}']}
+| | | ... | ${memif1}
+| | | ${memif_if1_mac}= | Get interface mac | ${nodes['${dut}']}
+| | | ... | ${memif_if1_key}
+| | | ${memif_if2_key}= | Get interface by sw index | ${nodes['${dut}']}
+| | | ... | ${memif2}
+| | | ${memif_if2_mac}= | Get interface mac | ${nodes['${dut}']}
+| | | ... | ${memif_if2_key}
+| | | VPP Add IP Neighbor | ${nodes['${dut}']}
+| | | ... | ${memif1} | ${ip_net_memif2}.1 | ${memif_if2_mac}
+| | | VPP Add IP Neighbor | ${nodes['${dut}']}
+| | | ... | ${memif2} | ${ip_net_memif1}.1 | ${memif_if1_mac}
+
+| Initialize IPv4 routing with memif pairs
+| | [Documentation]
+| | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
+| | ... | Memif interface to separate IPv4 VRF with one physical or
+| | ... | virtual interface to create a chain accross DUT node.
+| | ...
+| | ... | *Arguments:*
+| | ... | - count - Number of memif pairs (containers). Type: integer
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize IPv4 routing with memif pairs \| ${1} \|
+| | ...
+| | [Arguments] | ${count}=${1}
+| | ...
+| | :FOR | ${dut} | IN | @{duts}
+| | | Initialize IPv4 routing with memif pairs on DUT node | ${dut} | ${count}
+| | Set interfaces in path up
+| | Show Memif on all DUTs | ${nodes}
+| | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
+
+| Initialize L2 xconnect for single memif
+| | [Documentation]
+| | ... | Create single Memif interface on all defined VPP nodes. Cross
+| | ... | connect Memif interface with one physical interface.
+| | ...
+| | ... | *Arguments:*
+| | ... | - number - Memif ID. Type: integer
+| | ...
+| | ... | *Note:*
+| | ... | Socket paths for Memif are defined in following format:
+| | ... | - /tmp/memif-DUT1_CNF\${number}-\${sid}
+| | ...
+| | ... | KW uses test variable ${rxq_count_int} set by KW Add worker threads
+| | ... | and rxqueues to all DUTs
+| | ...
+| | ... | *Example:*
+| | ...
+| | ... | \| Initialize L2 xconnect for single memif \| 1 \|
+| | ...
+| | [Arguments] | ${number}=${1}
+| | ...
+| | ${duts}= | Get Matches | ${nodes} | DUT*
+| | :FOR | ${dut} | IN | @{duts}
+| | | ${sock}= | Set Variable | memif-${dut}_CNF
+| | | ${sid}= | Evaluate | (${number} * ${2}) - ${1}
+| | | Set up single memif interface on DUT node | ${nodes['${dut}']} | ${sock}
+| | | ... | mid=${number} | sid=${sid} | memif_if=${dut}-memif-${number}-if1
+| | | ... | rxq=${rxq_count_int} | txq=${rxq_count_int}
+| | | Configure L2XC | ${nodes['${dut}']} | ${${dut}_if1}
+| | | ... | ${${dut}-memif-${number}-if1}
+| | Set single interfaces in path up
+| | Show Memif on all DUTs | ${nodes}
+| | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
+
+| Initialize L2 Bridge Domain for single memif
+| | [Documentation]
+| | ... | Create single Memif interface on all defined VPP nodes. Put Memif
+| | ... | interface to separate L2 bridge domain with one physical interface.
+| | ...
+| | ... | *Arguments:*
+| | ... | - number - Memif ID. Type: integer