resources/libraries/robot/ip/ip4.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.InterfaceUtil
  16 | Library | resources.libraries.python.IPv4Util.IPv4Util
  17 | Library | resources.libraries.python.IPv4Setup.IPv4Setup
  18 | Library | resources.libraries.python.NodePath
  19 | Library | resources.libraries.python.Routing
  20 | Library | resources.libraries.python.TrafficScriptExecutor
  21 | Resource | resources/libraries/robot/shared/counters.robot
  22 | Resource | resources/libraries/robot/shared/default.robot
  23 | Resource | resources/libraries/robot/shared/testing_path.robot
  24 | Variables | resources/libraries/python/IPv4NodeAddress.py | ${nodes}
  25 | ...
  26 | Documentation | IPv4 keywords
  27
  28 *** Keywords ***
  29 | Show IP FIB On All DUTs
  30 | | [Documentation] | Show IP FIB on all DUTs.
  31 | | ...
  32 | | ${duts}= | Get Matches | ${nodes} | DUT*
  33 | | :FOR | ${dut} | IN | @{duts}
  34 | | | VPP Show IP Table | ${nodes['${dut}']}
  35
  36 | Configure IPv4 addresses on all DUTs
  37 | | [Documentation] | Setup IPv4 address on all DUTs in topology
  38 | | [Arguments] | ${nodes} | ${nodes_addr}
  39 | | ${interfaces}= | VPP nodes set ipv4 addresses | ${nodes} | ${nodes_addr}
  40 | | :FOR | ${interface} | IN | @{interfaces}
  41 | | | Set Interface State | @{interface} | up | if_type=name
  42
  43 | Configure routes for IPv4 test
  44 | | [Documentation] | Setup routing on all VPP nodes required for IPv4 tests
  45 | | [Arguments] | ${nodes} | ${nodes_addr}
  46 | | Append Nodes | ${nodes['DUT1']} | ${nodes['DUT2']}
  47 | | Compute Path
  48 | | ${tg}= | Set Variable | ${nodes['TG']}
  49 | | ${dut1_if} | ${dut1}= | First Interface
  50 | | ${dut2_if} | ${dut2}= | Last Interface
  51 | | ${dut1_if_addr}= | Get IPv4 address of node "${dut1}" interface "${dut1_if}" from "${nodes_addr}"
  52 | | ${dut2_if_addr}= | Get IPv4 address of node "${dut2}" interface "${dut2_if}" from "${nodes_addr}"
  53 | | @{tg_dut1_links}= | Get active links connecting "${tg}" and "${dut1}"
  54 | | @{tg_dut2_links}= | Get active links connecting "${tg}" and "${dut2}"
  55 | | :FOR | ${link} | IN | @{tg_dut1_links}
  56 | | | ${net}= | Get Link Address | ${link} | ${nodes_addr}
  57 | | | ${prefix}= | Get Link Prefix | ${link} | ${nodes_addr}
  58 | | | Vpp Route Add | ${dut2} | ${net} | ${prefix} | ${dut1_if_addr}
  59 | | | ... | ${dut2_if}
  60 | | :FOR | ${link} | IN | @{tg_dut2_links}
  61 | | | ${net}= | Get Link Address | ${link} | ${nodes_addr}
  62 | | | ${prefix}= | Get Link Prefix | ${link} | ${nodes_addr}
  63 | | | Vpp Route Add | ${dut1} | ${net} | ${prefix} | ${dut2_if_addr}
  64 | | | ... | ${dut1_if}
  65
  66 | Configure DUT nodes for IPv4 testing
  67 | | Configure IPv4 addresses on all DUTs | ${nodes} | ${nodes_ipv4_addr}
  68 | | Setup ARP on all DUTs | ${nodes} | ${nodes_ipv4_addr}
  69 | | Configure routes for IPv4 test | ${nodes} | ${nodes_ipv4_addr}
  70 | | All Vpp Interfaces Ready Wait | ${nodes}
  71
  72 | Route traffic from interface '${from_port}' on node '${from_node}' to interface '${to_port}' on node '${to_node}' '${hops}' hops away using IPv4
  73 | | ${src_ip}= | Get IPv4 address of node "${from_node}" interface "${from_port}" from "${nodes_ipv4_addr}"
  74 | | ${dst_ip}= | Get IPv4 address of node "${to_node}" interface "${to_port}" from "${nodes_ipv4_addr}"
  75 | | ${src_mac}= | Get interface mac | ${from_node} | ${from_port}
  76 | | ${dst_mac}= | Get interface mac | ${to_node} | ${to_port}
  77 | | ${is_dst_tg}= | Is TG node | ${to_node}
  78 | | ${adj_node} | ${adj_int}= | Get adjacent node and interface | ${nodes}
  79 | | ... | ${from_node} | ${from_port}
  80 | | ${from_port_name}= | Get interface name | ${from_node} | ${from_port}
  81 | | ${to_port_name}= | Get interface name | ${to_node} | ${to_port}
  82 | | ${adj_int_mac}= | Get interface MAC | ${adj_node} | ${adj_int}
  83 | | ${args}= | Traffic Script Gen Arg | ${to_port_name} | ${from_port_name}
  84 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
  85 | | ${args}= | Catenate | ${args} | --hops ${hops}
  86 | | ... | --first_hop_mac ${adj_int_mac} | --is_dst_tg ${is_dst_tg}
  87 | | Run Traffic Script On Node | ipv4_ping_ttl_check.py | ${from_node} | ${args}
  88
  89 | Execute IPv4 ICMP echo sweep
  90 | | [Documentation] | Type of the src_node must be TG and dst_node must be DUT
  91 | | [Arguments] | ${src_node} | ${dst_node} | ${start_size} | ${end_size}
  92 | | ... | ${step}
  93 | | Append Nodes | ${src_node} | ${dst_node}
  94 | | Compute Path
  95 | | ${src_port} | ${src_node}= | First Interface
  96 | | ${dst_port} | ${dst_node}= | Last Interface
  97 | | ${src_ip}= | Get IPv4 address of node "${src_node}" interface "${src_port}" from "${nodes_ipv4_addr}"
  98 | | ${dst_ip}= | Get IPv4 address of node "${dst_node}" interface "${dst_port}" from "${nodes_ipv4_addr}"
  99 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
 100 | | ${dst_mac}= | Get Interface Mac | ${dst_node} | ${dst_port}
 101 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
 102 | | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
 103 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
 104 | | ${args}= | Catenate | ${args} | --start_size ${start_size}
 105 | | ... | --end_size ${end_size} | --step ${step}
 106 | | Run Traffic Script On Node | ipv4_sweep_ping.py | ${src_node} | ${args}
 107 | | ... | timeout=${180}
 108
 109 | Send ARP request and verify response
 110 | | [Arguments] | ${tg_node} | ${vpp_node}
 111 | | ${link_name}= | Get first active connecting link between node "${tg_node}" and "${vpp_node}"
 112 | | ${src_if}= | Get interface by link name | ${tg_node} | ${link_name}
 113 | | ${dst_if}= | Get interface by link name | ${vpp_node} | ${link_name}
 114 | | ${src_ip}= | Get IPv4 address of node "${tg_node}" interface "${src_if}" from "${nodes_ipv4_addr}"
 115 | | ${dst_ip}= | Get IPv4 address of node "${vpp_node}" interface "${dst_if}" from "${nodes_ipv4_addr}"
 116 | | ${src_mac}= | Get node link mac | ${tg_node} | ${link_name}
 117 | | ${dst_mac}= | Get node link mac | ${vpp_node} | ${link_name}
 118 | | ${src_if_name}= | Get interface name | ${tg_node} | ${src_if}
 119 | | ${args}= | Traffic Script Gen Arg | ${src_if_name} | ${src_if_name}
 120 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
 121 | | Run Traffic Script On Node | arp_request.py | ${tg_node} | ${args}
 122
 123 | Configure IP addresses on interfaces
 124 | | [Documentation] | Iterates through @{args} list and Set Interface Address
 125 | | ... | for every (${dut_node}, ${interface}, ${address},
 126 | | ... | ${prefix}) tuple.
 127 | | ...
 128 | | ... | *Arguments:*
 129 | | ... | - dut_node - Node where IP address should be set to.
 130 | | ... | Type: dictionary
 131 | | ... | - interface - Interface name. Type: string
 132 | | ... | - address - IP address. Type: string
 133 | | ... | - prefix - Prefix length. Type: integer
 134 | | ...
 135 | | ... | *Example:*
 136 | | ...
 137 | | ... | \| Configure IP addresses on interfaces \
 138 | | ... | \| ${dut1_node} \| ${dut1_to_dut2} \| 192.168.1.1 \| 24 \|
 139 | | ... | \| ... \| ${dut1_node} \| ${dut1_to_tg} \| 192.168.2.1 \| 24 \|
 140 | | ...
 141 | | [Arguments] | @{args}
 142 | | :FOR | ${dut_node} | ${interface} | ${address} | ${prefix} | IN | @{args}
 143 | | | Set Interface Address | ${dut_node} | ${interface} | ${address}
 144 | | | ... | ${prefix}
 145
 146 | Send ICMP echo request and verify answer
 147 | | [Documentation] | Run traffic script that waits for ICMP reply and ignores
 148 | | ... | all other packets.
 149 | | ...
 150 | | ... | *Arguments:*
 151 | | ... | - tg_node - TG node where run traffic script. Type: dictionary
 152 | | ... | - tg_interface - TG interface where send ICMP echo request.
 153 | | ... | Type: string
 154 | | ... | - dst_mac - Destination MAC address. Type: string
 155 | | ... | - src_mac - Source MAC address. Type: string
 156 | | ... | - dst_ip - Destination IP address. Type: string
 157 | | ... | - src_ip - Source IP address. Type: string
 158 | | ... | - timeout - Wait timeout in seconds (Default: 10). Type: integer
 159 | | ...
 160 | | ... | *Example:*
 161 | | ...
 162 | | ... | \| Send ICMP echo request and verify answer \
 163 | | ... | \| ${nodes['TG']} \| eth2 \
 164 | | ... | \| 08:00:27:46:2b:4c \| 08:00:27:66:b8:57 \
 165 | | ... | \| 192.168.23.10 \| 192.168.23.1 \| 10 \|
 166 | | ...
 167 | | [Arguments] | ${tg_node} | ${tg_interface}
 168 | | ... | ${dst_mac} | ${src_mac} | ${dst_ip} | ${src_ip} | ${timeout}=${10}
 169 | | ...
 170 | | ${tg_interface_name}= | Get interface name | ${tg_node} | ${tg_interface}
 171 | | ${args}= | Catenate | --rx_if ${tg_interface_name}
 172 | | ... | --tx_if ${tg_interface_name} | --dst_mac ${dst_mac}
 173 | | ... | --src_mac ${src_mac} | --dst_ip ${dst_ip} | --src_ip ${src_ip}
 174 | | ... | --timeout ${timeout}
 175 | | Run Traffic Script On Node | send_icmp_wait_for_reply.py
 176 | | ... | ${tg_node} | ${args}
 177
 178 | Initialize IPv4 forwarding in circular topology
 179 | | [Documentation]
 180 | | ... | Set UP state on VPP interfaces in path on nodes in 2-node / 3-node
 181 | | ... | circular topology. Get the interface MAC addresses and setup ARP on
 182 | | ... | all VPP interfaces. Setup IPv4 addresses with /24 prefix on DUT-TG
 183 | | ... | links. In case of 3-node topology setup IPv4 adresses with /30 prefix
 184 | | ... | on DUT1-DUT2 link and set routing on both DUT nodes with prefix /24
 185 | | ... | and next hop of neighbour DUT interface IPv4 address. Configure route
 186 | | ... | entries for remote hosts IPv4 addresses if required.
 187 | | ...
 188 | | ... | *Arguments:*
 189 | | ... | - tg_if1_ip4 - IP address of TG interface1. Type: string
 190 | | ... | - tg_if2_ip4 - IP address of TG interface2. Type: string
 191 | | ... | - dut1_if1_ip4 - IP address of DUT1 interface1. Type: string
 192 | | ... | - dut1_if2_ip4 - IP address of DUT1 interface1. Type: string
 193 | | ... | - dut2_if1_ip4 - IP address of DUT2 interface1 (Optional).
 194 | | ... | Type: string
 195 | | ... | - dut2_if2_ip4 - IP address of DUT2 interface2 (Optional).
 196 | | ... | Type: string
 197 | | ... | - remote_host1_ip4 - IP address of remote host1 (Optional).
 198 | | ... | Type: string
 199 | | ... | - remote_host2_ip4 - IP address of remote host2 (Optional).
 200 | | ... | Type: string
 201 | | ... | - remote_host_ip4_prefix - IP address prefix for host IP addresses
 202 | | ... | (Optional). Type: string or integer
 203 | | ...
 204 | | ... | *Example:*
 205 | | ...
 206 | | ... | \| Initialize IPv4 forwarding in circular topology \
 207 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \|
 208 | | ... | \| Initialize IPv4 forwarding in circular topology \
 209 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \
 210 | | ... | \| remote_host1_ip4=192.168.0.1 \| remote_host2_ip4=192.168.0.2 \
 211 | | ... | \| remote_host_ip4_prefix=32 \|
 212 | | ... | \| Initialize IPv4 forwarding in circular topology \
 213 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
 214 | | ... | \| 20.20.20.1 \|
 215 | | ... | \| Initialize IPv4 forwarding in circular topology \
 216 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
 217 | | ... | \| 20.20.20.1 \| remote_host1_ip4=192.168.0.1 \
 218 | | ... | \| remote_host2_ip4=192.168.0.2 \| remote_host_ip4_prefix=32 \|
 219 | | ...
 220 | | [Arguments] | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4}
 221 | | ... | ${dut1_if2_ip4} | ${dut2_if1_ip4}=${NONE} | ${dut2_if2_ip4}=${NONE}
 222 | | ... | ${remote_host1_ip4}=${NONE} | ${remote_host2_ip4}=${NONE}
 223 | | ... | ${remote_host_ip4_prefix}=${NONE}
 224 | | ...
 225 | | Set interfaces in path up
 226 | | ...
 227 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 228 | | ... | Variable Should Exist | ${dut2_node}
 229 | | ...
 230 | | Run Keyword If | '${dut2_status}' == 'PASS'
 231 | | ... | Initialize IPv4 forwarding in 3-node circular topology
 232 | | ... | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4} | ${dut1_if2_ip4}
 233 | | ... | ${dut2_if1_ip4} | ${dut2_if2_ip4} | ${remote_host1_ip4}
 234 | | ... | ${remote_host2_ip4} | ${remote_host_ip4_prefix}
 235 | | ... | ELSE
 236 | | ... | Initialize IPv4 forwarding in 2-node circular topology
 237 | | ... | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4} | ${dut1_if2_ip4}
 238 | | ... | remote_host1_ip4=${remote_host1_ip4}
 239 | | ... | remote_host2_ip4=${remote_host2_ip4}
 240 | | ... | remote_host_ip4_prefix=${remote_host_ip4_prefix}
 241
 242 | Initialize IPv4 forwarding in 2-node circular topology
 243 | | [Documentation]
 244 | | ... | Set UP state on VPP interfaces on DUT node in 2-node circular
 245 | | ... | topology. Get the interface MAC addresses and setup ARP on
 246 | | ... | all VPP interfaces. Setup IPv4 addresses with /24 prefix on DUT-TG
 247 | | ... | links. Configure route entries for remote hosts IPv4 addresses
 248 | | ... | if required.
 249 | | ...
 250 | | ... | *Arguments:*
 251 | | ... | - tg_if1_ip4 - IP address of TG interface1. Type: string
 252 | | ... | - tg_if2_ip4 - IP address of TG interface2. Type: string
 253 | | ... | - dut1_if1_ip4 - IP address of DUT1 interface1. Type: string
 254 | | ... | - dut1_if2_ip4 - IP address of DUT1 interface1. Type: string
 255 | | ... | - remote_host1_ip4 - IP address of remote host1 (Optional).
 256 | | ... | Type: string
 257 | | ... | - remote_host2_ip4 - IP address of remote host2 (Optional).
 258 | | ... | Type: string
 259 | | ... | - remote_host_ip4_prefix - IP address prefix for host IP addresses
 260 | | ... | (Optional). Type: string or integer
 261 | | ...
 262 | | ... | *Example:*
 263 | | ...
 264 | | ... | \| Initialize IPv4 forwarding in circular topology \
 265 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \|
 266 | | ... | \| Initialize IPv4 forwarding in circular topology \
 267 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 20.20.20.1 \
 268 | | ... | \| 192.168.0.1 \| 192.168.0.2 \| 32 \|
 269 | | ...
 270 | | [Arguments] | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4}
 271 | | ... | ${dut1_if2_ip4} | ${remote_host1_ip4}=${NONE}
 272 | | ... | ${remote_host2_ip4}=${NONE} | ${remote_host_ip4_prefix}=${NONE}
 273 | | ...
 274 | | ${dut_tg_ip4_prefix}= | Set Variable | 24
 275 | | ...
 276 | | Add arp on dut | ${dut_node} | ${dut_to_tg_if1} | ${tg_if1_ip4}
 277 | | ... | ${tg_to_dut_if1_mac}
 278 | | Add arp on dut | ${dut_node} | ${dut_to_tg_if2} | ${tg_if2_ip4}
 279 | | ... | ${tg_to_dut_if2_mac}
 280 | | ...
 281 | | Configure IP addresses on interfaces | ${dut_node} | ${dut_to_tg_if1}
 282 | | ... | ${dut1_if1_ip4} | ${dut_tg_ip4_prefix}
 283 | | Configure IP addresses on interfaces | ${dut_node} | ${dut_to_tg_if2}
 284 | | ... | ${dut1_if2_ip4} | ${dut_tg_ip4_prefix}
 285 | | ...
 286 | | Run Keyword Unless | '${remote_host1_ip4}' == '${NONE}'
 287 | | ... | Vpp Route Add | ${dut_node} | ${remote_host1_ip4}
 288 | | ... | ${remote_host_ip4_prefix} | ${tg_if1_ip4} | ${dut_to_tg_if1}
 289 | | Run Keyword Unless | '${remote_host2_ip4}' == '${NONE}'
 290 | | ... | Vpp Route Add | ${dut_node} | ${remote_host2_ip4}
 291 | | ... | ${remote_host_ip4_prefix} | ${tg_if2_ip4} | ${dut_to_tg_if2}
 292
 293 | Initialize IPv4 forwarding in 3-node circular topology
 294 | | [Documentation]
 295 | | ... | Set UP state on VPP interfaces in path on nodes in 3-node circular
 296 | | ... | topology. Get the interface MAC addresses and setup ARP on all VPP
 297 | | ... | interfaces. Setup IPv4 addresses with /24 prefix on DUT-TG links.
 298 | | ... | Configure IPv4 adresses with /30 prefix on DUT1-DUT2 link and set
 299 | | ... | routing on both DUT nodes with prefix /24 and next hop of neighbour
 300 | | ... | DUT interface IPv4 address. Configure route entries for remote hosts
 301 | | ... | IPv4 addresses if required.
 302 | | ...
 303 | | ... | *Arguments:*
 304 | | ... | - tg_if1_ip4 - IP address of TG interface1. Type: string
 305 | | ... | - tg_if2_ip4 - IP address of TG interface2. Type: string
 306 | | ... | - dut1_if1_ip4 - IP address of DUT1 interface1. Type: string
 307 | | ... | - dut1_if2_ip4 - IP address of DUT1 interface1. Type: string
 308 | | ... | - dut2_if1_ip4 - IP address of DUT2 interface1. Type: string
 309 | | ... | - dut2_if2_ip4 - IP address of DUT2 interface2. Type: string
 310 | | ... | - remote_host1_ip4 - IP address of remote host1 (Optional).
 311 | | ... | Type: string
 312 | | ... | - remote_host2_ip4 - IP address of remote host2 (Optional).
 313 | | ... | Type: string
 314 | | ... | - remote_host_ip4_prefix - IP address prefix for host IP addresses
 315 | | ... | (Optional). Type: string or integer
 316 | | ...
 317 | | ... | *Example:*
 318 | | ...
 319 | | ... | \| Initialize IPv4 forwarding in circular topology \
 320 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
 321 | | ... | \| 20.20.20.1 \|
 322 | | ... | \| Initialize IPv4 forwarding in circular topology \
 323 | | ... | \| 10.10.10.2 \| 20.20.20.2 \| 10.10.10.1 \| 1.1.1.1 \| 1.1.1.2 \
 324 | | ... | \| 20.20.20.1 \| 192.168.0.1 \| 192.168.0.2 \| 32 \|
 325 | | ...
 326 | | [Arguments] | ${tg_if1_ip4} | ${tg_if2_ip4} | ${dut1_if1_ip4}
 327 | | ... | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut2_if2_ip4}
 328 | | ... | ${remote_host1_ip4}=${NONE} | ${remote_host2_ip4}=${NONE}
 329 | | ... | ${remote_host_ip4_prefix}=${NONE}
 330 | | ...
 331 | | ${dut_tg_ip4_prefix}= | Set Variable | 24
 332 | | ${dut_link_ip4_prefix}= | Set Variable | 30
 333 | | ...
 334 | | Add arp on dut | ${dut1_node} | ${dut1_to_tg} | ${tg_if1_ip4}
 335 | | ... | ${tg_to_dut1_mac}
 336 | | Add arp on dut | ${dut1_node} | ${dut1_to_dut2} | ${dut2_if1_ip4}
 337 | | ... | ${dut2_to_dut1_mac}
 338 | | Add arp on dut | ${dut2_node} | ${dut2_to_dut1} | ${dut1_if2_ip4}
 339 | | ... | ${dut1_to_dut2_mac}
 340 | | Add arp on dut | ${dut2_node} | ${dut2_to_tg} | ${tg_if2_ip4}
 341 | | ... | ${tg_to_dut2_mac}
 342 | | ...
 343 | | Configure IP addresses on interfaces | ${dut1_node} | ${dut1_to_tg}
 344 | | ... | ${dut1_if1_ip4} | ${dut_tg_ip4_prefix}
 345 | | Configure IP addresses on interfaces | ${dut1_node} | ${dut1_to_dut2}
 346 | | ... | ${dut1_if2_ip4} | ${dut_link_ip4_prefix}
 347 | | Configure IP addresses on interfaces | ${dut2_node} | ${dut2_to_dut1}
 348 | | ... | ${dut2_if1_ip4} | ${dut_link_ip4_prefix}
 349 | | Configure IP addresses on interfaces | ${dut2_node} | ${dut2_to_tg}
 350 | | ... | ${dut2_if2_ip4} | ${dut_tg_ip4_prefix}
 351 | | ...
 352 | | Vpp Route Add | ${dut1_node} | ${tg_if2_ip4} | ${dut_tg_ip4_prefix}
 353 | | ... | ${dut2_if1_ip4} | ${dut1_to_dut2}
 354 | | Vpp Route Add | ${dut2_node} | ${tg_if1_ip4} | ${dut_tg_ip4_prefix}
 355 | | ... | ${dut1_if2_ip4} | ${dut2_to_dut1}
 356 | | ...
 357 | | Run Keyword Unless | '${remote_host1_ip4}' == '${NONE}'
 358 | | ... | Vpp Route Add | ${dut1_node} | ${remote_host1_ip4}
 359 | | ... | ${remote_host_ip4_prefix} | ${tg_if1_ip4} | ${dut1_to_tg}
 360 | | Run Keyword Unless | '${remote_host2_ip4}' == '${NONE}'
 361 | | ... | Vpp Route Add | ${dut1_node} | ${remote_host2_ip4}
 362 | | ... | ${remote_host_ip4_prefix} | ${dut2_if1_ip4} | ${dut1_to_dut2}
 363 | | Run Keyword Unless | '${remote_host1_ip4}' == '${NONE}'
 364 | | ... | Vpp Route Add | ${dut2_node} | ${remote_host1_ip4}
 365 | | ... | ${remote_host_ip4_prefix} | ${dut1_if2_ip4} | ${dut2_to_dut1}
 366 | | Run Keyword Unless | '${remote_host2_ip4}' == '${NONE}'
 367 | | ... | Vpp Route Add | ${dut2_node} | ${remote_host2_ip4}
 368 | | ... | ${remote_host_ip4_prefix} | ${tg_if2_ip4} | ${dut2_to_tg}