Add dot1q-ip4base-[ndrpdr|mrr] perf tests for 2-node topology
[csit.git] / resources / libraries / robot / l2 / tagging.robot
1 # Copyright (c) 2016 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Settings ***
15 | Documentation | Keywords for VLAN tests
16 | Resource | resources/libraries/robot/shared/default.robot
17 | Resource | resources/libraries/robot/l2/l2_xconnect.robot
18 | Library | resources.libraries.python.L2Util
19 | Library | resources.libraries.python.InterfaceUtil
20 | Library | resources.libraries.python.NodePath
21
22 *** Keywords ***
23
24 | Initialize VLAN sub-interfaces in 3-node circular topology
25 | | [Arguments] | ${DUT1} | ${INT1} | ${DUT2} | ${INT2} | ${SUB_ID}
26 | | ...         | ${OUTER_VLAN_ID} | ${INNER_VLAN_ID} | ${TYPE_SUBIF}
27 | | [Documentation] | *Create two subinterfaces on DUTs.*
28 | | ...
29 | | ... | *Arguments:*
30 | | ... | - DUT1 - Node to add sub-interface.
31 | | ... | - INT1 - Interface name on which create sub-interface.
32 | | ... | - DUT2 - Node to add sub-interface.
33 | | ... | - INT2 - Interface name on which create sub-interface.
34 | | ... | - SUB_ID - ID of the sub-interface to be created.
35 | | ... | - OUTER_VLAN_ID - Outer VLAN ID.
36 | | ... | - INNER_VLAN_ID - Inner VLAN ID.
37 | | ... | - TYPE_SUBIF - Type of sub-interface.
38 | | ...
39 | | ... | _Set testcase variables with name and index of created interfaces:_
40 | | ... | - subif_name_1
41 | | ... | - subif_index_1
42 | | ... | - subif_name_2
43 | | ... | - subif_index_2
44 | | ...
45 | | ${INT1_name}= | Get interface name | ${DUT1} | ${INT1}
46 | | ${subif_name_1} | ${subif_index_1}= | Create subinterface | ${DUT1}
47 | | ...                                 | ${INT1_name} | ${SUB_ID}
48 | | ...                                 | ${OUTER_VLAN_ID} | ${INNER_VLAN_ID}
49 | | ...                                 | ${TYPE_SUBIF}
50 | | ${INT2_name}= | Get interface name | ${DUT2} | ${INT2}
51 | | ${subif_name_2} | ${subif_index_2}= | Create subinterface | ${DUT2}
52 | | ...                                 | ${INT2_name} | ${SUB_ID}
53 | | ...                                 | ${OUTER_VLAN_ID} | ${INNER_VLAN_ID}
54 | | ...                                 | ${TYPE_SUBIF}
55 | | Set Interface State | ${DUT1} | ${subif_index_1} | up
56 | | Set Interface State | ${DUT2} | ${subif_index_2} | up
57 | | Set Test Variable | ${subif_name_1}
58 | | Set Test Variable | ${subif_index_1}
59 | | Set Test Variable | ${subif_name_2}
60 | | Set Test Variable | ${subif_index_2}
61
62 | Initialize VLAN dot1q sub-interfaces in circular topology
63 | | [Arguments] | ${DUT1} | ${INT1} | ${DUT2}=${None} | ${INT2}=${None}
64 | | ... | ${SUB_ID}=10
65 | | [Documentation] | *Create two dot1q subinterfaces on DUTs.*
66 | | ...
67 | | ... | *Arguments:*
68 | | ... | - DUT1 - Node to add sub-interface.
69 | | ... | - INT1 - Interface name on which create VLAN sub-interface.
70 | | ... | - DUT2 - Node to add sub-interface.
71 | | ... | - INT2 - Interface name on which create VLAN sub-interface.
72 | | ... | - SUB_ID - ID of the sub-interface to be created.
73 | | ...
74 | | ... | _Set testcase variables with name and index of created interfaces:_
75 | | ... | - subif_name_1
76 | | ... | - subif_index_1
77 | | ... | - subif_name_2
78 | | ... | - subif_index_2
79 | | ...
80 | | ... | *Example:*
81 | | ...
82 | | ... | \| Initialize VLAN dot1q sub-interfaces in circular topology \
83 | | ... | \| ${nodes['DUT1']} \| ${dut1_if2} \| ${nodes['DUT2']} \
84 | | ... | \| ${dut1_if2} \| 10 \|
85 | | ...
86 | | ${INT1_NAME}= | Get interface name | ${DUT1} | ${INT1}
87 | | ${INT2_NAME}= | Run Keyword Unless | ${DUT2} == ${None}
88 | | ... | Get interface name | ${DUT2} | ${INT2}
89 | | ${subif_name_1} | ${subif_index_1}= | Create Vlan Subinterface
90 | | ... | ${DUT1} | ${INT1_NAME} | ${SUB_ID}
91 | | ${subif_name_2} | ${subif_index_2}=
92 | | ... | Run Keyword Unless | ${DUT2} == ${None}
93 | | ... | Create Vlan Subinterface | ${DUT2} | ${INT2_NAME} | ${SUB_ID}
94 | | Set Interface State | ${DUT1} | ${subif_index_1} | up
95 | | Run Keyword Unless | ${DUT2} == ${None}
96 | | ... | Set Interface State | ${DUT2} | ${subif_index_2} | up
97 | | Set Test Variable | ${subif_name_1}
98 | | Set Test Variable | ${subif_index_1}
99 | | Run Keyword Unless | ${DUT2} == ${None}
100 | | ... | Set Test Variable | ${subif_name_2}
101 | | Run Keyword Unless | ${DUT2} == ${None}
102 | | ... | Set Test Variable | ${subif_index_2}
103
104 | Configure L2 tag rewrite method on interfaces
105 | | [Arguments] | ${DUT1} | ${SUB_INT1} | ${DUT2}=${None} | ${SUB_INT2}=${None}
106 | | ... | ${TAG_REWRITE_METHOD}=${None}
107 | | [Documentation] | *Setup tag rewrite on sub-interfaces on DUTs.*
108 | | ...
109 | | ... | *Arguments:*
110 | | ... | - DUT1 - Node to rewrite tags.
111 | | ... | - SUB_INT1 - Interface on which rewrite tags.
112 | | ... | - DUT2 - Node to rewrite tags.
113 | | ... | - SUB_INT2 - Interface on which rewrite tags.
114 | | ... | - TAG_REWRITE_METHOD - Method of tag rewrite.
115 | | ...
116 | | L2 Vlan tag rewrite | ${DUT1} | ${SUB_INT1} | ${TAG_REWRITE_METHOD}
117 | | Run Keyword Unless | ${DUT2} == ${None}
118 | | ... | L2 Vlan tag rewrite | ${DUT2} | ${SUB_INT2} | ${TAG_REWRITE_METHOD}
119
120 | Connect interfaces and VLAN sub-interfaces using L2XC
121 | | [Arguments] | ${DUT1} | ${INT1} | ${SUB_INT1}
122 | | ...         | ${DUT2} | ${INT2} | ${SUB_INT2}
123 | | [Documentation] | *Add interface and subinterface to bidirectional
124 | | ...             | L2-xconnect on DUTs.*
125 | | ...
126 | | ... | *Arguments:*
127 | | ... | - DUT1 - Node to add bidirectional cross-connect.
128 | | ... | - INT1 - Interface to add to the cross-connect.
129 | | ... | - SUB_INT1 - Sub-interface to add to the cross-connect.
130 | | ... | - DUT2 - Node to add bidirectional cross-connect.
131 | | ... | - INT2 - Interface to add to the cross-connect.
132 | | ... | - SUB_INT2 - Sub-interface to add to the cross-connect.
133 | | ...
134 | | Configure L2XC | ${DUT1} | ${INT1} | ${SUB_INT1}
135 | | Configure L2XC | ${DUT2} | ${INT2} | ${SUB_INT2}
136
137 | Create vlan sub-interface
138 | | [Documentation] | Create VLAN sub-interface on DUT and set admin status up.
139 | | ...
140 | | ... | *Arguments:*
141 | | ... | - dut_node - Node to add VLAN sub-intreface. Type: dictionary
142 | | ... | - interface - Interface to create VLAN sub-interface. Type: string
143 | | ... | - vlan_id - VLAN ID. Type: integer
144 | | ...
145 | | ... | *Return:*
146 | | ... | - vlan_name - VLAN sub-interface name. Type: string
147 | | ... | - vlan_index - VLAN sub-interface SW index. Type: integer
148 | | ...
149 | | ... | *Example:*
150 | | ...
151 | | ... | \| Create vlan sub-interface \| ${nodes['DUT1']} \| port3 \| 100 \|
152 | | ...
153 | | [Arguments] | ${dut_node} | ${interface} | ${vlan_id}
154 | | [Return] | ${vlan_name} | ${vlan_index}
155 | | ${interface_name}= | Get interface name | ${dut_node} | ${interface}
156 | | ${vlan_name} | ${vlan_index}= | Create Vlan Subinterface
157 | | ... | ${dut_node} | ${interface_name} | ${vlan_id}
158 | | Set Interface State | ${dut_node} | ${vlan_index} | up
159
160 | Create tagged sub-interface
161 | | [Documentation] | Create tagged sub-interface on DUT. Type of tagged \
162 | | ... | sub-intreface depends on type_subif value:
163 | | ... | - one_tag -> VLAN
164 | | ... | - two_tags -> QinQ VLAN
165 | | ... | - two_tags dot1ad - DOT1AD
166 | | ...
167 | | ... | *Arguments:*
168 | | ... | - dut_node - Node to add VLAN sub-intreface. Type: dictionary
169 | | ... | - interface - Interface to create tagged sub-interface. Type: string
170 | | ... | - subif_id - Sub-interface ID. Type: integer
171 | | ... | - outer_vlan_id - VLAN (outer) ID (Optional). Type: integer
172 | | ... | - inner_vlan_id - VLAN inner ID (Optional). Type: integer
173 | | ... | - type_subif - Sub-interface type (Optional). Type: string
174 | | ...
175 | | ... | *Return:*
176 | | ... | - subif_name - Sub-interface name. Type: string
177 | | ... | - subif_index - Sub-interface SW index. Type: integer
178 | | ...
179 | | ... | *Example:*
180 | | ...
181 | | ... | \| Create tagged sub-interface \| ${nodes['DUT1']} \| port1 \| 10 \
182 | | ... | \| outer_vlan_id=100 \| inner_vlan_id=200 \
183 | | ... | \| type_subif=two_tags dot1ad \|
184 | | ...
185 | | [Arguments] | ${dut_node} | ${interface} | ${subif_id}
186 | | ... | ${outer_vlan_id}=${None} | ${inner_vlan_id}=${None}
187 | | ... | ${type_subif}=${None}
188 | | [Return] | ${subif_name} | ${subif_index}
189 | | ${interface_name}= | Get interface name | ${dut_node} | ${interface}
190 | | ${subif_name} | ${subif_index}= | Create Subinterface
191 | | ... | ${dut_node} | ${interface_name} | ${subif_id}
192 | | ... | outer_vlan_id=${outer_vlan_id} | inner_vlan_id=${inner_vlan_id}
193 | | ... | type_subif=${type_subif}
194
195 | Configure L2 tag rewrite method on interface
196 | | [Documentation] | Set L2 tag rewrite on (sub-)interface on DUT
197 | | ...
198 | | ... | *Arguments:*
199 | | ... | - dut_node - Node to set L2 tag rewrite method. Type: dictionary
200 | | ... | - interface - (Sub-)interface name or SW index to set L2 tag rewrite
201 | | ... | method. Type: string or integer
202 | | ... | - tag_rewrite_method - Tag rewrite method. Type: string
203 | | ... | - push_dot1q - True to push tags as Dot1q, False to push tags as
204 | | ... | Dot1ad (Optional). Type: boolean
205 | | ... | - tag1_id - VLAN tag1 ID (Optional). Type: integer
206 | | ... | - tag2_id - VLAN tag2 ID (Optional). Type: integer
207 | | ...
208 | | ... | *Return:*
209 | | ...
210 | | ... | - No value returned
211 | | ...
212 | | ... | *Example:*
213 | | ...
214 | | ... | \| Configure L2 tag rewrite method on interface \| ${nodes['DUT1']} \
215 | | ... | \| 9 \| pop-1 \|
216 | | ... | \| Configure L2 tag rewrite method on interface \| ${nodes['DUT2']} \
217 | | ... | \| 10 \| translate-1-2 \| push_dot1q=${False} \| tag1_id=10 \
218 | | ... | \| tag1_id=20 \|
219 | | ...
220 | | [Arguments] | ${dut_node} | ${interface} | ${tag_rewrite_method}
221 | | ... | ${push_dot1q}=${True} | ${tag1_id}=${None} | ${tag2_id}=${None}
222 | | ${result}= | Evaluate | isinstance($interface, int)
223 | | ${interface_name}= | Run Keyword If | ${result} | Set Variable | ${interface}
224 | | ...                | ELSE | Get interface name | ${dut_node} | ${interface}
225 | | L2 Vlan Tag Rewrite | ${dut_node} | ${interface_name} | ${tag_rewrite_method}
226 | | ... | push_dot1q=${push_dot1q} | tag1_id=${tag1_id} | tag2_id=${tag2_id}