resources/libraries/robot/honeycomb/honeycomb.robot

   1 # Copyright (c) 2017 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.honeycomb.HoneycombSetup
  16 | Library | resources.libraries.python.honeycomb.HoneycombUtil
  17 | Library | resources.libraries.python.honeycomb.HcPersistence
  18 | Library | resources.libraries.python.DUTSetup
  19 | Library | resources.libraries.python.InterfaceUtil
  20
  21 *** Keywords ***
  22 | Configure Honeycomb service on DUTs
  23 | | [Documentation] | *Setup environment for honeycomb testing.*
  24 | | ...
  25 | | ... | _Setup steps:_
  26 | | ... | - 1. Login to each honeycomb node using ssh
  27 | | ... | - 2. Startup honeycomb service
  28 | | ... | - 3. Monitor service startup using HTTP GET request loop
  29 | | ... | Expected sequence of HTTP replies:
  30 | | ... | connection refused -> 404 -> 401 -> 503 or 500 -> 200 (pass)
  31 | | ... | - 4. Configure honeycomb nodes using HTTP PUT request
  32 | | ...
  33 | | ... | _Arguments:_
  34 | | ... | - duts - list of nodes to setup Honeycomb on
  35 | | ...
  36 | | ... | _Used global constants and variables:_
  37 | | ... | - RESOURCES_TPL_HC - path to honeycomb templates directory
  38 | | ... | - HTTPCodes - HTTP protocol status codes
  39 | | ...
  40 | | [Arguments] | @{duts}
  41 | | Start honeycomb on DUTs | @{duts}
  42 | | Wait until keyword succeeds | 4min | 16sec
  43 | | ... | Check honeycomb startup state | @{duts}
  44 | | Sleep | 5s | Make sure all modules are loaded and ready.
  45
  46 | Stop Honeycomb service on DUTs
  47 | | [Documentation] | *Cleanup environment after honeycomb testing.*
  48 | | ...
  49 | | ... | _Teardown steps:_
  50 | | ... | - 1. Login to each honeycomb node using ssh
  51 | | ... | - 2. Stop honeycomb service
  52 | | ... | - 3. Monitor service shutdown using HTTP GET request loop
  53 | | ... | Expected sequence of HTTP replies:
  54 | | ... | 200 -> 404 -> connection refused (pass)
  55 | | ...
  56 | | ... | _Arguments:_
  57 | | ... | - duts - list of nodes to stop Honeycomb on
  58 | | ...
  59 | | ... | _Used global constants and variables:_
  60 | | ... | - RESOURCES_TPL_HC - path to honeycomb templates directory
  61 | | ... | - HTTPCodes - HTTP protocol status codes
  62 | | ...
  63 | | [Arguments] | @{duts}
  64 | | Stop honeycomb on DUTs | @{duts}
  65 | | Wait until keyword succeeds | 60sec | 16sec
  66 | | ... | Check honeycomb shutdown state | @{duts}
  67
  68 | Clear persisted Honeycomb configuration
  69 | | [Documentation] | *Delete saved configuration.*
  70 | | ...
  71 | | ... | *Arguments:*
  72 | | ... | - duts - one or more nodes to clear persistence on. Type: dictionary
  73 | | ...
  74 | | ... | *Example:*
  75 | | ...
  76 | | ... | \| Clear persisted Honeycomb configuration \| ${nodes['DUT1']} \|
  77 | | ...
  78 | | [Arguments] | @{duts}
  79 | | Clear persisted Honeycomb config | @{duts}
  80
  81 | Restart Honeycomb and VPP and clear persisted configuration
  82 | | [Documentation] | Restarts Honeycomb and VPP with default configuration.
  83 | | ...
  84 | | ... | *Arguments:*
  85 | | ... | - node - information about a DUT node. Type: dictionary
  86 | | ...
  87 | | ... | *Example:*
  88 | | ...
  89 | | ... | \| Restart Honeycomb and VPP and clear persisted configuration \
  90 | | ... | \| ${nodes['DUT1']} \|
  91 | | ...
  92 | | [Arguments] | ${node}
  93 | | Stop Honeycomb service on DUTs | ${node}
  94 | | Clear persisted Honeycomb configuration | ${node}
  95 | | Setup DUT | ${node}
  96 | | Sleep | 10s | Wait 10sec so VPP is up for sure.
  97 | | Configure Honeycomb service on DUTs | ${node}
  98
  99 | Restart Honeycomb and VPP
 100 | | [Documentation] | Stops the Honeycomb service and verifies it is stopped.
 101 | | ... | Then restarts VPP, starts Honeycomb again and verifies it is running.
 102 | | ...
 103 | | ... | *Arguments:*
 104 | | ... | - node - information about a DUT node. Type: dictionary
 105 | | ...
 106 | | ... | *Example:*
 107 | | ...
 108 | | ... | \| Restart Honeycomb and VPP \| ${nodes['DUT1']} \|
 109 | | ...
 110 | | [Arguments] | ${node}
 111 | | Stop Honeycomb service on DUTs | ${node}
 112 | | Setup DUT | ${node}
 113 | | Sleep | 10s | Wait 10sec so VPP is up for sure.
 114 | | Configure Honeycomb service on DUTs | ${node}
 115
 116 | Restart Honeycomb and VPP in performance test
 117 | | [Documentation] | Stops Honeycomb and VPP and verifies HC is stopped.
 118 | | ... | Then restarts VPP, starts Honeycomb again and verifies it is running.
 119 | | ...
 120 | | ... | *Arguments:*
 121 | | ... | - node - information about a DUT node. Type: dictionary
 122 | | ...
 123 | | ... | *Example:*
 124 | | ...
 125 | | ... | \| Restart Honeycomb and VPP \| ${nodes['DUT1']} \|
 126 | | ...
 127 | | [Arguments] | ${node}
 128 | | Stop Honeycomb service on DUTs | ${node}
 129 | | Stop VPP service on DUT | ${node}
 130 | | Setup DUT | ${node}
 131 | | Sleep | 10s | Wait 10sec so VPP is up for sure.
 132 | | Configure Honeycomb service on DUTs | ${node}
 133 | | Wait until keyword succeeds | 2min | 16sec
 134 | | ... | Check honeycomb startup state | ${node}
 135
 136 | Archive Honeycomb log file
 137 | | [Documentation] | Copy honeycomb.log file from Honeycomb node\
 138 | | ... | to test executor.
 139 | | ...
 140 | | ... | *Arguments:*
 141 | | ... | - node - information about a DUT node. Type: dictionary
 142 | | ... | - perf - Running on performance testbed? Yes/no Type: boolean
 143 | | ...
 144 | | ... | *Example:*
 145 | | ...
 146 | | ... | \| Archive Honeycomb log file \| ${nudes['DUT1']} \|
 147 | | ...
 148 | | [Arguments] | ${node} | ${perf}=${False}
 149 | | Archive Honeycomb log | ${node} | ${perf}
 150
 151 | Configure ODL Client Service On DUT
 152 | | [Documentation] | Configure and start ODL client, then repeatedly check if
 153 | | ... | it is running.
 154 | | ...
 155 | | ... | *Arguments:*
 156 | | ... | - node - information about a DUT node. Type: dictionary
 157 | | ... | - odl_name - Name of ODL client version. Type: string
 158 | | ...
 159 | | ... | *Example:*
 160 | | ...
 161 | | ... | \| Configure ODL Client Service on DUT \| ${nodes['DUT1']} \
 162 | | ... | \| carbon-SR1 \|
 163 | | ...
 164 | | [Arguments] | ${node} | ${odl_name}
 165 | | Copy ODL Client | ${node} | ${odl_name} | /mnt/common | /tmp
 166 | | Setup ODL Client | ${node} | /tmp
 167 | | Wait until keyword succeeds | 2min | 30sec
 168 | | ... | Install ODL Features | ${node} | /tmp
 169 | | Wait until keyword succeeds | 4min | 16sec
 170 | | ... | Mount Honeycomb on ODL | ${node}
 171 | | Wait until keyword succeeds | 2min | 16sec
 172 | | ... | Check ODL startup state | ${node}
 173 | | Wait until keyword succeeds | 2min | 16sec
 174 | | ... | Check honeycomb startup state | ${node}
 175
 176 | Configure Honeycomb for functional testing
 177 | | [Documentation] | Configure Honeycomb with parameters for functional
 178 | | ... | testing, then start Honeycomb and repeatedly check startup status.
 179 | | ...
 180 | | ... | *Arguments:*
 181 | | ... | - node - information about a DUT node. Type: dictionary
 182 | | ...
 183 | | ... | *Example:*
 184 | | ...
 185 | | ... | \| Configure Honeycomb for functional testing \| ${nodes['DUT1']} \|
 186 | | ...
 187 | | [Arguments] | ${node}
 188 | | Configure Restconf binding address | ${node}
 189 | | Configure Log Level | ${node} | TRACE
 190 | | Configure Persistence | ${node} | disable
 191 | | Configure jVPP timeout | ${node} | ${14}
 192 | | Clear Persisted Honeycomb Configuration | ${node}
 193 | | Generate Honeycomb startup configuration for ODL test | ${node}
 194 | | Configure Honeycomb service on DUTs | ${node}
 195
 196 | Configure ODL Client for functional testing
 197 | | [Documentation] | Read external variable HC_ODL. Depending on its
 198 | | ... | value either: do nothing, or setup ODL client for testing and
 199 | | ... | create a global variable that modifies Restconf requests to use ODL.
 200 | | ...
 201 | | ... | *Arguments:*
 202 | | ... | - node - information about a DUT node. Type: dictionary
 203 | | ...
 204 | | ... | *Example:*
 205 | | ...
 206 | | ... | \| Configure ODL Client for functional testing \| ${nodes['DUT1']} \|
 207 | | ...
 208 | | [Arguments] | ${node}
 209 | | ${use_odl_client}= | Get Variable Value | ${HC_ODL}
 210 | | Run Keyword If | '${use_odl_client}' != '${NONE}'
 211 | | ... | Run Keywords
 212 | | ... | Set Global Variable | ${use_odl_client} | AND
 213 | | ... | Configure ODL Client Service On DUT | ${node} | ${use_odl_client}
 214 | | ... | ELSE | Log | Variable HC_ODL is not present. Not using ODL.
 215 | | ... | level=INFO
 216
 217 | Set Up Honeycomb Functional Test Suite
 218 | | [Documentation] | Generic test suite setup for Honeycomb functional tests.
 219 | | ... | Restarts VPP, then enables Honeycomb and optionally ODL, based
 220 | | ... | on external variable.
 221 | | ...
 222 | | ... | *Arguments:*
 223 | | ... | - node - information about a DUT node. Type: dictionary
 224 | | ...
 225 | | ... | *Example:*
 226 | | ...
 227 | | ... | \| Set Up Honeycomb Functional Test Suite \| ${nodes['DUT1']} \|
 228 | | ...
 229 | | [Arguments] | ${node}
 230 | | Setup DUT | ${node}
 231 | | Configure all TGs for traffic script
 232 | | Configure Honeycomb for functional testing | ${node}
 233 | | Configure ODL Client for functional testing | ${node}
 234
 235 | Tear Down Honeycomb Functional Test Suite
 236 | | [Documentation] | Generic test suite teardown for Honeycomb functional
 237 | | ... | tests. Stops ODL client (if used), then stops Honeycomb and verifies
 238 | | ... | that they are both stopped.
 239 | | ...
 240 | | ... | *Arguments:*
 241 | | ... | - node - information about a DUT node. Type: dictionary
 242 | | ...
 243 | | ... | *Example:*
 244 | | ...
 245 | | ... | \| Tear Down Honeycomb Functional Test Suite \| ${nodes['DUT1']} \|
 246 | | ...
 247 | | [Arguments] | ${node}
 248 | | ${use_odl_client}= | Get Variable Value | ${HC_ODL}
 249 | | Run Keyword If | '${use_odl_client}' != '${NONE}'
 250 | | ... | Run Keywords
 251 | | ... | Stop ODL Client | ${node} | /tmp | AND
 252 | | ... | Wait until keyword succeeds | 3min | 15sec
 253 | | ... | Check ODL shutdown state | ${node} | AND
 254 | | ... | Set Global Variable | ${use_odl_client} | ${NONE}
 255 | | Stop Honeycomb service on DUTs | ${node}
 256 | | Stop VPP Service on DUT | ${node}
 257
 258 | Enable Honeycomb Feature
 259 | | [Documentation] | Enable the specified feature in Honeycomb configuration.
 260 | | ... | Requires a restart of Honeycomb to take effect.
 261 | | ...
 262 | | ... | *Arguments:*
 263 | | ... | - node - information about a DUT node. Type: dictionary
 264 | | ...
 265 | | ... | *Example:*
 266 | | ...
 267 | | ... | \| Enable Honeycomb Feature \| ${nodes['DUT1']} \| NSH \|
 268 | | ...
 269 | | [arguments] | ${node} | ${feature}
 270 | | Manage Honeycomb Features | ${node} | ${feature}
 271
 272 | Disable Honeycomb Feature
 273 | | [Documentation] | Disable the specified feature in Honeycomb configuration.
 274 | | ... | Requires a restart of Honeycomb to take effect.
 275 | | ...
 276 | | ... | *Arguments:*
 277 | | ... | - node - information about a DUT node. Type: dictionary
 278 | | ...
 279 | | ... | *Example:*
 280 | | ...
 281 | | ... | \| Disable Honeycomb Feature \| ${nodes['DUT1']} \| NSH \|
 282 | | ...
 283 | | [arguments] | ${node} | ${feature}
 284 | | Manage Honeycomb Features | ${node} | ${feature} | disable=${True}
 285
 286 | Stop VPP Service on DUT
 287 | | [Documentation] | Stop the VPP service on the specified node.
 288 | | ...
 289 | | ... | *Arguments:*
 290 | | ... | - node - information about a DUT node. Type: dictionary
 291 | | ...
 292 | | ... | *Example:*
 293 | | ...
 294 | | ... | \| Stop VPP Service on DUT \| ${nodes['DUT1']} \|
 295 | | ...
 296 | | [Arguments] | ${node}
 297 | | Stop VPP Service | ${node}
 298
 299 | Honeycomb Performance Suite Setup Generic
 300 | | [Documentation] | Generic test suite setup for Honeycomb performance tests.
 301 | | ... | Performs multiple attempts to start Honeycomb+VPP stack.
 302 | | ...
 303 | | ... | *Arguments:*
 304 | | ... | - node - information about a DUT node. Type: dictionary
 305 | | ...
 306 | | ... | *Example:*
 307 | | ...
 308 | | ... | \| Honeycomb Performance Suite Setup Generic \| ${nodes['DUT1']} \|
 309 | | ...
 310 | | [Arguments] | ${node}
 311 | | Wait until keyword succeeds | 8min | 2min
 312 | | ... | Restart Honeycomb and VPP in Performance test | ${node}
 313
 314 | Honeycomb Performance Suite Teardown Generic
 315 | | [Documentation] | Generic test suite teardown for Honeycomb performance
 316 | | ... | tests. Logs CPU usage before stopping Honeycomb.
 317 | | ...
 318 | | ... | *Arguments:*
 319 | | ... | - node - information about a DUT node. Type: dictionary
 320 | | ...
 321 | | ... | *Example:*
 322 | | ...
 323 | | ... | \| Honeycomb Performance Suite Teardown Generic \| ${nodes['DUT1']} \|
 324 | | ...
 325 | | [Arguments] | ${node}
 326 | | Log Honeycomb and VPP process distribution on cores | ${node}
 327 | | Stop Honeycomb service on DUTs | ${node}
 328 | | Stop VPP Service on DUT | ${node}
 329
 330 | Generate Honeycomb startup configuration for ODL test
 331 | | [Documentation] | Create HC startup configuration and apply to config
 332 | | ... | file on DUT. Requires Honeycomb restart to take effect.
 333 | | ...
 334 | | ... | *Arguments:*
 335 | | ... | - node - Honeycomb node. Type: dictionary
 336 | | ...
 337 | | ... | *Example:*
 338 | | ...
 339 | | ... | \| Generate Honeycomb startup configuration for ODL test \
 340 | | ... | \| ${nodes[DUT1]} \|
 341 | | ...
 342 | | [Arguments] | ${node}
 343 | | Import Library | resources.libraries.python.honeycomb.HoneycombSetup.HoneycombStartupConfig
 344 | | ... | WITH NAME | HC_config
 345 | | Run Keyword | HC_config.Set SSH Security provider
 346 | | Run Keyword | HC_config.Set Memory Size | ${32}
 347 | | Run Keyword | HC_config.Set Metaspace Size | ${32}
 348 | | Run Keyword | HC_config.Apply config | ${node}