+| | Set Test Variable | ${int} | vf
+| | Set interfaces in path up | validate=${validate}
+
+| Initialize layer driver on node
+| | [Documentation]
+| | ... | Initialize driver based interfaces on DUT.
+| |
+| | ... | *Arguments:*
+| | ... | - dut - DUT node.
+| | ... | Type: string
+| | ... | - driver - NIC driver used in test [vfio-pci|avf|rdma-core].
+| | ... | Type: string
+| |
+| | ... | *Example:*
+| |
+| | ... | \| Initialize layer driver \| DUT1 \| vfio-pci \|
+| |
+| | [Arguments] | ${dut} | ${driver}
+| |
+| | FOR | ${pf} | IN RANGE | 1 | ${nic_pfs} + 1
+| | | ${_vf}=
+| | | ... | Copy List | ${${dut}_${int}${pf}}
+| | | ${_ip4_addr}=
+| | | ... | Copy List | ${${dut}_${int}${pf}_ip4_addr}
+| | | ${_ip4_prefix}=
+| | | ... | Copy List | ${${dut}_${int}${pf}_ip4_prefix}
+| | | ${_mac}=
+| | | ... | Copy List | ${${dut}_${int}${pf}_mac}
+| | | ${_pci}=
+| | | ... | Copy List | ${${dut}_${int}${pf}_pci}
+| | | ${_vlan}=
+| | | ... | Copy List | ${${dut}_${int}${pf}_vlan}
+| | | Set Test Variable
+| | | ... | ${${dut}_vf${pf}} | ${_vf}
+| | | Set Test Variable
+| | | ... | ${${dut}_vf${pf}_ip4_addr} | ${_ip4_addr}
+| | | Set Suite Variable
+| | | ... | ${${dut}_vf${pf}_ip4_prefix} | ${_ip4_prefix}
+| | | Set Test Variable
+| | | ... | ${${dut}_vf${pf}_mac} | ${_mac}
+| | | Set Test Variable
+| | | ... | ${${dut}_vf${pf}_pci} | ${_pci}
+| | | Set Test Variable
+| | | ... | ${${dut}_vf${pf}_vlan} | ${_vlan}
+| | | Run Keyword | Initialize layer ${driver} on node | ${dut} | ${pf}
+| | END
+
+| Initialize layer tap on node
+| | [Documentation]
+| | ... | Initialize tap interfaces on DUT.
+| |
+| | ... | *Arguments:*
+| | ... | - dut - DUT node.
+| | ... | Type: string
+| | ... | - pf - TAP ID (logical port).
+| | ... | Type: integer
+| |
+| | ... | *Example:*
+| |
+| | ... | \| Initialize layer tap on node \| DUT1 \| 0 \|
+| |
+| | [Arguments] | ${dut} | ${pf}
+| |
+| | Create Namespace
+| | ... | ${nodes['${dut}']} | tap${${pf}-1}_namespace
+| | ${tap_feature_mask}= | Create Tap feature mask | gso=${enable_gso}
+| | ${_tap}=
+| | ... | And Add Tap Interface | ${nodes['${dut}']} | tap${${pf}-1}
+| | ... | host_namespace=tap${${pf}-1}_namespace
+| | ... | num_rx_queues=${rxq_count_int}
+| | ... | rxq_size=${nic_rxq_size} | txq_size=${nic_txq_size}
+| | ... | tap_feature_mask=${tap_feature_mask}
+| | ${_mac}=
+| | ... | Get Interface MAC | ${nodes['${dut}']} | tap${pf}
+| | ${_tap}= | Create List | ${_tap}
+| | ${_mac}= | Create List | ${_mac}
+| | Vhost User Affinity
+| | ... | ${nodes['${dut}']} | ${${dut}_pf${pf}}[0]
+| | ... | skip_cnt=${${CPU_CNT_MAIN}+${CPU_CNT_SYSTEM}+${cpu_count_int}}
+| | Set Test Variable
+| | ... | ${${dut}_vf${pf}} | ${_tap}
+| | Set Test Variable
+| | ... | ${${dut}_vf${pf}_mac} | ${_mac}
+
+| Initialize layer vhost on node
+| | [Documentation]
+| | ... | Initialize vhost interfaces on DUT.
+| |
+| | ... | *Arguments:*
+| | ... | - dut - DUT node.
+| | ... | Type: string
+| | ... | - pf - VHOST ID (logical port).
+| | ... | Type: integer
+| |
+| | ... | *Example:*
+| |
+| | ... | \| Initialize layer vhost on node \| DUT1 \| 0 \|
+| |
+| | [Arguments] | ${dut} | ${pf}
+| |
+| | ${virtio_feature_mask}= | Create Virtio feature mask | gso=${enable_gso}
+| | ${vhost}= | Vpp Create Vhost User Interface
+| | ... | ${nodes['${dut}']} | /var/run/vpp/sock-${pf}-1
+| | ... | is_server=${True} | virtio_feature_mask=${virtio_feature_mask}
+| | ${_mac}=
+| | ... | Get Interface MAC | ${nodes['${dut}']} | vhost${pf}
+| | ${_vhost}= | Create List | ${_vhost}
+| | ${_mac}= | Create List | ${_mac}
+| | Set Test Variable
+| | ... | ${${dut}_vf${pf}} | ${_vhost}
+| | Set Test Variable
+| | ... | ${${dut}_vf${pf}_mac} | ${_mac}