resources/libraries/robot/honeycomb/interfaces.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.InterfaceUtil
  16 | ...     | WITH NAME | interfaceCLI
  17 | Library | resources.libraries.python.honeycomb.HcAPIKwInterfaces.InterfaceKeywords
  18 | ...     | WITH NAME | InterfaceAPI
  19
  20 *** Keywords ***
  21 | Interface state is
  22 | | [Documentation] | Uses VPP binary API to ensure that the interface under\
  23 | | ... | test is in the specified admin state.
  24 | | ...
  25 | | ... | *Arguments:*
  26 | | ... | - node - information about a DUT node. Type: dictionary
  27 | | ... | - interface - name of an interface on the specified node. Type: string
  28 | | ... | - state - state to set on interface. Type:string
  29 | | ...
  30 | | ... | *Example:*
  31 | | ...
  32 | | ... | \| Interface state is \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \
  33 | | ... | \| up \|
  34 | | [Arguments] | ${node} | ${interface} | ${state}
  35 | | interfaceCLI.Set interface state | ${node} | ${interface} | ${state}
  36 | | ... | if_type=name
  37
  38 | Honeycomb sets interface state
  39 | | [Documentation] | Uses Honeycomb API to change the admin state\
  40 | | ... | of the specified interface.
  41 | | ...
  42 | | ... | *Arguments:*
  43 | | ... | - node - information about a DUT node. Type: dictionary
  44 | | ... | - interface - name of an interface on the specified node. Type: string
  45 | | ... | - state - state to set on interface. Type:string
  46 | | ...
  47 | | ... | *Example:*
  48 | | ...
  49 | | ... | \| Honeycomb sets interface state \| ${nodes['DUT1']} \
  50 | | ... | \| GigabitEthernet0/8/0 \| up \|
  51 | | [Arguments] | ${node} | ${interface} | ${state}
  52 | | interfaceAPI.Set interface state | ${node} | ${interface} | ${state}
  53
  54 | Interface state from Honeycomb should be
  55 | | [Documentation] | Retrieves interface admin state through Honeycomb and\
  56 | | ... | compares with state supplied in argument.
  57 | | ...
  58 | | ... | *Arguments:*
  59 | | ... | - node - information about a DUT node. Type: dictionary
  60 | | ... | - interface - name of an interface on the specified node. Type: string
  61 | | ... | - state - expected interface state. Type: string
  62 | | ...
  63 | | ... | *Example:*
  64 | | ...
  65 | | ... | \| Interface state from Honeycomb should be \| ${nodes['DUT1']} \
  66 | | ... | \| GigabitEthernet0/8/0 \| up \|
  67 | | [Arguments] | ${node} | ${interface} | ${state}
  68 | | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
  69 | | ${api_state}= | Set Variable | ${api_data['admin-status']}
  70 | | Should be equal | ${api_state} | ${state}
  71
  72 | Interface state from VAT should be
  73 | | [Documentation] | Retrieves interface admin state through VAT and compares\
  74 | | ... | with state supplied in argument.
  75 | | ...
  76 | | ... | *Arguments:*
  77 | | ... | - node - information about a DUT node. Type: dictionary
  78 | | ... | - interface - name of an interface on the specified node. Type: string
  79 | | ... | - state - expected interface state. Type: string
  80 | | ...
  81 | | ... | _NOTE:_ Vat returns state as int (1/0) instead of string (up/down).
  82 | | ... | This keyword also handles translation.
  83 | | ...
  84 | | ... | *Example:*
  85 | | ...
  86 | | ... | \| Interface state from VAT should be \| ${nodes['DUT1']} \
  87 | | ... | \| GigabitEthernet0/8/0 \| up \|
  88 | | [Arguments] | ${node} | ${interface} | ${state}
  89 | | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
  90 | | ${vat_state}= | Set Variable if
  91 | | ... | ${vat_data['admin_up_down']} == 1 | up | down
  92 | | Should be equal | ${vat_state} | ${state}
  93
  94 | Honeycomb sets interface ipv4 address
  95 | | [Documentation] | Uses Honeycomb API to change ipv4 configuration\
  96 | | ... | of the specified interface.
  97 | | ...
  98 | | ... | *Arguments:*
  99 | | ... | - node - information about a DUT node. Type: dictionary
 100 | | ... | - interface - name of an interface on the specified node. Type: string
 101 | | ... | - address - IP address to set. Type: string
 102 | | ... | - netmask - subnet mask to set. Type: string
 103 | | ... | - settings - ipv4 interface settings. Type: dictionary
 104 | | ...
 105 | | ... | *Example:*
 106 | | ...
 107 | | ... | \| Honeycomb sets interface ipv4 configuration \| ${nodes['DUT1']} \
 108 | | ... | \| GigabitEthernet0/8/0 \| 192.168.0.2 \| 255.255.255.0 \
 109 | | ... | \| ${{'enabled': True, 'mtu': 1500}} \|
 110 | | [Arguments] | ${node} | ${interface} | ${address} | ${netmask}
 111 | | ... | ${settings}
 112 | | interfaceAPI.Add first ipv4 address
 113 | | ... | ${node} | ${interface} | ${address} | ${netmask}
 114 | | :FOR | ${key} | IN | @{settings.keys()}
 115 | | | interfaceAPI.Configure interface ipv4
 116 | | | ... | ${node} | ${interface} | ${key} | ${settings['${key}']}
 117
 118 | Honeycomb sets interface ipv4 address with prefix
 119 | | [Documentation] | Uses Honeycomb API to assign an ipv4 address to the\
 120 | | ... | specified interface. Any existing addresses will be removed.
 121 | | ...
 122 | | ... | *Arguments:*
 123 | | ... | - node - information about a DUT node. Type: dictionary
 124 | | ... | - interface - name of an interface on the specified node. Type: string
 125 | | ... | - address - IP address to set. Type: string
 126 | | ... | - prefix - length of address network prefix. Type: int
 127 | | ... | - settings - ipv4 interface settings. Type: dictionary
 128 | | ...
 129 | | ... | *Example:*
 130 | | ...
 131 | | ... | \| Honeycomb sets interface ipv4 address with prefix \
 132 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| 192.168.0.2 \| 24 \|
 133 | | [Arguments] | ${node} | ${interface} | ${address} | ${prefix}
 134 | | ... | ${settings}
 135 | | interfaceAPI.Add first ipv4 address
 136 | | ... | ${node} | ${interface} | ${address} | ${prefix}
 137 | | :FOR | ${key} | IN | @{settings.keys()}
 138 | | | interfaceAPI.Configure interface ipv4
 139 | | | ... | ${node} | ${interface} | ${key} | ${settings['${key}']}
 140
 141 | Honeycomb adds interface ipv4 neighbor
 142 | | [Documentation] | Uses Honeycomb API to assign an ipv4 neighbor to the\
 143 | | ... | specified interface.
 144 | | ...
 145 | | ... | *Arguments:*
 146 | | ... | - node - information about a DUT node. Type: dictionary
 147 | | ... | - interface - name of an interface on the specified node. Type: string
 148 | | ... | - fib_address - IP address to add to fib table. Type: string
 149 | | ... | - fib_mac - MAC address to add to fib table. Type: string
 150 | | ...
 151 | | ... | *Example:*
 152 | | ...
 153 | | ... | \| Honeycomb adds interface ipv4 neighbor \| ${nodes['DUT1']} \
 154 | | ... | \| GigabitEthernet0/8/0 \| 192.168.0.3 \| 08:00:27:c0:5d:37 \
 155 | | ... | \| ${{'enabled': True, 'mtu': 1500}} \|
 156 | | [Arguments] | ${node} | ${interface} | ${fib_address} | ${fib_mac}
 157 | | interfaceAPI.Add ipv4 neighbor
 158 | | ... | ${node} | ${interface} | ${fib_address} | ${fib_mac}
 159
 160 | IPv4 config from Honeycomb should be
 161 | | [Documentation] | Retrieves interface ipv4 configuration through Honeycomb\
 162 | | ... | and compares with state supplied in argument.
 163 | | ...
 164 | | ... | *Arguments:*
 165 | | ... | - node - information about a DUT node. Type: dictionary
 166 | | ... | - interface - name of an interface on the specified node. Type: string
 167 | | ... | - address - IP address to expect. Type: string
 168 | | ... | - prefix - prefix length to expect. Type: string
 169 | | ... | - fib_address - IP address to expect in fib table. Type: string
 170 | | ... | - fib_mac - MAC address to expect in fib table. Type: string
 171 | | ... | - settings - ipv4 interface settings to expect. Type: dictionary
 172 | | ...
 173 | | ... | *Example:*
 174 | | ...
 175 | | ... | \| IPv4 config from Honeycomb should be \| ${nodes['DUT1']} \
 176 | | ... | \| GigabitEthernet0/8/0 \| 192.168.0.2 \| 255.255.255.0 \
 177 | | ... | \| 192.168.0.3 \| 08:00:27:c0:5d:37 \
 178 | | ... | \| ${{'enabled': True, 'mtu': 1500}} \|
 179 | | [Arguments] | ${node} | ${interface} | ${address} | ${prefix}
 180 | | ... | ${fib_address} | ${fib_mac} | ${settings}
 181 | | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
 182 | | Should be equal | ${address}
 183 | | ... | ${api_data['ietf-ip:ipv4']['address'][0]['ip']}
 184 | | Should be equal | ${prefix}
 185 | | ... | ${api_data['ietf-ip:ipv4']['address'][0]['prefix-length']}
 186 | | Should be equal | ${fib_address}
 187 | | ... | ${api_data['ietf-ip:ipv4']['neighbor'][0]['ip']}
 188 | | Should be equal | ${fib_mac}
 189 | | ... | ${api_data['ietf-ip:ipv4']['neighbor'][0]['link-layer-address']}
 190 | | :FOR | ${key} | IN | @{settings.keys()}
 191 | | | Should be equal
 192 | | | ... | ${settings['${key}']} | ${api_data['ietf-ip:ipv4']['${key}']}
 193
 194 | IPv4 config from VAT should be
 195 | | [Documentation] | Retrieves interface ipv4 configuration through VAT and\
 196 | | ... | compares with state supplied in argument.
 197 | | ...
 198 | | ... | *Arguments:*
 199 | | ... | - node - information about a DUT node. Type: dictionary
 200 | | ... | - interface - name of an interface on the specified node. Type: string
 201 | | ... | - address - IP address to expect. Type: string
 202 | | ... | - netmask - subnet mask to expect. Type: string
 203 | | ...
 204 | | ... | *Example:*
 205 | | ...
 206 | | ... | \| IPv4 config from VAT should be \| ${nodes['DUT1']} \
 207 | | ... | \| GigabitEthernet0/8/0 \| 192.168.0.2 \| 255.255.255.0 \|
 208 | | [Arguments] | ${node} | ${interface} | ${address} | ${netmask}
 209 | | ${vpp_data}= | interfaceCLI.VPP get interface ip addresses
 210 | | ... | ${node} | ${interface} | ipv4
 211 | | Should be equal | ${vpp_data[0]['ip']} | ${address}
 212 | | Should be equal | ${vpp_data[0]['netmask']} | ${netmask}
 213
 214 | Honeycomb removes interface ipv4 addresses
 215 | | [Documentation] | Removes all configured ipv4 addresses from the specified\
 216 | | ... | interface.
 217 | | ...
 218 | | ... | *Arguments:*
 219 | | ... | - node - information about a DUT node. Type: dictionary
 220 | | ... | - interface - name of an interface on the specified node. Type: string
 221 | | ...
 222 | | ... | *Example:*
 223 | | ...
 224 | | ... | \| Honeycomb removes interface ipv4 addresses \| ${nodes['DUT1']} \
 225 | | ... | \| GigabitEthernet0/8/0 \|
 226 | | [Arguments] | ${node} | ${interface}
 227 | | Remove all ipv4 addresses | ${node} | ${interface}
 228
 229 | IPv4 address from Honeycomb should be empty
 230 | | [Documentation] | Retrieves interface ipv4 configuration through Honeycomb\
 231 | | ... | and expects to find no IPv4 addresses.
 232 | | ...
 233 | | ... | *Arguments:*
 234 | | ... | - node - information about a DUT node. Type: dictionary
 235 | | ... | - interface - name of an interface on the specified node. Type: string
 236 | | ...
 237 | | ... | *Example:*
 238 | | ...
 239 | | ... | \| IPv4 address from Honeycomb should be empty\| ${nodes['DUT1']} \
 240 | | ... | \| GigabitEthernet0/8/0 \|
 241 | | [Arguments] | ${node} | ${interface}
 242 | | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
 243 | | Should be empty | ${api_data['ietf-ip:ipv4']['address']
 244
 245 | IPv4 address from VAT should be empty
 246 | | [Documentation] | Retrieves interface ipv4 configuration through VAT and\
 247 | | ... | and expects to find no ipv4 addresses.
 248 | | ...
 249 | | ... | *Arguments:*
 250 | | ... | - node - information about a DUT node. Type: dictionary
 251 | | ... | - interface - name of an interface on the specified node. Type: string
 252 | | ...
 253 | | ... | *Example:*
 254 | | ...
 255 | | ... | \| IPv4 config from VAT should be empty \| ${nodes['DUT1']} \
 256 | | ... | \| GigabitEthernet0/8/0 \|
 257 | | [Arguments] | ${node} | ${interface}
 258 | | Run keyword and expect error | *No JSON object could be decoded.*
 259 | | ... | InterfaceCLI.VPP get interface ip addresses
 260 | | ... | ${node} | ${interface} | ipv4
 261
 262 | Honeycomb sets interface ipv6 configuration
 263 | | [Documentation] | Uses Honeycomb API to change ipv6 configuration\
 264 | | ... | of the specified interface.
 265 | | ...
 266 | | ... | *Arguments:*
 267 | | ... | - node - information about a DUT node. Type: dictionary
 268 | | ... | - interface - name of an interface on the specified node. Type: string
 269 | | ... | - address - IP address to set. Type: string
 270 | | ... | - prefix - length of subnet prefix to set. Type: string
 271 | | ... | - fib_address - IP address to add to fib table. Type: string
 272 | | ... | - fib_mac - MAC address to add to fib table. Type: string
 273 | | ... | - settings - ipv6 interface settings. Type: dictionary
 274 | | ...
 275 | | ... | *Example:*
 276 | | ...
 277 | | ... | \| Honeycomb sets interface ipv6 configuration \| ${nodes['DUT1']} \
 278 | | ... | \| GigabitEthernet0/8/0 \| 10::10 \| 64 \
 279 | | ... | \| 10::11 \| 08:00:27:c0:5d:37 \| ${{'enabled': True, 'mtu': 1500}} \|
 280 | | [Arguments] | ${node} | ${interface} | ${address} | ${prefix}
 281 | | ... | ${fib_address} | ${fib_mac} | ${settings}
 282 | | interfaceAPI.Add first ipv6 address
 283 | | ... | ${node} | ${interface} | ${address} | ${prefix}
 284 | | interfaceAPI.Add first ipv6 neighbor
 285 | | ... | ${node} | ${interface} | ${fib_address} | ${fib_mac}
 286 | | :FOR | ${key} | IN | @{settings.keys()}
 287 | | | interfaceAPI.Configure interface ipv6
 288 | | | ... | ${node} | ${interface} | ${key} | ${settings['${key}']}
 289
 290 | IPv6 config from Honeycomb should be
 291 | | [Documentation] | Retrieves interface ipv6 configuration through Honeycomb\
 292 | | ... | and compares with state supplied in argument.
 293 | | ...
 294 | | ... | *Arguments:*
 295 | | ... | - node - information about a DUT node. Type: dictionary
 296 | | ... | - interface - name of an interface on the specified node. Type: string
 297 | | ... | - address - IP address to expect. Type: string
 298 | | ... | - prefix - length of subnet prefix to expect. Type: string
 299 | | ... | - fib_address - IP address to expect in fib table. Type: string
 300 | | ... | - fib_mac - MAC address to expect in fib table. Type: string
 301 | | ... | - settings - ipv6 interface settings to expect. Type: dictionary
 302 | | ...
 303 | | ... | *Example:*
 304 | | ...
 305 | | ... | \| IPv6 config from Honeycomb should be \| ${nodes['DUT1']} \
 306 | | ... | \| GigabitEthernet0/8/0 \| 10::10 \| 64 \
 307 | | ... | \| 10::11 \| 08:00:27:c0:5d:37 \| ${{'enabled': True, 'mtu': 1500}} \|
 308 | | [Arguments] | ${node} | ${interface} | ${address} | ${prefix}
 309 | | ... | ${fib_address} | ${fib_mac} | ${settings}
 310 | | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
 311 | | Should be equal | ${address}
 312 | | ... | ${api_data['ietf-ip:ipv6']['address'][0]['ip']}
 313 | | Should be equal | ${prefix}
 314 | | ... | ${api_data['ietf-ip:ipv6']['address'][0]['prefix-length']}
 315 | | Should be equal | ${fib_address}
 316 | | ... | ${api_data['ietf-ip:ipv6']['neighbor'][0]['ip']
 317 | | Should be equal | ${fib_mac}
 318 | | ... | ${api_data['ietf-ip:ipv6']['neighbor'][0]['link-layer-address']
 319 | | :FOR | ${key} | IN | @{settings.keys()}
 320 | | | Should be equal
 321 | | ... | ${settings['{key']} | ${api_data['ietf-ip:ipv6']['{$key}']}
 322
 323 | IPv6 config from VAT should be
 324 | | [Documentation] | Retrieves interface ipv6 configuration through VAT and\
 325 | | ... | compares with state supplied in argument.
 326 | | ...
 327 | | ... | *Arguments:*
 328 | | ... | - node - information about a DUT node. Type: dictionary
 329 | | ... | - interface - name of an interface on the specified node. Type: string
 330 | | ... | - address - IP address to expect. Type: string
 331 | | ... | - prefix - length of subnet prefix to expect. Type: string
 332 | | ...
 333 | | ... | *Example:*
 334 | | ...
 335 | | ... | \| IPv6 config from VAT should be \| ${nodes['DUT1']} \
 336 | | ... | \| GigabitEthernet0/8/0 \| 10::10 \| 64 \|
 337 | | [Arguments] | ${node} | ${interface} | ${address} | ${prefix}
 338 | | ${vpp_data}= | interfaceCLI.VPP get interface ip addresses
 339 | | ... | ${node} | ${interface} | ipv6
 340 | | Should be equal | ${vpp_data[0]['ip']} | ${address}
 341 | | Should be equal | ${vpp_data[0]['prefix-length']} | ${prefix}
 342
 343 | Honeycomb sets interface ethernet and routing configuration
 344 | | [Documentation] | Uses Honeycomb API to change interface configuration.
 345 | | ...
 346 | | ... | *Arguments:*
 347 | | ... | - node - information about a DUT node. Type: dictionary
 348 | | ... | - interface - name of an interface on the specified node. Type: string
 349 | | ... | - ethernet - interface ethernet settings. Type: dictionary
 350 | | ... | - routing - interface routing settings. Type: dictionary
 351 | | ...
 352 | | ... | *Example:*
 353 | | ...
 354 | | ... | \| Honeycomb sets interface ethernet and routing configuration \
 355 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| ${{'mtu': 1500}} \
 356 | | ... | \| ${{'vrf-if': 2}} \|
 357 | | [Arguments] | ${node} | ${interface} | ${ethernet} | ${routing}
 358 | | :FOR | ${key} | IN | @{ethernet.keys()}
 359 | | | interfaceAPI.Configure interface ethernet
 360 | | | ... | ${node} | ${interface} | ${key} | ${ethernet['${key}']}
 361 | | :FOR | ${key} | IN | @{routing.keys()}
 362 | | | interfaceAPI.Configure interface routing
 363 | | | ... | ${node} | ${interface} | ${key} | ${routing['${key}']}
 364
 365 | Interface ethernet and routing configuration from Honeycomb should be
 366 | | [Documentation] | Retrieves interface routing and ethernet configuration\
 367 | | ... | through Honeycomb and compares with settings supplied in arguments.
 368 | | ...
 369 | | ... | *Arguments:*
 370 | | ... | - node - information about a DUT node. Type: dictionary
 371 | | ... | - interface - name of an interface on the specified node. Type: string
 372 | | ... | - ethernet - interface ethernet settings. Type: dictionary
 373 | | ... | - routing - interface routing settings. Type: dictionary
 374 | | ...
 375 | | ... | *Example:*
 376 | | ...
 377 | | ... | \| Interface ethernet and routing configuration from Honeycomb \
 378 | | ... | should be \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \
 379 | | ... | \| ${{'mtu': 1500}} \| ${{'vrf-id': 2}} \|
 380 | | [Arguments] | ${node} | ${interface} | ${ethernet} | ${routing}
 381 | | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
 382 | | :FOR | ${key} | IN | @{ethernet.keys()}
 383 | | | Should be equal
 384 | | | ... | ${api_data['v3po:ethernet']['${key}']} | ${ethernet['${key}']}
 385 | | :FOR | ${key} | IN | @{routing.keys()}
 386 | | | Should be equal | ${api_data['${key}']} | ${routing['${key}']}
 387
 388 | Interface ethernet and routing configuration from VAT should be
 389 | | [Documentation] | Retrieves interface routing and ethernet configuration\
 390 | | ... | through VAT and compares with settings supplied in arguments.
 391 | | ...
 392 | | ... | *Arguments:*
 393 | | ... | - node - information about a DUT node. Type: dictionary
 394 | | ... | - interface - name of an interface on the specified node. Type: string
 395 | | ... | - mtu - value of maximum transmission unit expected. Type: integer
 396 | | ... | - vrf-id - ID number of a VPN expected on interface. Type: integer
 397 | | ...
 398 | | ... | *Example:*
 399 | | ...
 400 | | ... | \| Interface ethernet and routing configuration from VAT \
 401 | | ... | should be \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \| ${1500} \
 402 | | ... | \| ${2} \|
 403 | | [Arguments] | ${node} | ${interface} | ${mtu} | ${vrf-id}
 404 | | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
 405 | | Should be equal | ${vat_data['mtu']} | ${mtu}
 406
 407 | Interface configuration from Honeycomb should be empty
 408 | | [Documentation] | Attempts to retrieve interface configuration through\
 409 | | ... | Honeycomb and expects to get empty dictionary.
 410 | | ...
 411 | | ... | *Arguments:*
 412 | | ... | - node - information about a DUT node. Type: dictionary
 413 | | ... | - interface - name of a interface on the specified node. Type:\
 414 | | ... | string
 415 | | ...
 416 | | ... | *Example:*
 417 | | ... | \| Interface configuration from Honeycomb should be empty\
 418 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \|
 419 | | ...
 420 | | [Arguments] | ${node} | ${interface}
 421 | | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
 422 | | Should be empty | ${api_data}
 423
 424 | Interface configuration from VAT should be empty
 425 | | [Documentation] | Attempts to retrieve Interface configuration through\
 426 | | ... | VAT and expects to get empty dictionary.
 427 | | ...
 428 | | ... | *Arguments:*
 429 | | ... | - node - information about a DUT node. Type: dictionary
 430 | | ... | - interface - name of a Interface on the specified node. Type:\
 431 | | ... | string
 432 | | ...
 433 | | ... | *Example:*
 434 | | ... | \| Interface configuration from VAT should be empty\
 435 | | ... | \| ${nodes['DUT1']} \| GigabitEthernet0/8/0 \|
 436 | | ...
 437 | | [Arguments] | ${node} | ${interface} |
 438 | | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
 439 | | Should be empty | ${vat_data}
 440
 441 | Interface indices from Honeycomb and VAT should correspond
 442 | | [Documentation] | Uses VAT and Honeycomb to get operational data about the\
 443 | | ... | given interface and compares the interface indexes. The interface
 444 | | ... | index from Honeycomb should be greater than index from VAT by one.
 445 | | ...
 446 | | ... | *Arguments:*
 447 | | ... | - node - information about a DUT node. Type: dictionary
 448 | | ... | - interface - name of the interface to be checked. Type: string
 449 | | ...
 450 | | ... | *Example:*
 451 | | ...
 452 | | ... | \| Interface indices from Honeycomb and VAT should correspond \
 453 | | ... | \| ${nodes['DUT1']} \| vxlan_gpe_tunnel0 \|
 454 | | ...
 455 | | [Arguments] | ${node} | ${interface}
 456 | | ...
 457 | | ${api_data}= | interfaceAPI.Get interface oper data | ${node} | ${interface}
 458 | | ${vat_data}= | InterfaceCLI.VPP get interface data | ${node} | ${interface}
 459 | | ${sw_if_index}= | EVALUATE | ${vat_data['sw_if_index']} + 1
 460 | | Should be equal as strings
 461 | | ... | ${api_data['if-index']} | ${sw_if_index}