resources/libraries/robot/l2/l2_bridge_domain.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.L2Util
  16 | Library | resources.libraries.python.InterfaceUtil
  17 | Library | resources.libraries.python.NodePath
  18 | Library | resources.libraries.python.VhostUser
  19 | Library | resources.libraries.python.Memif
  20
  21 *** Keywords ***
  22 | Show Bridge Domain Data On All DUTs
  23 | | [Documentation] | Show Bridge Domain data on all DUTs.
  24 | |
  25 | | FOR | ${dut} | IN | @{duts}
  26 | | | VPP Get Bridge Domain Data | ${nodes['${dut}']}
  27 | | END
  28
  29 | Add interface to bridge domain
  30 | | [Documentation]
  31 | | ... | Set given interface admin state to up and add this
  32 | | ... | interface to required L2 bridge domain on defined VPP node.
  33 | |
  34 | | ... | *Arguments:*
  35 | | ... | - ${dut} - DUT node. Type: dictionary
  36 | | ... | - ${dut_if} - DUT node interface name. Type: string
  37 | | ... | - ${bd_id} - Bridge domain ID. Type: integer
  38 | | ... | - ${shg} - Split-horizon group ID. Type: integer, default value: 0
  39 | |
  40 | | ... | *Example:*
  41 | |
  42 | | ... | \| Add interface to bridge domain \| ${nodes['DUT2']} \
  43 | | ... | \| GigabitEthernet0/8/0 \| 3 \|
  44 | |
  45 | | [Arguments] | ${dut} | ${dut_if} | ${bd_id} | ${shg}=0
  46 | |
  47 | | Set Interface State | ${dut} | ${dut_if} | up
  48 | | Add Interface To L2 BD | ${dut} | ${dut_if} | ${bd_id} | ${shg}
  49
  50 | Initialize L2 bridge domain on node
  51 | | [Documentation]
  52 | | ... | Setup L2 bridge domain topology by adding two interfaces on DUT into
  53 | | ... | separate bridge domains that are created automatically starting with
  54 | | ... | index 1. Learning is enabled. Interfaces are brought up.
  55 | |
  56 | | ... | *Arguments:*
  57 | | ... | - dut - DUT node. Type: string
  58 | | ... | - count - Number of bridge domains interfaces. Type: integer
  59 | |
  60 | | ... | *Example:*
  61 | |
  62 | | ... | \| Initialize L2 bridge domain on node \| DUT1 \| 1 \|
  63 | |
  64 | | [Arguments] | ${dut} | ${count}=${1}
  65 | |
  66 | | FOR | ${id} | IN RANGE | 1 | ${count} + 1
  67 | | | Add Interface To L2 BD
  68 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${id}}[0] | ${id}
  69 | | | Add Interface To L2 BD
  70 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${id}}[0] | ${id}
  71 | | END
  72
  73 | Initialize L2 bridge domain
  74 | | [Documentation]
  75 | | ... | Setup L2 bridge domain topology by adding two interfaces on each DUT
  76 | | ... | into separate bridge domains that are created automatically starting
  77 | | ... | with index 1. Learning is enabled. Interfaces are brought up.
  78 | |
  79 | | ... | *Arguments:*
  80 | | ... | - count - Number of bridge domains. Type: integer
  81 | |
  82 | | ... | *Example:*
  83 | |
  84 | | ... | \| Initialize L2 bridge domain \| 1 \|
  85 | |
  86 | | [Arguments] | ${count}=${1}
  87 | |
  88 | | FOR | ${dut} | IN | @{duts}
  89 | | | Initialize L2 bridge domain on node | ${dut} | count=${count}
  90 | | END
  91
  92 | Initialize L2 bridge domains with Vhost-User on node
  93 | | [Documentation]
  94 | | ... | Create pairs of Vhost-User interfaces for defined number of VMs on
  95 | | ... | defined VPP node. Add each Vhost-User interface into L2 bridge
  96 | | ... | domains with learning enabled with physical inteface or Vhost-User
  97 | | ... | interface of another VM.
  98 | |
  99 | | ... | *Arguments:*
 100 | | ... | - dut - DUT node. Type: string
 101 | | ... | - nf_chain - NF chain. Type: integer
 102 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 103 | | ... | - virtio_feature_mask - Enabled Virtio features (Optional).
 104 | | ... | Type: integer
 105 | |
 106 | | ... | *Note:*
 107 | | ... | Socket paths for VM are defined in following format:
 108 | | ... | - /var/run/vpp/sock-\${VM_ID}-1
 109 | | ... | - /var/run/vpp/sock-\${VM_ID}-2
 110 | |
 111 | | ... | *Example:*
 112 | |
 113 | | ... | \| Initialize L2 bridge domains with Vhost-User on node \| DUT1 \
 114 | | ... | \| 1 \| 1 \|
 115 | |
 116 | | [Arguments] | ${dut} | ${nf_chain}=${1} | ${nf_nodes}=${1}
 117 | | ... | ${virtio_feature_mask}=${None}
 118 | |
 119 | | ${bd_id1}= | Evaluate | ${nf_nodes} * (${nf_chain} - 1) + ${nf_chain}
 120 | | ${bd_id2}= | Evaluate | ${nf_nodes} * ${nf_chain} + ${nf_chain}
 121 | | Add interface to bridge domain
 122 | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${nf_chain}}[0]
 123 | | ... | ${bd_id1}
 124 | | Add interface to bridge domain
 125 | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${nf_chain}}[0]
 126 | | ... | ${bd_id2}
 127 | | FOR | ${nf_node} | IN RANGE | 1 | ${nf_nodes} + 1
 128 | | | ${qemu_id}= | Evaluate | (${nf_chain} - ${1}) * ${nf_nodes} + ${nf_node}
 129 | | | Configure vhost interfaces
 130 | | | ... | ${nodes['${dut}']}
 131 | | | ... | /var/run/vpp/sock-${qemu_id}-1 | /var/run/vpp/sock-${qemu_id}-2
 132 | | | ... | ${dut}-vhost-${qemu_id}-if1 | ${dut}-vhost-${qemu_id}-if2
 133 | | | ... | virtio_feature_mask=${virtio_feature_mask}
 134 | | | ${bd_id1}= | Evaluate | ${qemu_id} + (${nf_chain} - 1)
 135 | | | ${bd_id2}= | Evaluate | ${bd_id1} + 1
 136 | | | Add interface to bridge domain
 137 | | | ... | ${nodes['${dut}']} | ${${dut}-vhost-${qemu_id}-if1} | ${bd_id1}
 138 | | | Add interface to bridge domain
 139 | | | ... | ${nodes['${dut}']} | ${${dut}-vhost-${qemu_id}-if2} | ${bd_id2}
 140 | | END
 141
 142 | Initialize L2 bridge domains with Vhost-User
 143 | | [Documentation]
 144 | | ... | Create pairs of Vhost-User interfaces for defined number of VNF nodes
 145 | | ... | on all defined VPP nodes. Add each Vhost-User interface into L2 bridge
 146 | | ... | domains with learning enabled with physical inteface or Vhost-User
 147 | | ... | interface of another VM.
 148 | |
 149 | | ... | *Arguments:*
 150 | | ... | - nf_chain - NF chain. Type: integer
 151 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 152 | | ... | - virtio_feature_mask - Enabled Virtio features (Optional).
 153 | | ... | Type: integer
 154 | |
 155 | | ... | *Example:*
 156 | |
 157 | | ... | \| Initialize L2 bridge domains with Vhost-User \| 1 \| 1 \|
 158 | |
 159 | | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1}
 160 | | ... | ${virtio_feature_mask}=${None}
 161 | |
 162 | | FOR | ${dut} | IN | @{duts}
 163 | | | Initialize L2 bridge domains with Vhost-User on node
 164 | | | ... | ${dut} | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 165 | | | ... | virtio_feature_mask=${virtio_feature_mask}
 166 | | END
 167
 168 | Initialize L2 bridge domains for multiple chains with Vhost-User
 169 | | [Documentation]
 170 | | ... | Create pairs of Vhost-User interfaces for defined number of NF chains
 171 | | ... | with defined number of VNF nodes on all defined VPP nodes. Add each
 172 | | ... | Vhost-User interface into L2 bridge domains with learning enabled
 173 | | ... | with physical inteface or Vhost-User interface of another VM.
 174 | | ... | Put all interfaces in path up.
 175 | |
 176 | | ... | *Arguments:*
 177 | | ... | - nf_chains - Number of chains of NFs. Type: integer
 178 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 179 | | ... | - start - Id of first chain, allows to add chains during test.
 180 | | ... |     Type: integer
 181 | | ... | - virtio_feature_mask - Enabled Virtio features (Optional).
 182 | | ... | Type: integer
 183 | |
 184 | | ... | *Example:*
 185 | |
 186 | | ... | \| Initialize L2 bridge domains for multiple chains with Vhost-User \
 187 | | ... | \| 3 \| 1 \| 2 \|
 188 | |
 189 | | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${start}=${1}
 190 | | ... | ${virtio_feature_mask}=${None}
 191 | |
 192 | | Set interfaces in path up
 193 | | FOR | ${nf_chain} | IN RANGE | ${start} | ${nf_chains} + 1
 194 | | | Initialize L2 bridge domains with Vhost-User
 195 | | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 196 | | | ... | virtio_feature_mask=${virtio_feature_mask}
 197 | | END
 198
 199 | Initialize L2 bridge domain with VXLANoIPv4 in 3-node circular topology
 200 | | [Documentation]
 201 | | ... | Setup L2 bridge domain topology with VXLANoIPv4 by connecting
 202 | | ... | physical and vxlan interfaces on each DUT. All interfaces are brought
 203 | | ... | up. IPv4 addresses with prefix /24 are configured on interfaces
 204 | | ... | between DUTs. VXLAN sub-interfaces has same IPv4 address as
 205 | | ... | interfaces.
 206 | |
 207 | | Set interfaces in path up
 208 | | VPP Interface Set IP Address
 209 | | ... | ${dut1} | ${DUT1_${int}2}[0] | 172.16.0.1 | 24
 210 | | VPP Interface Set IP Address
 211 | | ... | ${dut2} | ${DUT2_${int}1}[0] | 172.16.0.2 | 24
 212 | | VPP Add IP Neighbor
 213 | | ... | ${dut1} | ${DUT1_${int}2}[0] | 172.16.0.2
 214 | | ... | ${DUT2_${int}1_mac}[0]
 215 | | VPP Add IP Neighbor
 216 | | ... | ${dut2} | ${DUT2_${int}1}[0] | 172.16.0.1
 217 | | ... | ${DUT1_${int}2_mac}[0]
 218 | | ${dut1s_vxlan}= | Create VXLAN interface
 219 | | ... | ${dut1} | 24 | 172.16.0.1 | 172.16.0.2
 220 | | ${dut2s_vxlan}= | Create VXLAN interface
 221 | | ... | ${dut2} | 24 | 172.16.0.2 | 172.16.0.1
 222 | | VPP Add L2 Bridge Domain
 223 | | ... | ${dut1} | ${1} | ${DUT1_${int}1}[0] | ${dut1s_vxlan}
 224 | | Set Interface State
 225 | | ... | ${dut1} | ${dut1s_vxlan} | up
 226 | | VPP Add L2 Bridge Domain
 227 | | ... | ${dut2} | ${1} | ${DUT2_${int}2}[0] | ${dut2s_vxlan}
 228 | | Set Interface State
 229 | | ... | ${dut2} | ${dut2s_vxlan} | up
 230
 231 | Initialize L2 bridge domain with VLAN and VXLANoIPv4 in 3-node circular topology
 232 | | [Documentation]
 233 | | ... | Setup L2 bridge domain topology with VLAN and VXLANoIPv4 by connecting
 234 | | ... | pairs of VLAN sub-interface and VXLAN interface to separate L2 bridge
 235 | | ... | domain on each DUT. All interfaces are brought up. IPv4 addresses
 236 | | ... | with prefix /32 are configured on interfaces between DUTs. VXLAN
 237 | | ... | sub-interfaces has same IPv4 address as interfaces.
 238 | |
 239 | | ... | *Arguments:*
 240 | | ... | - vxlan_count - VXLAN count. Type: integer
 241 | |
 242 | | ... | *Example:*
 243 | |
 244 | | ... | \| Initialize L2 bridge domain with VLAN and VXLANoIPv4 in 3-node \
 245 | | ... | \| circular topology \| ${1} \|
 246 | |
 247 | | [Arguments] | ${vxlan_count}=${1}
 248 | |
 249 | | Set interfaces in path up
 250 | |
 251 | | ${bd_id_start}= | Set Variable | ${1}
 252 | | ${vni_start} = | Set Variable | ${20}
 253 | |
 254 | | ${ip_step} = | Set Variable | ${2}
 255 | | ${dut1_ip_start}= | Set Variable | 172.16.0.1
 256 | | ${dut2_ip_start}= | Set Variable | 172.16.0.2
 257 | |
 258 | | Vpp create multiple VXLAN IPv4 tunnels
 259 | | ... | node=${dut1}
 260 | | ... | node_vxlan_if=${DUT1_${int}2}[0]
 261 | | ... | node_vlan_if=${DUT1_${int}1}[0]
 262 | | ... | op_node=${dut2}
 263 | | ... | op_node_if=${DUT2_${int}1}[0]
 264 | | ... | n_tunnels=${vxlan_count}
 265 | | ... | vni_start=${vni_start}
 266 | | ... | src_ip_start=${dut1_ip_start}
 267 | | ... | dst_ip_start=${dut2_ip_start}
 268 | | ... | ip_step=${ip_step}
 269 | | ... | bd_id_start=${bd_id_start}
 270 | | Vpp create multiple VXLAN IPv4 tunnels
 271 | | ... | node=${dut2}
 272 | | ... | node_vxlan_if=${DUT2_${int}1}[0]
 273 | | ... | node_vlan_if=${DUT2_${int}2}[0]
 274 | | ... | op_node=${dut1}
 275 | | ... | op_node_if=${DUT1_${int}2}[0]
 276 | | ... | n_tunnels=${vxlan_count}
 277 | | ... | vni_start=${vni_start}
 278 | | ... | src_ip_start=${dut2_ip_start}
 279 | | ... | dst_ip_start=${dut1_ip_start}
 280 | | ... | ip_step=${ip_step}
 281 | | ... | bd_id_start=${bd_id_start}
 282
 283 | Initialize L2 bridge domains with Vhost-User and VXLANoIPv4 in 3-node circular topology
 284 | | [Documentation]
 285 | | ... | Create two Vhost-User interfaces on all defined VPP nodes. Add each
 286 | | ... | Vhost-User interface into L2 bridge domains with learning enabled
 287 | | ... | with physical inteface.
 288 | | ... | Setup VXLANoIPv4 between DUTs by connecting physical and vxlan
 289 | | ... | interfaces on each DUT. All interfaces are brought up.
 290 | | ... | IPv4 addresses with prefix /24 are configured on interfaces between
 291 | | ... | DUTs. VXLAN sub-interfaces has same IPv4 address as interfaces.
 292 | |
 293 | | ... | *Arguments:*
 294 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 295 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 296 | | ... | - virtio_feature_mask - Enabled Virtio features (Optional).
 297 | | ... | Type: integer
 298 | |
 299 | | ... | *Example:*
 300 | |
 301 | | ... | \| L2 bridge domains with Vhost-User and VXLANoIPv4 initialized in a\
 302 | | ... | 3-node circular topology \| 1 \| 2 \|
 303 | |
 304 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${virtio_feature_mask}=${None}
 305 | |
 306 | | VPP Interface Set IP Address
 307 | | ... | ${dut1} | ${DUT1_${int}2}[0] | 172.16.0.1 | 24
 308 | | VPP Interface Set IP Address
 309 | | ... | ${dut2} | ${DUT2_${int}1}[0] | 172.16.0.2 | 24
 310 | | Set interfaces in path up
 311 | | ${dut1s_vxlan}= | Create VXLAN interface
 312 | | ... | ${dut1} | 24 | 172.16.0.1 | 172.16.0.2
 313 | | ${dut2s_vxlan}= | Create VXLAN interface
 314 | | ... | ${dut2} | 24 | 172.16.0.2 | 172.16.0.1
 315 | | Configure vhost interfaces | ${dut1}
 316 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 317 | | ... | virtio_feature_mask=${virtio_feature_mask}
 318 | | Add interface to bridge domain
 319 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 320 | | Add interface to bridge domain
 321 | | ... | ${dut1} | ${vhost_if1} | ${bd_id1}
 322 | | Add interface to bridge domain
 323 | | ... | ${dut1} | ${vhost_if2} | ${bd_id2}
 324 | | Add interface to bridge domain
 325 | | ... | ${dut1} | ${dut1s_vxlan} | ${bd_id2}
 326 | | Configure vhost interfaces | ${dut2}
 327 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 328 | | ... | virtio_feature_mask=${virtio_feature_mask}
 329 | | Add interface to bridge domain
 330 | | ... | ${dut2} | ${dut2s_vxlan} | ${bd_id1}
 331 | | Add interface to bridge domain
 332 | | ... | ${dut2} | ${vhost_if1} | ${bd_id1}
 333 | | Add interface to bridge domain
 334 | | ... | ${dut2} | ${vhost_if2} | ${bd_id2}
 335 | | Add interface to bridge domain
 336 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 337
 338 | Initialize L2 bridge domains with VLAN dot1q sub-interfaces in circular topology
 339 | | [Documentation]
 340 | | ... | Setup L2 bridge domain topology with learning enabled with VLAN by
 341 | | ... | connecting physical and vlan interfaces on each DUT. In case of 3-node
 342 | | ... | topology create VLAN sub-interfaces between DUTs. In case of 2-node
 343 | | ... | topology create VLAN sub-interface on dut1-if2 interface. All
 344 | | ... | interfaces are brought up.
 345 | |
 346 | | ... | *Arguments:*
 347 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 348 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 349 | | ... | - subid - ID of the sub-interface to be created. Type: string
 350 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 351 | |
 352 | | ... | _NOTE:_ This KW uses following test case variables:
 353 | | ... | - dut1 - DUT1 node.
 354 | | ... | - dut2 - DUT2 node.
 355 | | ... | - dut1_if2 - DUT1 interface towards DUT2.
 356 | | ... | - dut2_if1 - DUT2 interface towards DUT1.
 357 | |
 358 | | ... | *Example:*
 359 | |
 360 | | ... | \| Initialize L2 bridge domains with VLAN dot1q sub-interfaces
 361 | | ... | in a 3-node circular topology \| 1 \| 2 \| 10 \| pop-1 \|
 362 | |
 363 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 364 | |
 365 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 366 | | ... | Variable Should Exist | ${dut2}
 367 | |
 368 | | Set interfaces in path up
 369 | |
 370 | | Run Keyword If | '${dut2_status}' == 'PASS'
 371 | | ... | Initialize VLAN dot1q sub-interfaces in circular topology
 372 | | ... | ${dut1} | ${DUT1_${int}2}[0]
 373 | | ... | ${dut2} | ${DUT2_${int}1}[0] | SUB_ID=${subid}
 374 | | ... | ELSE | Initialize VLAN dot1q sub-interfaces in circular topology
 375 | | ... | ${dut1} | ${DUT1_${int}2}[0] | SUB_ID=${subid}
 376 | | Run Keyword If | '${dut2_status}' == 'PASS'
 377 | | ... | Configure L2 tag rewrite method on interfaces
 378 | | ... | ${dut1} | ${subif_index_1}
 379 | | ... | ${dut2} | ${subif_index_2} | TAG_REWRITE_METHOD=${tag_rewrite}
 380 | | ... | ELSE | Configure L2 tag rewrite method on interfaces
 381 | | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
 382 | | Add interface to bridge domain
 383 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 384 | | Add interface to bridge domain
 385 | | ... | ${dut1} | ${subif_index_1} | ${bd_id1}
 386 | | Run Keyword If | '${dut2_status}' == 'PASS'
 387 | | ... | Add interface to bridge domain
 388 | | ... | ${dut2} | ${subif_index_2} | ${bd_id2}
 389 | | Run Keyword If | '${dut2_status}' == 'PASS'
 390 | | ... | Add interface to bridge domain
 391 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 392
 393 | Initialize L2 bridge domains with Vhost-User and VLAN in circular topology
 394 | | [Documentation]
 395 | | ... | Create two Vhost-User interfaces on all defined VPP nodes. Add each
 396 | | ... | Vhost-User interface into L2 bridge domains with learning enabled
 397 | | ... | with physical inteface. In case of 3-node topology create VLAN
 398 | | ... | sub-interfaces between DUTs. In case of 2-node topology create VLAN
 399 | | ... | sub-interface on dut1-if2 interface. All interfaces are brought up.
 400 | |
 401 | | ... | *Arguments:*
 402 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 403 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 404 | | ... | - subid - ID of the sub-interface to be created. Type: string
 405 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 406 | | ... | - virtio_feature_mask - Enabled Virtio features (Optional).
 407 | | ... | Type: integer
 408 | |
 409 | | ... | *Example:*
 410 | |
 411 | | ... | \| L2 bridge domains with Vhost-User and VLAN initialized in circular\
 412 | | ... | topology \| 1 \| 2 \| 10 \| pop-1 \|
 413 | |
 414 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 415 | | ... | ${virtio_feature_mask}=${None}
 416 | |
 417 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 418 | | ... | Variable Should Exist | ${dut2}
 419 | |
 420 | | Set interfaces in path up
 421 | |
 422 | | Run Keyword If | '${dut2_status}' == 'PASS'
 423 | | ... | Initialize VLAN dot1q sub-interfaces in circular topology
 424 | | ... | ${dut1} | ${DUT1_${int}2}[0]
 425 | | ... | ${dut2} | ${DUT2_${int}1}[0] | SUB_ID=${subid}
 426 | | ... | ELSE | Initialize VLAN dot1q sub-interfaces in circular topology
 427 | | ... | ${dut1} | ${DUT1_${int}2}[0] | SUB_ID=${subid}
 428 | | Run Keyword If | '${dut2_status}' == 'PASS'
 429 | | ... | Configure L2 tag rewrite method on interfaces
 430 | | ... | ${dut1} | ${subif_index_1}
 431 | | ... | ${dut2} | ${subif_index_2} | TAG_REWRITE_METHOD=${tag_rewrite}
 432 | | ... | ELSE | Configure L2 tag rewrite method on interfaces
 433 | | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
 434 | | Configure vhost interfaces | ${dut1}
 435 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 436 | | ... | virtio_feature_mask=${virtio_feature_mask}
 437 | | Add interface to bridge domain
 438 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 439 | | Add interface to bridge domain
 440 | | ... | ${dut1} | ${vhost_if1} | ${bd_id1}
 441 | | Add interface to bridge domain
 442 | | ... | ${dut1} | ${vhost_if2} | ${bd_id2}
 443 | | Add interface to bridge domain
 444 | | ... | ${dut1} | ${subif_index_1} | ${bd_id2}
 445 | | Run Keyword If | '${dut2_status}' == 'PASS'
 446 | | ... | Configure vhost interfaces | ${dut2}
 447 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 448 | | ... | virtio_feature_mask=${virtio_feature_mask}
 449 | | Run Keyword If | '${dut2_status}' == 'PASS'
 450 | | ... | Add interface to bridge domain | ${dut2} | ${subif_index_2}
 451 | | ... | ${bd_id1}
 452 | | Run Keyword If | '${dut2_status}' == 'PASS'
 453 | | ... | Add interface to bridge domain | ${dut2} | ${vhost_if1} | ${bd_id1}
 454 | | Run Keyword If | '${dut2_status}' == 'PASS'
 455 | | ... | Add interface to bridge domain | ${dut2} | ${vhost_if2} | ${bd_id2}
 456 | | Run Keyword If | '${dut2_status}' == 'PASS'
 457 | | ... | Add interface to bridge domain | ${dut2} | ${DUT2_${int}2}[0]
 458 | | ... | ${bd_id2}
 459
 460 | Initialize L2 bridge domains with Vhost-User and VLAN with VPP link bonding in a 3-node circular topology
 461 | | [Documentation]
 462 | | ... | Create two Vhost-User interfaces on all defined VPP nodes. Create one
 463 | | ... | link bonding (BondEthernet) interface on both VPP nodes. Enslave one
 464 | | ... | physical interface towards next DUT by BondEthernet interface. Setup
 465 | | ... | VLAN on BondEthernet interfaces between DUTs. Add one Vhost-User
 466 | | ... | interface into L2 bridge domains with learning enabled with physical
 467 | | ... | interface towards TG and other Vhost-User interface into L2 bridge
 468 | | ... | domains with learning enabled with VLAN sub-interface. All interfaces
 469 | | ... | are brought up.
 470 | |
 471 | | ... | *Arguments:*
 472 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 473 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 474 | | ... | - subid - ID of the sub-interface to be created. Type: string
 475 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 476 | | ... | - bond_mode - Link bonding mode. Type: string
 477 | | ... | - lb_mode - Load balance mode. Type: string
 478 | | ... | - virtio_feature_mask - Enabled Virtio features (Optional).
 479 | | ... | Type: integer
 480 | |
 481 | | ... | *Example:*
 482 | |
 483 | | ... | \| Initialize L2 bridge domains with Vhost-User and VLAN with VPP\
 484 | | ... | link bonding in a 3-node circular topology \| 1 \| 2 \
 485 | | ... | \| 10 \| pop-1 \| xor \| l34 \|
 486 | |
 487 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 488 | | ... | ${bond_mode} | ${lb_mode} | ${virtio_feature_mask}=${None}
 489 | |
 490 | | Set interfaces in path up
 491 | | ${dut1_eth_bond_if1}= | VPP Create Bond Interface
 492 | | ... | ${dut1} | ${bond_mode} | ${lb_mode}
 493 | | Set Interface State | ${dut1} | ${dut1_eth_bond_if1} | up
 494 | | VPP Set interface MTU | ${dut1} | ${dut1_eth_bond_if1}
 495 | | FOR | ${pf} | IN RANGE | 1 | ${nic_pfs} + 1
 496 | | | ${_even}= | Evaluate | ${pf} % 2
 497 | | | Run Keyword Unless | ${even}
 498 | | | ... | VPP Enslave Physical Interface
 499 | | | ... | ${dut1} | ${DUT1_${int}${pf}}[0] | ${dut1_eth_bond_if1}
 500 | | END
 501 | | ${dut2_eth_bond_if1}= | VPP Create Bond Interface
 502 | | ... | ${dut2} | ${bond_mode} | ${lb_mode}
 503 | | Set Interface State | ${dut2} | ${dut2_eth_bond_if1} | up
 504 | | VPP Set interface MTU | ${dut2} | ${dut2_eth_bond_if1}
 505 | | FOR | ${pf} | IN RANGE | 1 | ${nic_pfs} + 1
 506 | | | ${_even}= | Evaluate | ${pf} % 2
 507 | | | Run Keyword If | ${even}
 508 | | | ... | VPP Enslave Physical Interface
 509 | | | ... | ${dut2} | ${DUT2_${int}${pf}}[0] | ${dut2_eth_bond_if1}
 510 | | END
 511 | | VPP Show Bond Data On All Nodes | ${nodes} | verbose=${TRUE}
 512 | | Initialize VLAN dot1q sub-interfaces in circular topology
 513 | | ... | ${dut1} | ${dut1_eth_bond_if1}
 514 | | ... | ${dut2} | ${dut2_eth_bond_if1} | ${subid}
 515 | | Configure L2 tag rewrite method on interfaces
 516 | | ... | ${dut1} | ${subif_index_1}
 517 | | ... | ${dut2} | ${subif_index_2} | ${tag_rewrite}
 518 | | Configure vhost interfaces | ${dut1}
 519 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 520 | | ... | virtio_feature_mask=${virtio_feature_mask}
 521 | | Add interface to bridge domain
 522 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 523 | | Add interface to bridge domain
 524 | | ... | ${dut1} | ${vhost_if1} | ${bd_id1}
 525 | | Add interface to bridge domain
 526 | | ... | ${dut1} | ${vhost_if2} | ${bd_id2}
 527 | | Add interface to bridge domain
 528 | | ... | ${dut1} | ${subif_index_1} | ${bd_id2}
 529 | | Configure vhost interfaces | ${dut2}
 530 | | ... | /var/run/vpp/sock-1-${bd_id1} | /var/run/vpp/sock-1-${bd_id2}
 531 | | ... | virtio_feature_mask=${virtio_feature_mask}
 532 | | Add interface to bridge domain
 533 | | ... | ${dut2} | ${subif_index_2} | ${bd_id1}
 534 | | Add interface to bridge domain
 535 | | ... | ${dut2} | ${vhost_if1} | ${bd_id1}
 536 | | Add interface to bridge domain
 537 | | ... | ${dut2} | ${vhost_if2} | ${bd_id2}
 538 | | Add interface to bridge domain
 539 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 540
 541 | Initialize L2 Bridge Domain with memif pairs on DUT node
 542 | | [Documentation]
 543 | | ... | Create pairs of Memif interfaces on DUT node. Put each Memif interface
 544 | | ... | to separate L2 bridge domain with one physical or memif interface
 545 | | ... | to create a chain accross DUT node.
 546 | |
 547 | | ... | *Arguments:*
 548 | | ... | - dut - DUT node. Type: dictionary
 549 | | ... | - nf_chain - NF chain. Type: integer
 550 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 551 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 552 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 553 | |
 554 | | ... | *Note:*
 555 | | ... | Socket paths for Memif are defined in following format:
 556 | | ... | - /tmp/memif-\${dut}_CNF\${nf_id}-\${sid}
 557 | |
 558 | | ... | *Example:*
 559 | |
 560 | | ... | \| Initialize L2 Bridge Domain with memif pairs on DUT node \
 561 | | ... | \| ${dut} \| 1 \| 1 \|
 562 | |
 563 | | [Arguments] | ${dut} | ${nf_chain}=${1} | ${nf_nodes}=${1}
 564 | | ... | ${auto_scale}=${True}
 565 | |
 566 | | ${rxq}= | Run Keyword If | ${auto_scale} == ${True}
 567 | | ... | Set Variable | ${rxq_count_int}
 568 | | ... | ELSE | Set Variable | ${1}
 569 | | ${bd_id1}= | Evaluate | ${nf_nodes} * (${nf_chain} - 1) + ${nf_chain}
 570 | | ${bd_id2}= | Evaluate | ${nf_nodes} * ${nf_chain} + ${nf_chain}
 571 | | Add interface to bridge domain
 572 | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${nf_chain}}[0]
 573 | | ... | ${bd_id1}
 574 | | Add interface to bridge domain
 575 | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${nf_chain}}[0]
 576 | | ... | ${bd_id2}
 577 | | FOR | ${nf_node} | IN RANGE | 1 | ${nf_nodes}+1
 578 | | | ${nf_id}= | Evaluate | (${nf_chain} - ${1}) * ${nf_nodes} + ${nf_node}
 579 | | | ${sock1}= | Set Variable | memif-${dut}_CNF
 580 | | | ${sock2}= | Set Variable | memif-${dut}_CNF
 581 | | | ${bd_id1}= | Evaluate | ${nf_id} + (${nf_chain} - 1)
 582 | | | ${bd_id2}= | Evaluate | ${bd_id1} + 1
 583 | | | Set up memif interfaces on DUT node | ${nodes['${dut}']}
 584 | | | ... | ${sock1} | ${sock2} | ${nf_id} | ${dut}-memif-${nf_id}-if1
 585 | | | ... | ${dut}-memif-${nf_id}-if2 | ${rxq} | ${rxq}
 586 | | | Add interface to bridge domain
 587 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id}-if1} | ${bd_id1}
 588 | | | Add interface to bridge domain
 589 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id}-if2} | ${bd_id2}
 590 | | END
 591
 592 | Initialize L2 Bridge Domain with memif pairs
 593 | | [Documentation]
 594 | | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
 595 | | ... | Memif interface to separate L2 bridge domain with one physical or
 596 | | ... | virtual interface to create a chain accross DUT node.
 597 | |
 598 | | ... | *Arguments:*
 599 | | ... | - nf_chain - NF chain. Type: integer
 600 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 601 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 602 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 603 | |
 604 | | ... | *Example:*
 605 | |
 606 | | ... | \| Initialize L2 Bridge Domain with memif pairs \| 1 \| 1 \|
 607 | |
 608 | | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 609 | |
 610 | | FOR | ${dut} | IN | @{duts}
 611 | | | Initialize L2 Bridge Domain with memif pairs on DUT node | ${dut}
 612 | | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 613 | | | ... | auto_scale=${auto_scale}
 614 | | END
 615
 616 | Initialize L2 Bridge Domain for multiple chains with memif pairs
 617 | | [Documentation]
 618 | | ... | Create pairs of Memif interfaces for defined number of NF chains
 619 | | ... | with defined number of NF nodes on all defined VPP nodes. Add each
 620 | | ... | Memif interface into L2 bridge domains with learning enabled
 621 | | ... | with physical inteface or Memif interface of another NF.
 622 | |
 623 | | ... | *Arguments:*
 624 | | ... | - nf_chains - Number of chains of NFs. Type: integer
 625 | | ... | - nf_nodes - Number of NFs nodes per chain. Type: integer
 626 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 627 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 628 | |
 629 | | ... | *Example:*
 630 | |
 631 | | ... | \| Initialize L2 Bridge Domain for multiple chains with memif pairs \
 632 | | ... | \| 1 \| 1 \|
 633 | |
 634 | | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 635 | |
 636 | | FOR | ${nf_chain} | IN RANGE | 1 | ${nf_chains}+1
 637 | | | Initialize L2 Bridge Domain with memif pairs | nf_chain=${nf_chain}
 638 | | | ... | nf_nodes=${nf_nodes} | auto_scale=${auto_scale}
 639 | | END
 640 | | Set interfaces in path up
 641 | | Show Memif on all DUTs | ${nodes}
 642 | | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
 643
 644 | Initialize L2 Bridge Domain for pipeline with memif pairs
 645 | | [Documentation]
 646 | | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
 647 | | ... | Memif interface to separate L2 bridge domain with one physical or
 648 | | ... | virtual interface to create a service pipeline on DUT node.
 649 | |
 650 | | ... | *Arguments:*
 651 | | ... | - nf_chain - NF pipe. Type: integer
 652 | | ... | - nf_nodes - Number of NFs nodes per pipeline. Type: integer
 653 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 654 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 655 | |
 656 | | ... | *Example:*
 657 | |
 658 | | ... | \| Initialize L2 Bridge Domain for pipeline with memif pairs \
 659 | | ... | \| 1 \| 1 \|
 660 | |
 661 | | [Arguments] | ${nf_chain}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 662 | |
 663 | | ${rxq}= | Run Keyword If | ${auto_scale} == ${True}
 664 | | ... | Set Variable | ${rxq_count_int}
 665 | | ... | ELSE | Set Variable | ${1}
 666 | | ${bd_id1}= | Evaluate | ${nf_nodes} * (${nf_chain} - 1) + ${nf_chain}
 667 | | ${bd_id2}= | Evaluate | ${nf_nodes} * ${nf_chain} + ${nf_chain}
 668 | | FOR | ${dut} | IN | @{duts}
 669 | | | Add interface to bridge domain
 670 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}1_${nf_chain}}[0]
 671 | | | ... | ${bd_id1}
 672 | | | Add interface to bridge domain
 673 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}2_${nf_chain}}[0]
 674 | | | ... | ${bd_id2}
 675 | | | ${nf_id_frst}= | Evaluate | (${nf_chain}-${1}) * ${nf_nodes} + ${1}
 676 | | | ${nf_id_last}= | Evaluate | (${nf_chain}-${1}) * ${nf_nodes} + ${nf_nodes}
 677 | | | ${sid_frst}= | Evaluate | ${nf_id_frst} * ${2} - ${1}
 678 | | | ${sid_last}= | Evaluate | ${nf_id_last} * ${2}
 679 | | | Set up single memif interface on DUT node | ${nodes['${dut}']}
 680 | | | ... | memif-${dut}_CNF | mid=${nf_id_frst} | sid=${sid_frst}
 681 | | | ... | memif_if=${dut}-memif-${nf_id_frst}-if1
 682 | | | ... | rxq=${rxq} | txq=${rxq}
 683 | | | Set up single memif interface on DUT node | ${nodes['${dut}']}
 684 | | | ... | memif-${dut}_CNF | mid=${nf_id_last} | sid=${sid_last}
 685 | | | ... | memif_if=${dut}-memif-${nf_id_last}-if2
 686 | | | ... | rxq=${rxq} | txq=${rxq}
 687 | | | Add interface to bridge domain
 688 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id_frst}-if1} | ${bd_id1}
 689 | | | Add interface to bridge domain
 690 | | | ... | ${nodes['${dut}']} | ${${dut}-memif-${nf_id_last}-if2} | ${bd_id2}
 691 | | END
 692
 693 | Initialize L2 Bridge Domain for multiple pipelines with memif pairs
 694 | | [Documentation]
 695 | | ... | Create pairs of Memif interfaces for defined number of NF pipelines
 696 | | ... | with defined number of NF nodes on all defined VPP nodes. Add each
 697 | | ... | Memif interface into L2 bridge domains with learning enabled
 698 | | ... | with physical inteface or Memif interface of another NF.
 699 | |
 700 | | ... | *Arguments:*
 701 | | ... | - nf_chains - Number of pipelines of NFs. Type: integer
 702 | | ... | - nf_nodes - Number of NFs nodes per pipeline. Type: integer
 703 | | ... | - auto_scale - Whether to use same amount of RXQs for memif interface
 704 | | ... | in containers as vswitch, otherwise use single RXQ. Type: boolean
 705 | |
 706 | | ... | *Example:*
 707 | |
 708 | | ... | \| Initialize L2 Bridge Domain for multiple pipelines with memif \
 709 | | ... | pairs \| 1 \| 1 \|
 710 | |
 711 | | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 712 | |
 713 | | FOR | ${nf_chain} | IN RANGE | 1 | ${nf_chains}+1
 714 | | | Initialize L2 Bridge Domain for pipeline with memif pairs
 715 | | | ... | nf_chain=${nf_chain} | nf_nodes=${nf_nodes}
 716 | | | ... | auto_scale=${auto_scale}
 717 | | END
 718 | | Set interfaces in path up
 719 | | Show Memif on all DUTs | ${nodes}
 720 | | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
 721
 722 | Initialize L2 Bridge Domain with memif pairs and VLAN in circular topology
 723 | | [Documentation]
 724 | | ... | Create pairs of Memif interfaces on all defined VPP nodes. Put each
 725 | | ... | Memif interface to separate L2 bridge domain with one physical or
 726 | | ... | virtual interface to create a chain accross DUT node. In case of
 727 | | ... | 3-node topology create VLAN sub-interfaces between DUTs. In case of
 728 | | ... | 2-node topology create VLAN sub-interface on dut1-if2 interface. All
 729 | | ... | interfaces are brought up.
 730 | |
 731 | | ... | *Arguments:*
 732 | | ... | - bd_id1 - Bridge domain ID. Type: integer
 733 | | ... | - bd_id2 - Bridge domain ID. Type: integer
 734 | | ... | - subid - ID of the sub-interface to be created. Type: string
 735 | | ... | - tag_rewrite - Method of tag rewrite. Type: string
 736 | |
 737 | | ... | *Example:*
 738 | |
 739 | | ... | \| Initialize L2 Bridge Domain with memif pairs and VLAN in circular\
 740 | | ... | topology \| 1 \| 2 \| 10 \| pop-1 \|
 741 | |
 742 | | [Arguments] | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 743 | |
 744 | | ${dut2_status} | ${value}= | Run Keyword And Ignore Error
 745 | | ... | Variable Should Exist | ${dut2}
 746 | |
 747 | | Set interfaces in path up
 748 | |
 749 | | Run Keyword If | '${dut2_status}' == 'PASS'
 750 | | ... | Initialize VLAN dot1q sub-interfaces in circular topology
 751 | | ... | ${dut1} | ${DUT1_${int}2}[0]
 752 | | ... | ${dut2} | ${DUT2_${int}1}[0] | SUB_ID=${subid}
 753 | | ... | ELSE | Initialize VLAN dot1q sub-interfaces in circular topology
 754 | | ... | ${dut1} | ${DUT1_${int}2}[0] | SUB_ID=${subid}
 755 | | Run Keyword If | '${dut2_status}' == 'PASS'
 756 | | ... | Configure L2 tag rewrite method on interfaces
 757 | | ... | ${dut1} | ${subif_index_1}
 758 | | ... | ${dut2} | ${subif_index_2} | TAG_REWRITE_METHOD=${tag_rewrite}
 759 | | ... | ELSE | Configure L2 tag rewrite method on interfaces
 760 | | ... | ${dut1} | ${subif_index_1} | TAG_REWRITE_METHOD=${tag_rewrite}
 761 | |
 762 | | ${number}= | Set Variable | ${1}
 763 | | ${sock1}= | Set Variable | memif-DUT1_CNF
 764 | | ${sock2}= | Set Variable | memif-DUT1_CNF
 765 | | ${memif_if1_name}= | Set Variable | DUT1-memif-${number}-if1
 766 | | ${memif_if2_name}= | Set Variable | DUT1-memif-${number}-if2
 767 | | Set up memif interfaces on DUT node | ${dut1} | ${sock1} | ${sock2}
 768 | | ... | ${number} | ${memif_if1_name} | ${memif_if2_name} | ${rxq_count_int}
 769 | | ... | ${rxq_count_int}
 770 | | Add interface to bridge domain
 771 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${bd_id1}
 772 | | Add interface to bridge domain
 773 | | ... | ${dut1} | ${${memif_if1_name}} | ${bd_id1}
 774 | | Add interface to bridge domain
 775 | | ... | ${dut1} | ${${memif_if2_name}} | ${bd_id2}
 776 | | Add interface to bridge domain
 777 | | ... | ${dut1} | ${subif_index_1} | ${bd_id2}
 778 | | ${sock1}= | Run Keyword If | '${dut2_status}' == 'PASS'
 779 | | ... | Set Variable | memif-DUT2_CNF
 780 | | ${sock2}= | Run Keyword If | '${dut2_status}' == 'PASS'
 781 | | ... | Set Variable | memif-DUT2_CNF
 782 | | ${memif_if1_name}= | Run Keyword If | '${dut2_status}' == 'PASS'
 783 | | ... | Set Variable | DUT2-memif-${number}-if1
 784 | | ${memif_if2_name}= | Run Keyword If | '${dut2_status}' == 'PASS'
 785 | | ... | Set Variable | DUT2-memif-${number}-if2
 786 | | Run Keyword If | '${dut2_status}' == 'PASS'
 787 | | ... | Set up memif interfaces on DUT node | ${dut2} | ${sock1} | ${sock2}
 788 | | ... | ${number} | ${memif_if1_name} | ${memif_if2_name} | ${rxq_count_int}
 789 | | ... | ${rxq_count_int}
 790 | | Run Keyword If | '${dut2_status}' == 'PASS'
 791 | | ... | Add interface to bridge domain
 792 | | ... | ${dut2} | ${subif_index_2} | ${bd_id1}
 793 | | Run Keyword If | '${dut2_status}' == 'PASS'
 794 | | ... | Add interface to bridge domain
 795 | | ... | ${dut2} | ${${memif_if1_name}} | ${bd_id1}
 796 | | Run Keyword If | '${dut2_status}' == 'PASS'
 797 | | ... | Add interface to bridge domain
 798 | | ... | ${dut2} | ${${memif_if2_name}} | ${bd_id2}
 799 | | Run Keyword If | '${dut2_status}' == 'PASS'
 800 | | ... | Add interface to bridge domain
 801 | | ... | ${dut2} | ${DUT2_${int}2}[0] | ${bd_id2}
 802 | |
 803 | | Show Memif on all DUTs | ${nodes}
 804 | | VPP round robin RX placement on all DUTs | ${nodes} | prefix=memif
 805
 806 | Initialize L2 Bridge Domain for single memif
 807 | | [Documentation]
 808 | | ... | Create single Memif interface on all defined VPP nodes. Put Memif
 809 | | ... | interface to separate L2 bridge domain with one physical interface.
 810 | |
 811 | | ... | *Arguments:*
 812 | | ... | - number - Memif ID. Type: integer
 813 | |
 814 | | ... | *Note:*
 815 | | ... | Socket paths for Memif are defined in following format:
 816 | | ... | - /tmp/memif-DUT1_CNF\${number}-\${sid}
 817 | |
 818 | | ... | KW uses test variable ${rxq_count_int} set by KW Add worker threads
 819 | | ... | and rxqueues to all DUTs
 820 | |
 821 | | ... | *Example:*
 822 | |
 823 | | ... | \| Initialize L2 Bridge Domain for single memif \| 1 \|
 824 | |
 825 | | [Arguments] | ${number}=${1}
 826 | |
 827 | | FOR | ${dut} | IN | @{duts}
 828 | | | ${sock}= | Set Variable | memif-${dut}_CNF
 829 | | | ${sid}= | Evaluate | (${number} * ${2}) - ${1}
 830 | | | Set up single memif interface on DUT node | ${nodes['${dut}']} | ${sock}
 831 | | | ... | mid=${number} | sid=${sid} | memif_if=${dut}-memif-${number}-if1
 832 | | | ... | rxq=${rxq_count_int} | txq=${rxq_count_int}
 833 | | | Add interface to bridge domain
 834 | | | ... | ${nodes['${dut}']} | ${${dut}_${int}1}[]0 | ${number}
 835 | | | Add interface to bridge domain | ${nodes['${dut}']}
 836 | | | ... | ${${dut}-memif-${number}-if1} | ${number}
 837 | | END
 838 | | Set single interfaces in path up
 839 | | Show Memif on all DUTs | ${nodes}
 840
 841 | Initialize L2 bridge domain with MACIP ACLs on DUT1 in 3-node circular topology
 842 | | [Documentation]
 843 | | ... | Setup L2BD topology by adding two interfaces on DUT1 into bridge
 844 | | ... | domain that is created automatically with index 1. Learning is
 845 | | ... | enabled. Interfaces are brought up. Apply required MACIP ACL rules to
 846 | | ... | DUT1 interfaces.
 847 | |
 848 | | Set interfaces in path up
 849 | | VPP Add L2 Bridge Domain
 850 | | ... | ${dut1} | ${1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]
 851 | | Configure L2XC
 852 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${DUT2_${int}2}[0]
 853 | | Configure MACIP ACLs
 854 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]
 855
 856 | Initialize L2 bridge domain with IPv4 ACLs on DUT1 in 3-node circular topology
 857 | | [Documentation]
 858 | | ... | Setup L2BD topology by adding two interfaces on DUT1 into bridge
 859 | | ... | domain that is created automatically with index 1. Learning is
 860 | | ... | enabled. Interfaces are brought up. Apply required ACL rules to DUT1
 861 | | ... | interfaces.
 862 | |
 863 | | Set interfaces in path up
 864 | | VPP Add L2 Bridge Domain
 865 | | ... | ${dut1} | ${1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]
 866 | | Configure L2XC
 867 | | ... | ${dut2} | ${DUT2_${int}1}[0] | ${DUT2_${int}2}[0]
 868 | | Configure IPv4 ACLs
 869 | | ... | ${dut1} | ${DUT1_${int}1}[0] | ${DUT1_${int}2}[0]