resources/libraries/robot/ip/ip6.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.InterfaceUtil
  16 | Library | resources.libraries.python.IPv6Util
  17 | Library | resources.libraries.python.IPv6Setup
  18 | Library | resources.libraries.python.NodePath
  19 | Library | resources.libraries.python.Routing
  20 | Library | resources.libraries.python.topology.Topology
  21 | Library | resources.libraries.python.TrafficScriptExecutor
  22 | Resource | resources/libraries/robot/shared/counters.robot
  23 | Resource | resources/libraries/robot/shared/default.robot
  24 | Resource | resources/libraries/robot/shared/testing_path.robot
  25 | ...
  26 | Documentation | IPv6 keywords
  27
  28 *** Keywords ***
  29 | Send IPv6 icmp echo request to DUT1 ingress inteface and verify answer
  30 | | [Documentation] | Type of the src_node must be TG and dst_node must be DUT
  31 | | [Arguments] | ${tg_node} | ${dut_node} | ${nodes_addr}
  32 | | Append Nodes | ${tg_node} | ${dut_node}
  33 | | Compute Path
  34 | | ${src_port} | ${src_node}= | First Interface
  35 | | ${dst_port} | ${dst_node}= | Last Interface
  36 | | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port}
  37 | | ... | ${nodes_addr}
  38 | | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port}
  39 | | ... | ${nodes_addr}
  40 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
  41 | | ${dst_mac}= | Get Interface Mac | ${dst_node} | ${dst_port}
  42 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
  43 | | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
  44 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
  45 | | Run Traffic Script On Node | icmpv6_echo.py | ${tg_node} | ${args}
  46
  47 | Execute IPv6 ICMP echo sweep
  48 | | [Documentation] | Type of the src_node must be TG and dst_node must be DUT
  49 | | [Arguments] | ${src_node} | ${dst_node} | ${start_size} | ${end_size}
  50 | | ... | ${step} | ${nodes_addr}
  51 | | Append Nodes | ${src_node} | ${dst_node}
  52 | | Compute Path
  53 | | ${src_port} | ${src_node}= | First Interface
  54 | | ${dst_port} | ${dst_node}= | Last Interface
  55 | | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port}
  56 | | ... | ${nodes_addr}
  57 | | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port}
  58 | | ... | ${nodes_addr}
  59 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
  60 | | ${dst_mac}= | Get Interface Mac | ${dst_node} | ${dst_port}
  61 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
  62 | | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
  63 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
  64 | | ${args}= | Catenate | ${args} | --start_size ${start_size}
  65 | | ... | --end_size ${end_size} | --step ${step}
  66 | | Run Traffic Script On Node | ipv6_sweep_ping.py | ${src_node} | ${args}
  67 | | ... | timeout=${180}
  68
  69 | Send IPv6 ICMP echo request to DUT1 egress interface and verify answer
  70 | | [Documentation] | Send traffic from TG to first DUT egress interface
  71 | | [Arguments] | ${tg_node} | ${first_dut} | ${second_dut} | ${nodes_addr}
  72 | | Append Nodes | ${tg_node} | ${first_dut} | ${second_dut}
  73 | | Compute Path
  74 | | ${src_port} | ${src_node}= | First Interface
  75 | | ${dst_port} | ${dst_node}= | Last Egress Interface
  76 | | ${hop_port} | ${hop_node}= | First Ingress Interface
  77 | | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port}
  78 | | ... | ${nodes_addr}
  79 | | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port}
  80 | | ... | ${nodes_addr}
  81 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
  82 | | ${dst_mac}= | Get Interface Mac | ${hop_node} | ${hop_port}
  83 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
  84 | | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
  85 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
  86 | | Run Traffic Script On Node | icmpv6_echo.py | ${tg_node} | ${args}
  87
  88
  89 | Send IPv6 ICMP echo request to DUT2 via DUT1 and verify answer
  90 | | [Documentation] | Send traffic from TG to second DUT through first DUT
  91 | | [Arguments] | ${tg_node} | ${first_dut} | ${second_dut} | ${nodes_addr}
  92 | | Append Nodes | ${tg_node} | ${first_dut} | ${second_dut}
  93 | | Compute Path
  94 | | ${src_port} | ${src_node}= | First Interface
  95 | | ${dst_port} | ${dst_node}= | Last Interface
  96 | | ${hop_port} | ${hop_node}= | First Ingress Interface
  97 | | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port}
  98 | | ... | ${nodes_addr}
  99 | | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port}
 100 | | ... | ${nodes_addr}
 101 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
 102 | | ${dst_mac}= | Get Interface Mac | ${hop_node} | ${hop_port}
 103 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
 104 | | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
 105 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
 106 | | Run Traffic Script On Node | icmpv6_echo.py | ${tg_node} | ${args}
 107
 108 | Send IPv6 ICMP echo request to DUT2 egress interface via DUT1 and verify answer
 109 | | [Documentation] | Send traffic from TG to second DUT egress interface
 110 | | ... | through first DUT
 111 | | [Arguments] | ${tg_node} | ${first_dut} | ${second_dut} | ${nodes_addr}
 112 | | Append Nodes | ${tg_node} | ${first_dut} | ${second_dut} | ${tg_node}
 113 | | Compute Path
 114 | | ${src_port} | ${src_node}= | First Interface
 115 | | ${dst_port} | ${dst_node}= | Last Egress Interface
 116 | | ${hop_port} | ${hop_node}= | First Ingress Interface
 117 | | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port}
 118 | | ... | ${nodes_addr}
 119 | | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port}
 120 | | ... | ${nodes_addr}
 121 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
 122 | | ${dst_mac}= | Get Interface Mac | ${hop_node} | ${hop_port}
 123 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
 124 | | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
 125 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
 126 | | Run Traffic Script On Node | icmpv6_echo.py | ${tg_node} | ${args}
 127
 128 | Ipv6 tg to tg routed
 129 | | [Documentation] | Send traffic from one TG port to another through DUT nodes
 130 | | ... | and send reply back, also verify hop limit processing
 131 | | [Arguments] | ${tg_node} | ${first_dut} | ${second_dut} | ${nodes_addr}
 132 | | Append Nodes | ${tg_node} | ${first_dut} | ${second_dut} | ${tg_node}
 133 | | Compute Path
 134 | | ${src_port} | ${src_node}= | First Interface
 135 | | ${dst_port} | ${dst_node}= | Last Interface
 136 | | ${src_nh_port} | ${src_nh_node}= | First Ingress Interface
 137 | | ${dst_nh_port} | ${dst_nh_node}= | Last Egress Interface
 138 | | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port}
 139 | | ... | ${nodes_addr}
 140 | | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port}
 141 | | ... | ${nodes_addr}
 142 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
 143 | | ${dst_mac}= | Get Interface Mac | ${src_node} | ${dst_port}
 144 | | ${src_nh_mac}= | Get Interface Mac | ${src_nh_node} | ${src_nh_port}
 145 | | ${dst_nh_mac}= | Get Interface Mac | ${dst_nh_node} | ${dst_nh_port}
 146 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
 147 | | ${dst_port_name}= | Get interface name | ${dst_node} | ${dst_port}
 148 | | ${args}= | Traffic Script Gen Arg | ${dst_port_name} | ${src_port_name}
 149 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
 150 | | ${args}= | Catenate | ${args} | --src_nh_mac ${src_nh_mac}
 151 | | ... | --dst_nh_mac ${dst_nh_mac} | --h_num 2
 152 | | Run Traffic Script On Node | icmpv6_echo_req_resp.py | ${tg_node} | ${args}
 153
 154 | Send IPv6 neighbor solicitation and verify answer
 155 | | [Documentation] | Send IPv6 neighbor solicitation from TG to DUT
 156 | | [Arguments] | ${tg_node} | ${dut_node} | ${nodes_addr}
 157 | | Append Nodes | ${tg_node} | ${dut_node}
 158 | | Compute Path
 159 | | ${src_port} | ${src_node}= | First Interface
 160 | | ${dst_port} | ${dst_node}= | Last Interface
 161 | | ${src_ip}= | Get Node Port Ipv6 Address | ${src_node} | ${src_port}
 162 | | ... | ${nodes_addr}
 163 | | ${dst_ip}= | Get Node Port Ipv6 Address | ${dst_node} | ${dst_port}
 164 | | ... | ${nodes_addr}
 165 | | ${src_mac}= | Get Interface Mac | ${src_node} | ${src_port}
 166 | | ${dst_mac}= | Get Interface Mac | ${dst_node} | ${dst_port}
 167 | | ${src_port_name}= | Get interface name | ${src_node} | ${src_port}
 168 | | ${args}= | Traffic Script Gen Arg | ${src_port_name} | ${src_port_name}
 169 | | ... | ${src_mac} | ${dst_mac} | ${src_ip} | ${dst_ip}
 170 | | Run Traffic Script On Node | ipv6_ns.py | ${src_node} | ${args}
 171
 172 | Configure IPv6 on all DUTs in topology
 173 | | [Documentation] | Setup IPv6 address on all DUTs
 174 | | [Arguments] | ${nodes} | ${nodes_addr}
 175 | | Restart Vpp Service On All Duts | ${nodes}
 176 | | Verify Vpp On All Duts | ${nodes}
 177 | | VPP Enable Traces On All Duts | ${nodes}
 178 | | ${interfaces}= | Nodes Set Ipv6 Addresses | ${nodes} | ${nodes_addr}
 179 | | :FOR | ${interface} | IN | @{interfaces}
 180 | | | Set Interface State | @{interface} | up | if_type=name
 181 | | All Vpp Interfaces Ready Wait | ${nodes}
 182
 183 | Suppress ICMPv6 router advertisement message
 184 | | [Documentation] | Suppress ICMPv6 router advertisement message for link
 185 | | ... | scope address
 186 | | [Arguments] | ${nodes}
 187 | | Vpp All Ra Suppress Link Layer | ${nodes}
 188
 189 | Configure IPv6 routing on all DUTs
 190 | | [Documentation] | Setup routing on all VPP nodes required for IPv6 tests
 191 | | [Arguments] | ${nodes} | ${nodes_addr}
 192 | | Append Nodes | ${nodes['DUT1']} | ${nodes['DUT2']}
 193 | | Compute Path
 194 | | ${tg}= | Set Variable | ${nodes['TG']}
 195 | | ${dut1_if} | ${dut1}= | First Interface
 196 | | ${dut2_if} | ${dut2}= | Last Interface
 197 | | ${dut1_if_addr}= | Get Node Port Ipv6 Address | ${dut1} | ${dut1_if}
 198 | | ... | ${nodes_addr}
 199 | | ${dut2_if_addr}= | Get Node Port Ipv6 Address | ${dut2} | ${dut2_if}
 200 | | ... | ${nodes_addr}
 201 | | @{tg_dut1_links}= | Get active links connecting "${tg}" and "${dut1}"
 202 | | @{tg_dut2_links}= | Get active links connecting "${tg}" and "${dut2}"
 203 | | :FOR | ${link} | IN | @{tg_dut1_links}
 204 | | | ${net}= | Get Link Address | ${link} | ${nodes_addr}
 205 | | | ${prefix}= | Get Link Prefix | ${link} | ${nodes_addr}
 206 | | | Vpp Route Add | ${dut2} | ${net} | ${prefix} | gateway=${dut1_if_addr}
 207 | | | ... | interface=${dut2_if}
 208 | | :FOR | ${link} | IN | @{tg_dut2_links}
 209 | | | ${net}= | Get Link Address | ${link} | ${nodes_addr}
 210 | | | ${prefix}= | Get Link Prefix | ${link} | ${nodes_addr}
 211 | | | Vpp Route Add | ${dut1} | ${net} | ${prefix} | gateway=${dut2_if_addr}
 212 | | | ... | interface=${dut1_if}
 213
 214 | Configure IPv6 forwarding in circular topology
 215 | | [Documentation]
 216 | | ... | Set UP state on VPP interfaces in path on nodes in 2-node / 3-node
 217 | | ... | circular topology. Get the interface MAC addresses and setup ARP on
 218 | | ... | all VPP interfaces. Setup IPv6 addresses with /64 prefix on DUT-TG
 219 | | ... | links. In case of 3-node topology setup IPv6 adresses with /96 prefix
 220 | | ... | on DUT1-DUT2 link and set routing on both DUT nodes with prefix /64
 221 | | ... | and next hop of neighbour DUT interface IPv6 address. Configure route
 222 | | ... | entries for remote hosts IPv6 addresses if required.
 223 | | ...
 224 | | ... | *Arguments:*
 225 | | ... | - tg_if1_ip6 - IPv6 address of TG interface1. Type: string
 226 | | ... | - tg_if2_ip6 - IPv6 address of TG interface2. Type: string
 227 | | ... | - dut1_if1_ip6 - IPv6 address of DUT1 interface1. Type: string
 228 | | ... | - dut1_if2_ip6 - IPv6 address of DUT1 interface1. Type: string
 229 | | ... | - dut2_if1_ip6 - IPv6 address of DUT2 interface1 (Optional).
 230 | | ... | Type: string
 231 | | ... | - dut2_if2_ip6 - IPv6 address of DUT2 interface2 (Optional).
 232 | | ... | Type: string
 233 | | ... | - remote_host1_ip6 - IPv6 address of remote host1 (Optional).
 234 | | ... | Type: string
 235 | | ... | - remote_host2_ip6 - IPv6 address of remote host2 (Optional).
 236 | | ... | Type: string
 237 | | ... | - remote_host_ip6_prefix - IPv6 address prefix for host IPv6 addresses
 238 | | ... | (Optional). Type: string or integer
 239 | | ...
 240 | | ... | *Example:*
 241 | | ...
 242 | | ... | \| Configure IPv6 forwarding in circular topology \
 243 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2001:2::1 \|
 244 | | ... | \| Configure IPv6 forwarding in circular topology \
 245 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2001:2::1 \
 246 | | ... | \| remote_host1_ip6=3ffe:5f::1 \| remote_host2_ip6=3ffe:5f::2 \
 247 | | ... | \| remote_host_ip6_prefix=128 \|
 248 | | ... | \| Configure IPv6 forwarding in circular topology \
 249 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2003:3::1 \| 2003:3::2 \
 250 | | ... | \| 2001:2::1 \|
 251 | | ... | \| Configure IPv6 forwarding in circular topology \
 252 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2003:3::1 \| 2003:3::2 \
 253 | | ... | \| 2001:2::1 \| remote_host1_ip4=3ffe:5f::1 \
 254 | | ... | \| remote_host2_ip4=3ffe:5f::2 \| remote_host_ip4_prefix=128 \|
 255 | | ...
 256 | | [Arguments] | ${tg_if1_ip6} | ${tg_if2_ip6} | ${dut1_if1_ip6}
 257 | | ... | ${dut1_if2_ip6} | ${dut2_if1_ip6}=${NONE} | ${dut2_if2_ip6}=${NONE}
 258 | | ... | ${remote_host1_ip6}=${NONE} | ${remote_host2_ip6}=${NONE}
 259 | | ... | ${remote_host_ip6_prefix}=${NONE}
 260 | | ...
 261 | | ...
 262 | | Configure interfaces in path up
 263 | | ...
 264 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 265 | | ... | Variable Should Exist | ${dut2_node}
 266 | | ...
 267 | | Run Keyword If | '${dut2_status}' == 'PASS'
 268 | | ... | Configure IPv6 forwarding in 3-node circular topology
 269 | | ... | ${tg_if1_ip6} | ${tg_if2_ip6} | ${dut1_if1_ip6} | ${dut1_if2_ip6}
 270 | | ... | ${dut2_if1_ip6} | ${dut2_if2_ip6} | ${remote_host1_ip6}
 271 | | ... | ${remote_host2_ip6} | ${remote_host_ip6_prefix}
 272 | | ... | ELSE
 273 | | ... | Configure IPv6 forwarding in 2-node circular topology
 274 | | ... | ${tg_if1_ip6} | ${tg_if2_ip6} | ${dut1_if1_ip6} | ${dut1_if2_ip6}
 275 | | ... | remote_host1_ip6=${remote_host1_ip6}
 276 | | ... | remote_host2_ip6=${remote_host2_ip6}
 277 | | ... | remote_host_ip6_prefix=${remote_host_ip6_prefix}
 278
 279 | Configure IPv6 forwarding in 2-node circular topology
 280 | | [Documentation]
 281 | | ... | Set UP state on VPP interfaces on DUT node in 2-node circular
 282 | | ... | topology. Get the interface MAC addresses and setup ARP on
 283 | | ... | all VPP interfaces. Setup IPv6 addresses with /64 prefix on DUT-TG
 284 | | ... | links. Configure route entries for remote hosts IPv6 addresses
 285 | | ... | if required.
 286 | | ...
 287 | | ... | *Arguments:*
 288 | | ... | - tg_if1_ip6 - IPv6 address of TG interface1. Type: string
 289 | | ... | - tg_if2_ip6 - IPv6 address of TG interface2. Type: string
 290 | | ... | - dut1_if1_ip6 - IPv6 address of DUT1 interface1. Type: string
 291 | | ... | - dut1_if2_ip6 - IPv6 address of DUT1 interface1. Type: string
 292 | | ... | - remote_host1_ip6 - IPv6 address of remote host1 (Optional).
 293 | | ... | Type: string
 294 | | ... | - remote_host2_ip6 - IPv6 address of remote host2 (Optional).
 295 | | ... | Type: string
 296 | | ... | - remote_host_ip6_prefix - IPv6 address prefix for host IPv6 addresses
 297 | | ... | (Optional). Type: string or integer
 298 | | ...
 299 | | ... | *Example:*
 300 | | ...
 301 | | ... | \| Configure IPv6 forwarding in circular topology \
 302 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2001:2::1 \|
 303 | | ... | \| Configure IPv6 forwarding in circular topology \
 304 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2001:2::1 \
 305 | | ... | \| remote_host1_ip6=3ffe:5f::1 \| remote_host2_ip6=3ffe:5f::2 \
 306 | | ... | \| remote_host_ip6_prefix=128 \|
 307 | | ...
 308 | | [Arguments] | ${tg_if1_ip6} | ${tg_if2_ip6} | ${dut1_if1_ip6}
 309 | | ... | ${dut1_if2_ip6} | ${remote_host1_ip6}=${NONE}
 310 | | ... | ${remote_host2_ip6}=${NONE} | ${remote_host_ip6_prefix}=${NONE}
 311 | | ...
 312 | | ${dut_tg_ip6_prefix}= | Set Variable | 64
 313 | | ...
 314 | | Add IP neighbor | ${dut_node} | ${dut_to_tg_if1} | ${tg_if1_ip6}
 315 | | ... | ${tg_to_dut_if1_mac}
 316 | | Add IP neighbor | ${dut_node} | ${dut_to_tg_if2} | ${tg_if2_ip6}
 317 | | ... | ${tg_to_dut_if2_mac}
 318 | | ...
 319 | | VPP set If IPv6 addr | ${dut_node} | ${dut_to_tg_if1} | ${dut1_if1_ip6}
 320 | | ... | ${dut_tg_ip6_prefix}
 321 | | VPP set If IPv6 addr | ${dut_node} | ${dut_to_tg_if2} | ${dut1_if2_ip6}
 322 | | ... | ${dut_tg_ip6_prefix}
 323 | | ...
 324 | | Run Keyword Unless | '${remote_host1_ip6}' == '${NONE}'
 325 | | ... | Vpp Route Add | ${dut_node} | ${remote_host1_ip6}
 326 | | ... | ${remote_host_ip6_prefix} | gateway=${tg_if1_ip6}
 327 | | ... | interface=${dut_to_tg_if1}
 328 | | Run Keyword Unless | '${remote_host2_ip6}' == '${NONE}'
 329 | | ... | Vpp Route Add | ${dut_node} | ${remote_host2_ip6}
 330 | | ... | ${remote_host_ip6_prefix} | gateway=${tg_if2_ip6}
 331 | | ... | interface=${dut_to_tg_if2}
 332
 333 | Configure IPv6 forwarding in 3-node circular topology
 334 | | [Documentation]
 335 | | ... | Set UP state on VPP interfaces in path on nodes in 3-node circular
 336 | | ... | topology. Get the interface MAC addresses and setup ARP on all VPP
 337 | | ... | interfaces. Setup IPv6 addresses with /64 prefix on DUT-TG links.
 338 | | ... | Configure IPv6 adresses with /96 prefix on DUT1-DUT2 link and set
 339 | | ... | routing on both DUT nodes with prefix /64 and next hop of neighbour
 340 | | ... | DUT interface IPv6 address. Configure route entries for remote hosts
 341 | | ... | IPv6 addresses if required.
 342 | | ...
 343 | | ... | *Arguments:*
 344 | | ... | - tg_if1_ip6 - IPv6 address of TG interface1. Type: string
 345 | | ... | - tg_if2_ip6 - IPv6 address of TG interface2. Type: string
 346 | | ... | - dut1_if1_ip6 - IPv6 address of DUT1 interface1. Type: string
 347 | | ... | - dut1_if2_ip6 - IPv6 address of DUT1 interface1. Type: string
 348 | | ... | - dut2_if1_ip6 - IPv6 address of DUT2 interface1 Type: string
 349 | | ... | - dut2_if2_ip6 - IPv6 address of DUT2 interface2 Type: string
 350 | | ... | - remote_host1_ip6 - IPv6 address of remote host1 (Optional).
 351 | | ... | Type: string
 352 | | ... | - remote_host2_ip6 - IPv6 address of remote host2 (Optional).
 353 | | ... | Type: string
 354 | | ... | - remote_host_ip6_prefix - IPv6 address prefix for host IPv6 addresses
 355 | | ... | (Optional). Type: string or integer
 356 | | ...
 357 | | ... | *Example:*
 358 | | ...
 359 | | ... | \| Configure IPv6 forwarding in circular topology \
 360 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2003:3::1 \| 2003:3::2 \
 361 | | ... | \| 2001:2::1 \|
 362 | | ... | \| Configure IPv6 forwarding in circular topology \
 363 | | ... | \| 2001:1::2 \| 2001:2::2 \| 2001:1::1 \| 2003:3::1 \| 2003:3::2 \
 364 | | ... | \| 2001:2::1 \| remote_host1_ip4=3ffe:5f::1 \
 365 | | ... | \| remote_host2_ip4=3ffe:5f::2 \| remote_host_ip4_prefix=128 \|
 366 | | ...
 367 | | [Arguments] | ${tg_if1_ip6} | ${tg_if2_ip6} | ${dut1_if1_ip6}
 368 | | ... | ${dut1_if2_ip6} | ${dut2_if1_ip6} | ${dut2_if2_ip6}
 369 | | ... | ${remote_host1_ip6}=${NONE} | ${remote_host2_ip6}=${NONE}
 370 | | ... | ${remote_host_ip6_prefix}=${NONE}
 371 | | ...
 372 | | ${dut_tg_ip6_prefix}= | Set Variable | 64
 373 | | ${dut_link_ip6_prefix}= | Set Variable | 96
 374 | | ...
 375 | | Add IP neighbor | ${dut1_node} | ${dut1_to_tg} | ${tg_if1_ip6}
 376 | | ... | ${tg_to_dut1_mac}
 377 | | Add IP neighbor | ${dut1_node} | ${dut1_to_dut2} | ${dut2_if1_ip6}
 378 | | ... | ${dut2_to_dut1_mac}
 379 | | Add IP neighbor | ${dut2_node} | ${dut2_to_dut1} | ${dut1_if2_ip6}
 380 | | ... | ${dut1_to_dut2_mac}
 381 | | Add IP neighbor | ${dut2_node} | ${dut2_to_tg} | ${tg_if2_ip6}
 382 | | ... | ${tg_to_dut2_mac}
 383 | | ...
 384 | | VPP set If IPv6 addr | ${dut1_node} | ${dut1_to_tg} | ${dut1_if1_ip6}
 385 | | ... | ${dut_tg_ip6_prefix}
 386 | | VPP set If IPv6 addr | ${dut1_node} | ${dut1_to_dut2} | ${dut1_if2_ip6}
 387 | | ... | ${dut_link_ip6_prefix}
 388 | | VPP set If IPv6 addr | ${dut2_node} | ${dut2_to_dut1} | ${dut2_if1_ip6}
 389 | | ... | ${dut_link_ip6_prefix}
 390 | | VPP set If IPv6 addr | ${dut2_node} | ${dut2_to_tg} | ${dut2_if2_ip6}
 391 | | ... | ${dut_tg_ip6_prefix}
 392 | | ...
 393 | | Vpp Route Add | ${dut1_node} | ${tg_if2_ip6} | ${dut_tg_ip6_prefix}
 394 | | ... | gateway=${dut2_if1_ip6} | interface=${dut1_to_dut2}
 395 | | Vpp Route Add | ${dut2_node} | ${tg_if1_ip6} | ${dut_tg_ip6_prefix}
 396 | | ... | gateway=${dut1_if2_ip6} | interface=${dut2_to_dut1}
 397 | | ...
 398 | | Run Keyword Unless | '${remote_host1_ip6}' == '${NONE}'
 399 | | ... | Vpp Route Add | ${dut1_node} | ${remote_host1_ip6}
 400 | | ... | ${remote_host_ip6_prefix} | gateway=${tg_if1_ip6}
 401 | | ... | interface=${dut1_to_tg}
 402 | | Run Keyword Unless | '${remote_host2_ip6}' == '${NONE}'
 403 | | ... | Vpp Route Add | ${dut1_node} | ${remote_host2_ip6}
 404 | | ... | ${remote_host_ip6_prefix} | gateway=${dut2_if1_ip6}
 405 | | ... | interface=${dut1_to_dut2}
 406 | | Run Keyword Unless | '${remote_host1_ip6}' == '${NONE}'
 407 | | ... | Vpp Route Add | ${dut2_node} | ${remote_host1_ip6}
 408 | | ... | ${remote_host_ip6_prefix} | gateway=${dut1_if2_ip6}
 409 | | ... | interface=${dut2_to_dut1}
 410 | | Run Keyword Unless | '${remote_host2_ip6}' == '${NONE}'
 411 | | ... | Vpp Route Add | ${dut2_node} | ${remote_host2_ip6}
 412 | | ... | ${remote_host_ip6_prefix} | gateway=${tg_if2_ip6}
 413 | | ... | interface=${dut2_to_tg}