resources/libraries/robot/performance.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.topology.Topology
  16 | Library | resources.libraries.python.NodePath
  17 | Library | resources.libraries.python.InterfaceUtil
  18 | Library | resources.libraries.python.TrafficGenerator
  19 | Library | resources.libraries.python.TrafficGenerator.TGDropRateSearchImpl
  20 | Resource | resources/libraries/robot/default.robot
  21 | Resource | resources/libraries/robot/interfaces.robot
  22 | Resource | resources/libraries/robot/counters.robot
  23 | Resource | resources/libraries/robot/bridge_domain.robot
  24 | Resource | resources/libraries/robot/l2_xconnect.robot
  25 | Resource | resources/libraries/robot/ipv4.robot
  26 | Resource | resources/libraries/robot/ipv6.robot
  27 | Documentation | Performance suite keywords
  28
  29 *** Keywords ***
  30 | Setup performance rate Variables
  31 | | [Documentation]
  32 | | ... | Setup performance linerates as Suite Variables. Variables are used
  33 | | ... | as search boundaries in RFC2544 throughput search.
  34 | | ...
  35 | | ... | _NOTE:_ This KW sets following suite variables:
  36 | | ... | - 10Ge_linerate_pps_64B - Maximum number of packet per second
  37 | | ... |                           for 10GE with 64B L2 Frame.
  38 | | ... | - 10Ge_linerate_pps_68B - Maximum number of packet per second
  39 | | ... |                           for 10GE with 68B L2 Frame.
  40 | | ... | - 10Ge_linerate_pps_72B - Maximum number of packet per second
  41 | | ... |                           for 10GE with 72B L2 Frame.
  42 | | ... | - 10Ge_linerate_pps_78B - Maximum number of packet per second
  43 | | ... |                           for 10GE with 78B L2 Frame.
  44 | | ... | - 10Ge_linerate_pps_1518B - Maximum number of packet per second
  45 | | ... |                             for 10GE with 1518B L2 Frame.
  46 | | ... | - 10Ge_linerate_pps_1522B - Maximum number of packet per second
  47 | | ... |                             for 10GE with 1522B L2 Frame.
  48 | | ... | - 10Ge_linerate_pps_1526B - Maximum number of packet per second
  49 | | ... |                             for 10GE with 1526B L2 Frame.
  50 | | ... | - 10Ge_linerate_pps_9000B - Maximum number of packet per second
  51 | | ... |                             for 10GE with 9000B L2 Frame.
  52 | | ... | - 10Ge_linerate_pps_9004B - Maximum number of packet per second
  53 | | ... |                             for 10GE with 9004B L2 Frame.
  54 | | ... | - 10Ge_linerate_pps_9008B - Maximum number of packet per second
  55 | | ... |                             for 10GE with 9008B L2 Frame.
  56 | | ... | - 10Ge_linerate_pps_IMIX_v4_1 - Maximum number of packet per second
  57 | | ... |                                 for 10GE with IMIX_v4_1 profile.
  58 | | ... | - 40Ge_linerate_pps_64B - Maximum number of packet per second
  59 | | ... |                           for 40GE with 64B L2 Frame.
  60 | | ... | - 40Ge_linerate_pps_68B - Maximum number of packet per second
  61 | | ... |                           for 40GE with 68B L2 Frame.
  62 | | ... | - 40Ge_linerate_pps_72B - Maximum number of packet per second
  63 | | ... |                           for 40GE with 72B L2 Frame.
  64 | | ... | - 40Ge_linerate_pps_78B - Maximum number of packet per second
  65 | | ... |                           for 40GE with 78B L2 Frame.
  66 | | ... | - 40Ge_linerate_pps_1518B - Maximum number of packet per second
  67 | | ... |                             for 40GE with 1518B L2 Frame.
  68 | | ... | - 40Ge_linerate_pps_1522B - Maximum number of packet per second
  69 | | ... |                             for 40GE with 1522B L2 Frame.
  70 | | ... | - 40Ge_linerate_pps_1526B - Maximum number of packet per second
  71 | | ... |                             for 40GE with 1526B L2 Frame.
  72 | | ... | - 40Ge_linerate_pps_9000B - Maximum number of packet per second
  73 | | ... |                             for 40GE with 9000B L2 Frame.
  74 | | ... | - 40Ge_linerate_pps_9004B - Maximum number of packet per second
  75 | | ... |                             for 40GE with 9004B L2 Frame.
  76 | | ... | - 40Ge_linerate_pps_9008B - Maximum number of packet per second
  77 | | ... |                             for 40GE with 9008B L2 Frame.
  78 | | ...
  79 | | Set Suite Variable | ${10Ge_linerate_pps_64B} | 14880952
  80 | | Set Suite Variable | ${10Ge_linerate_pps_68B} | 14204545
  81 | | Set Suite Variable | ${10Ge_linerate_pps_72B} | 13586956
  82 | | Set Suite Variable | ${10Ge_linerate_pps_78B} | 12755102
  83 | | Set Suite Variable | ${10Ge_linerate_pps_1518B} | 812743
  84 | | Set Suite Variable | ${10Ge_linerate_pps_1522B} | 810635
  85 | | Set Suite Variable | ${10Ge_linerate_pps_9000B} | 138580
  86 | | Set Suite Variable | ${10Ge_linerate_pps_9004B} | 138519
  87 | | Set Suite Variable | ${10Ge_linerate_pps_9008B} | 138458
  88 | | Set Suite Variable | ${10Ge_linerate_pps_IMIX_v4_1} | 3343736
  89 | | Set Suite Variable | ${40Ge_linerate_pps_64B} | 59523809
  90 | | Set Suite Variable | ${40Ge_linerate_pps_68B} | 56818181
  91 | | Set Suite Variable | ${40Ge_linerate_pps_72B} | 54347826
  92 | | Set Suite Variable | ${40Ge_linerate_pps_78B} | 51020408
  93 | | Set Suite Variable | ${40Ge_linerate_pps_1518B} | 3250975
  94 | | Set Suite Variable | ${40Ge_linerate_pps_1522B} | 3242542
  95 | | Set Suite Variable | ${40Ge_linerate_pps_9000B} | 554323
  96 | | Set Suite Variable | ${40Ge_linerate_pps_9004B} | 554078
  97 | | Set Suite Variable | ${40Ge_linerate_pps_9008B} | 553832
  98
  99 | Get Frame Size
 100 | | [Documentation]
 101 | | ... | Framesize can be either integer in case of a single packet
 102 | | ... | in stream, or set of packets in case of IMIX type or simmilar.
 103 | | ... | This keyword returns average framesize.
 104 | | ...
 105 | | ... | *Arguments:*
 106 | | ... | - framesize - Framesize. Type: integer or string
 107 | | ...
 108 | | ... | *Example:*
 109 | | ...
 110 | | ... | \| Get Frame Size \| IMIX_v4_1
 111 | | [Arguments] | ${framesize}
 112 | | Run Keyword If | '${framesize}' == 'IMIX_v4_1'
 113 | | ...            | Return From Keyword | 353.83333
 114 | | Return From Keyword | ${framesize}
 115
 116 | Setup performance global Variables
 117 | | [Documentation]
 118 | | ... | Setup suite Variables. Variables are used across performance testing.
 119 | | ...
 120 | | ... | _NOTE:_ This KW sets following suite variables:
 121 | | ... | - glob_loss_acceptance - Loss acceptance treshold
 122 | | ... | - glob_loss_acceptance_type - Loss acceptance treshold type
 123 | | ...
 124 | | Set Suite Variable | ${glob_loss_acceptance} | 0.5
 125 | | Set Suite Variable | ${glob_loss_acceptance_type} | percentage
 126
 127 | 2-node circular Topology Variables Setup
 128 | | [Documentation]
 129 | | ... | Compute path for testing on two given nodes in circular
 130 | | ... | topology and set corresponding suite variables.
 131 | | ...
 132 | | ... | _NOTE:_ This KW sets following suite variables:
 133 | | ... | - tg - TG node
 134 | | ... | - tg_if1 - 1st TG interface towards DUT.
 135 | | ... | - tg_if2 - 2nd TG interface towards DUT.
 136 | | ... | - dut1 - DUT1 node
 137 | | ... | - dut1_if1 - 1st DUT interface towards TG.
 138 | | ... | - dut1_if2 - 2nd DUT interface towards TG.
 139 | | ...
 140 | | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
 141 | | Compute Path
 142 | | ${tg_if1} | ${tg}= | Next Interface
 143 | | ${dut1_if1} | ${dut1}= | Next Interface
 144 | | ${dut1_if2} | ${dut1}= | Next Interface
 145 | | ${tg_if2} | ${tg}= | Next Interface
 146 | | Set Suite Variable | ${tg}
 147 | | Set Suite Variable | ${tg_if1}
 148 | | Set Suite Variable | ${tg_if2}
 149 | | Set Suite Variable | ${dut1}
 150 | | Set Suite Variable | ${dut1_if1}
 151 | | Set Suite Variable | ${dut1_if2}
 152
 153 | 3-node circular Topology Variables Setup
 154 | | [Documentation]
 155 | | ... | Compute path for testing on three given nodes in circular
 156 | | ... | topology and set corresponding suite variables.
 157 | | ...
 158 | | ... | _NOTE:_ This KW sets following suite variables:
 159 | | ... | - tg - TG node
 160 | | ... | - tg_if1 - TG interface towards DUT1.
 161 | | ... | - tg_if2 - TG interface towards DUT2.
 162 | | ... | - dut1 - DUT1 node
 163 | | ... | - dut1_if1 - DUT1 interface towards TG.
 164 | | ... | - dut1_if2 - DUT1 interface towards DUT2.
 165 | | ... | - dut2 - DUT2 node
 166 | | ... | - dut2_if1 - DUT2 interface towards TG.
 167 | | ... | - dut2_if2 - DUT2 interface towards DUT1.
 168 | | ...
 169 | | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
 170 | | ...          | ${nodes['TG']}
 171 | | Compute Path
 172 | | ${tg_if1} | ${tg}= | Next Interface
 173 | | ${dut1_if1} | ${dut1}= | Next Interface
 174 | | ${dut1_if2} | ${dut1}= | Next Interface
 175 | | ${dut2_if1} | ${dut2}= | Next Interface
 176 | | ${dut2_if2} | ${dut2}= | Next Interface
 177 | | ${tg_if2} | ${tg}= | Next Interface
 178 | | Set Suite Variable | ${tg}
 179 | | Set Suite Variable | ${tg_if1}
 180 | | Set Suite Variable | ${tg_if2}
 181 | | Set Suite Variable | ${dut1}
 182 | | Set Suite Variable | ${dut1_if1}
 183 | | Set Suite Variable | ${dut1_if2}
 184 | | Set Suite Variable | ${dut2}
 185 | | Set Suite Variable | ${dut2_if1}
 186 | | Set Suite Variable | ${dut2_if2}
 187
 188 | 2-node circular Topology Variables Setup with DUT interface model
 189 | | [Documentation]
 190 | | ... | Compute path for testing on two given nodes in circular topology
 191 | | ... | based on interface model provided as an argument and set
 192 | | ... | corresponding suite variables.
 193 | | ...
 194 | | ... | *Arguments:*
 195 | | ... | - iface_model - Interface model. Type: string
 196 | | ...
 197 | | ... | _NOTE:_ This KW sets following suite variables:
 198 | | ... | - tg - TG node
 199 | | ... | - tg_if1 - 1st TG interface towards DUT.
 200 | | ... | - tg_if2 - 2nd TG interface towards DUT.
 201 | | ... | - dut1 - DUT1 node
 202 | | ... | - dut1_if1 - 1st DUT interface towards TG.
 203 | | ... | - dut1_if2 - 2nd DUT interface towards TG.
 204 | | ...
 205 | | ... | *Example:*
 206 | | ...
 207 | | ... | \| 2-node circular Topology Variables Setup with DUT interface model \
 208 | | ... | \| Intel-X520-DA2 \|
 209 | | [Arguments] | ${iface_model}
 210 | | ${iface_model_list}= | Create list | ${iface_model}
 211 | | Append Node | ${nodes['TG']}
 212 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 213 | | Append Node | ${nodes['TG']}
 214 | | Compute Path
 215 | | ${tg_if1} | ${tg}= | Next Interface
 216 | | ${dut1_if1} | ${dut1}= | Next Interface
 217 | | ${dut1_if2} | ${dut1}= | Next Interface
 218 | | ${tg_if2} | ${tg}= | Next Interface
 219 | | Set Suite Variable | ${tg}
 220 | | Set Suite Variable | ${tg_if1}
 221 | | Set Suite Variable | ${tg_if2}
 222 | | Set Suite Variable | ${dut1}
 223 | | Set Suite Variable | ${dut1_if1}
 224 | | Set Suite Variable | ${dut1_if2}
 225
 226 | 3-node circular Topology Variables Setup with DUT interface model
 227 | | [Documentation]
 228 | | ... | Compute path for testing on three given nodes in circular topology
 229 | | ... | based on interface model provided as an argument and set
 230 | | ... | corresponding suite variables.
 231 | | ...
 232 | | ... | *Arguments:*
 233 | | ... | - iface_model - Interface model. Type: string
 234 | | ...
 235 | | ... | _NOTE:_ This KW sets following suite variables:
 236 | | ... | - tg - TG node
 237 | | ... | - tg_if1 - TG interface towards DUT1.
 238 | | ... | - tg_if2 - TG interface towards DUT2.
 239 | | ... | - dut1 - DUT1 node
 240 | | ... | - dut1_if1 - DUT1 interface towards TG.
 241 | | ... | - dut1_if2 - DUT1 interface towards DUT2.
 242 | | ... | - dut2 - DUT2 node
 243 | | ... | - dut2_if1 - DUT2 interface towards TG.
 244 | | ... | - dut2_if2 - DUT2 interface towards DUT1.
 245 | | ...
 246 | | ... | *Example:*
 247 | | ...
 248 | | ... | \| 3-node circular Topology Variables Setup with DUT interface model \
 249 | | ... | \| Intel-X520-DA2 \|
 250 | | [Arguments] | ${iface_model}
 251 | | ${iface_model_list}= | Create list | ${iface_model}
 252 | | Append Node | ${nodes['TG']}
 253 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 254 | | Append Node | ${nodes['DUT2']} | filter_list=${iface_model_list}
 255 | | Append Node | ${nodes['TG']}
 256 | | Compute Path
 257 | | ${tg_if1} | ${tg}= | Next Interface
 258 | | ${dut1_if1} | ${dut1}= | Next Interface
 259 | | ${dut1_if2} | ${dut1}= | Next Interface
 260 | | ${dut2_if1} | ${dut2}= | Next Interface
 261 | | ${dut2_if2} | ${dut2}= | Next Interface
 262 | | ${tg_if2} | ${tg}= | Next Interface
 263 | | Set Suite Variable | ${tg}
 264 | | Set Suite Variable | ${tg_if1}
 265 | | Set Suite Variable | ${tg_if2}
 266 | | Set Suite Variable | ${dut1}
 267 | | Set Suite Variable | ${dut1_if1}
 268 | | Set Suite Variable | ${dut1_if2}
 269 | | Set Suite Variable | ${dut2}
 270 | | Set Suite Variable | ${dut2_if1}
 271 | | Set Suite Variable | ${dut2_if2}
 272
 273 | VPP interfaces in path are up in a 2-node circular topology
 274 | | [Documentation]
 275 | | ... | *Set UP state on VPP interfaces in path on nodes in 2-node circular
 276 | | ... | topology.*
 277 | | ...
 278 | | Set Interface State | ${dut1} | ${dut1_if1} | up
 279 | | Set Interface State | ${dut1} | ${dut1_if2} | up
 280 | | Vpp Node Interfaces Ready Wait | ${dut1}
 281
 282 | VPP interfaces in path are up in a 3-node circular topology
 283 | | [Documentation]
 284 | | ... | *Set UP state on VPP interfaces in path on nodes in 3-node circular
 285 | | ... | topology.*
 286 | | ...
 287 | | Set Interface State | ${dut1} | ${dut1_if1} | up
 288 | | Set Interface State | ${dut1} | ${dut1_if2} | up
 289 | | Set Interface State | ${dut2} | ${dut2_if1} | up
 290 | | Set Interface State | ${dut2} | ${dut2_if2} | up
 291 | | Vpp Node Interfaces Ready Wait | ${dut1}
 292 | | Vpp Node Interfaces Ready Wait | ${dut2}
 293
 294 | IPv4 forwarding initialized in a 3-node circular topology
 295 | | [Documentation]
 296 | | ... | Set UP state on VPP interfaces in path on nodes in 3-node circular
 297 | | ... | topology. Get the interface MAC addresses and setup ARP on all VPP
 298 | | ... | interfaces. Setup IPv4 addresses with /24 prefix on DUT-TG links and
 299 | | ... | /30 prefix on DUT1-DUT2 link. Set routing on both DUT nodes with
 300 | | ... | prefix /24 and next hop of neighbour DUT interface IPv4 address.
 301 | | ...
 302 | | Set Interface State | ${dut1} | ${dut1_if1} | up
 303 | | Set Interface State | ${dut1} | ${dut1_if2} | up
 304 | | Set Interface State | ${dut2} | ${dut2_if1} | up
 305 | | Set Interface State | ${dut2} | ${dut2_if2} | up
 306 | | ${tg1_if1_mac}= | Get Interface MAC | ${tg} | ${tg_if1}
 307 | | ${tg1_if2_mac}= | Get Interface MAC | ${tg} | ${tg_if2}
 308 | | ${dut1_if2_mac}= | Get Interface MAC | ${dut1} | ${dut1_if2}
 309 | | ${dut2_if1_mac}= | Get Interface MAC | ${dut2} | ${dut2_if1}
 310 | | dut1_v4.set_arp | ${dut1_if1} | 10.10.10.2 | ${tg1_if1_mac}
 311 | | dut1_v4.set_arp | ${dut1_if2} | 1.1.1.2 | ${dut2_if1_mac}
 312 | | dut2_v4.set_arp | ${dut2_if1} | 1.1.1.1 | ${dut1_if2_mac}
 313 | | dut2_v4.set_arp | ${dut2_if2} | 20.20.20.2 | ${tg1_if2_mac}
 314 | | dut1_v4.set_ip | ${dut1_if1} | 10.10.10.1 | 24
 315 | | dut1_v4.set_ip | ${dut1_if2} | 1.1.1.1 | 30
 316 | | dut2_v4.set_ip | ${dut2_if1} | 1.1.1.2 | 30
 317 | | dut2_v4.set_ip | ${dut2_if2} | 20.20.20.1 | 24
 318 | | dut1_v4.set_route | 20.20.20.0 | 24 | 1.1.1.2 | ${dut1_if2}
 319 | | dut2_v4.set_route | 10.10.10.0 | 24 | 1.1.1.1 | ${dut2_if1}
 320 | | All Vpp Interfaces Ready Wait | ${nodes}
 321
 322 | IPv6 forwarding initialized in a 3-node circular topology
 323 | | [Documentation]
 324 | | ... | Set UP state on VPP interfaces in path on nodes in 3-node circular
 325 | | ... | topology. Get the interface MAC addresses and setup neighbour on all
 326 | | ... | VPP interfaces. Setup IPv6 addresses with /128 prefixes on all
 327 | | ... | interfaces. Set routing on both DUT nodes with prefix /64 and
 328 | | ... | next hop of neighbour DUT interface IPv6 address.
 329 | | ...
 330 | | ${prefix}= | Set Variable | 64
 331 | | ${tg1_if1_mac}= | Get Interface MAC | ${tg} | ${tg_if1}
 332 | | ${tg1_if2_mac}= | Get Interface MAC | ${tg} | ${tg_if2}
 333 | | ${dut1_if2_mac}= | Get Interface MAC | ${dut1} | ${dut1_if2}
 334 | | ${dut2_if1_mac}= | Get Interface MAC | ${dut2} | ${dut2_if1}
 335 | | VPP Set If IPv6 Addr | ${dut1} | ${dut1_if1} | 2001:1::1 | ${prefix}
 336 | | VPP Set If IPv6 Addr | ${dut1} | ${dut1_if2} | 2001:3::1 | ${prefix}
 337 | | VPP Set If IPv6 Addr | ${dut2} | ${dut2_if1} | 2001:3::2 | ${prefix}
 338 | | VPP Set If IPv6 Addr | ${dut2} | ${dut2_if2} | 2001:2::1 | ${prefix}
 339 | | Vpp nodes ra suppress link layer | ${nodes}
 340 | | Add Ip Neighbor | ${dut1} | ${dut1_if1} | 2001:1::2 | ${tg1_if1_mac}
 341 | | Add Ip Neighbor | ${dut2} | ${dut2_if2} | 2001:2::2 | ${tg1_if2_mac}
 342 | | Add Ip Neighbor | ${dut1} | ${dut1_if2} | 2001:3::2 | ${dut2_if1_mac}
 343 | | Add Ip Neighbor | ${dut2} | ${dut2_if1} | 2001:3::1 | ${dut1_if2_mac}
 344 | | Vpp Route Add | ${dut1} | 2001:2::0 | ${prefix} | 2001:3::2 | ${dut1_if2}
 345 | | Vpp Route Add | ${dut2} | 2001:1::0 | ${prefix} | 2001:3::1 | ${dut2_if1}
 346
 347 | L2 xconnect initialized in a 3-node circular topology
 348 | | [Documentation]
 349 | | ... | Setup L2 xconnect topology by cross connecting two interfaces on
 350 | | ... | each DUT. Interfaces are brought up.
 351 | | ... |
 352 | | L2 setup xconnect on DUT | ${dut1} | ${dut1_if1} | ${dut1_if2}
 353 | | L2 setup xconnect on DUT | ${dut2} | ${dut2_if1} | ${dut2_if2}
 354 | | All Vpp Interfaces Ready Wait | ${nodes}
 355
 356 | L2 bridge domain initialized in a 3-node circular topology
 357 | | [Documentation]
 358 | | ... | Setup L2 DB topology by adding two interfaces on each DUT into BD
 359 | | ... | that is created automatically with index 1. Learning is enabled.
 360 | | ... | Interfaces are brought up.
 361 | | ... |
 362 | | Vpp l2bd forwarding setup | ${dut1} | ${dut1_if1} | ${dut1_if2}
 363 | | Vpp l2bd forwarding setup | ${dut2} | ${dut2_if1} | ${dut2_if2}
 364 | | All Vpp Interfaces Ready Wait | ${nodes}
 365
 366 | 2-node Performance Suite Setup
 367 | | [Documentation]
 368 | | ... | Suite preparation phase that setup default startup configuration of
 369 | | ... | VPP on all DUTs. Updates interfaces on all nodes and setup global
 370 | | ... | variables used in test cases. Initializes traffic generator.
 371 | | ...
 372 | | ... | *Arguments:*
 373 | | ... | - topology_type - Topology type. Type: string
 374 | | ...
 375 | | ... | *Example:*
 376 | | ...
 377 | | ... | \| 2-node Performance Suite Setup \| L2 \|
 378 | | [Arguments] | ${topology_type}
 379 | | Setup default startup configuration of VPP on all DUTs
 380 | | Show vpp version on all DUTs
 381 | | Setup performance rate Variables
 382 | | Setup performance global Variables
 383 | | 2-node circular Topology Variables Setup
 384 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 385 | | ...                          | ${dut1} | ${dut1_if1}
 386 | | ...                          | ${dut1} | ${dut1_if2}
 387 | | ...                          | ${topology_type}
 388
 389 | 3-node Performance Suite Setup
 390 | | [Documentation]
 391 | | ... | Suite preparation phase that setup default startup configuration of
 392 | | ... | VPP on all DUTs. Updates interfaces on all nodes and setup global
 393 | | ... | variables used in test cases. Initializes traffic generator.
 394 | | ...
 395 | | ... | *Arguments:*
 396 | | ... | - topology_type - Topology type. Type: string
 397 | | ...
 398 | | ... | *Example:*
 399 | | ...
 400 | | ... | \| 3-node Performance Suite Setup \| L2 \|
 401 | | [Arguments] | ${topology_type}
 402 | | Setup default startup configuration of VPP on all DUTs
 403 | | Show vpp version on all DUTs
 404 | | Setup performance rate Variables
 405 | | Setup performance global Variables
 406 | | 3-node circular Topology Variables Setup
 407 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 408 | | ...                          | ${dut1} | ${dut1_if1}
 409 | | ...                          | ${dut2} | ${dut2_if2}
 410 | | ...                          | ${topology_type}
 411
 412 2-node Performance Suite Setup with DUT's NIC model
 413 | | [Documentation]
 414 | | ... | Suite preparation phase that setup default startup configuration of
 415 | | ... | VPP on all DUTs. Updates interfaces on all nodes and setup global
 416 | | ... | variables used in test cases based on interface model provided as an
 417 | | ... | argument. Initializes traffic generator.
 418 | | ...
 419 | | ... | *Arguments:*
 420 | | ... | - topology_type - Topology type. Type: string
 421 | | ... | - nic_model - Interface model. Type: string
 422 | | ...
 423 | | ... | *Example:*
 424 | | ...
 425 | | ... | \| 2-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \|
 426 | | [Arguments] | ${topology_type} | ${nic_model}
 427 | | Setup default startup configuration of VPP on all DUTs
 428 | | Show vpp version on all DUTs
 429 | | Setup performance rate Variables
 430 | | Setup performance global Variables
 431 | | 2-node circular Topology Variables Setup with DUT interface model
 432 | | ... | ${nic_model}
 433 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 434 | | ...                          | ${dut1} | ${dut1_if1}
 435 | | ...                          | ${dut1} | ${dut1_if2}
 436 | | ...                          | ${topology_type}
 437
 438 3-node Performance Suite Setup with DUT's NIC model
 439 | | [Documentation]
 440 | | ... | Suite preparation phase that setup default startup configuration of
 441 | | ... | VPP on all DUTs. Updates interfaces on all nodes and setup global
 442 | | ... | variables used in test cases based on interface model provided as an
 443 | | ... | argument. Initializes traffic generator.
 444 | | ...
 445 | | ... | *Arguments:*
 446 | | ... | - topology_type - Topology type. Type: string
 447 | | ... | - nic_model - Interface model. Type: string
 448 | | ...
 449 | | ... | *Example:*
 450 | | ...
 451 | | ... | \| 3-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \|
 452 | | [Arguments] | ${topology_type} | ${nic_model}
 453 | | Setup default startup configuration of VPP on all DUTs
 454 | | Show vpp version on all DUTs
 455 | | Setup performance rate Variables
 456 | | Setup performance global Variables
 457 | | 3-node circular Topology Variables Setup with DUT interface model
 458 | | ... | ${nic_model}
 459 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 460 | | ...                          | ${dut1} | ${dut1_if1}
 461 | | ...                          | ${dut2} | ${dut2_if2}
 462 | | ...                          | ${topology_type}
 463
 464 | 3-node Performance Suite Teardown
 465 | | [Documentation]
 466 | | ... | Suite teardown phase with traffic generator teardown.
 467 | | ...
 468 | | Teardown traffic generator | ${tg}
 469
 470 | Find NDR using linear search and pps
 471 | | [Documentation]
 472 | | ... | Find throughput by using RFC2544 linear search with non drop rate.
 473 | | ...
 474 | | ... | *Arguments:*
 475 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 476 | | ... | - start_rate - Initial start rate [pps]. Type: float
 477 | | ... | - step_rate - Step of linear search [pps]. Type: float
 478 | | ... | - topology_type - Topology type. Type: string
 479 | | ... | - min_rate - Lower limit of search [pps]. Type: float
 480 | | ... | - max_rate - Upper limit of search [pps]. Type: float
 481 | | ...
 482 | | ... | *Return:*
 483 | | ... | - No value returned
 484 | | ...
 485 | | ... | *Example:*
 486 | | ...
 487 | | ... | \| Find NDR using linear search and pps \| 64 \| 5000000 \| \
 488 | | ... | \| 100000 \| 3-node-IPv4 \| 100000 \| 14880952
 489 | | [Arguments] | ${framesize} | ${start_rate} | ${step_rate}
 490 | | ...         | ${topology_type} | ${min_rate} | ${max_rate}
 491 | | ${duration}= | Set Variable | 10
 492 | | Set Duration | ${duration}
 493 | | Set Search Rate Boundaries | ${max_rate} | ${min_rate}
 494 | | Set Search Linear Step | ${step_rate}
 495 | | Set Search Frame Size | ${framesize}
 496 | | Set Search Rate Type pps
 497 | | Linear Search | ${start_rate} | ${topology_type}
 498 | | ${rate_per_stream} | ${latency}= | Verify Search Result
 499 | | Display result of NDR search | ${rate_per_stream} | ${framesize} | 2
 500 | | ...                          | ${latency}
 501 | | Traffic should pass with no loss | ${duration} | ${rate_per_stream}pps
 502 | | ...                              | ${framesize} | ${topology_type}
 503 | | ...                              | fail_on_loss=${False}
 504
 505 | Find PDR using linear search and pps
 506 | | [Documentation]
 507 | | ... | Find throughput by using RFC2544 linear search with partial drop rate
 508 | | ... | with PDR threshold and type specified by parameter.
 509 | | ...
 510 | | ... | *Arguments:*
 511 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 512 | | ... | - start_rate - Initial start rate [pps]. Type: float
 513 | | ... | - step_rate - Step of linear search [pps]. Type: float
 514 | | ... | - topology_type - Topology type. Type: string
 515 | | ... | - min_rate - Lower limit of search [pps]. Type: float
 516 | | ... | - max_rate - Upper limit of search [pps]. Type: float
 517 | | ... | - loss_acceptance - Accepted loss during search. Type: float
 518 | | ... | - loss_acceptance_type - Percentage or frames. Type: string
 519 | | ...
 520 | | ... | *Example:*
 521 | | ...
 522 | | ... | \| Find PDR using linear search and pps \| 64 \| 5000000 \
 523 | | ... | \| 100000 \| 3-node-IPv4 \| 100000 \| 14880952 \| 0.5 \| percentage
 524 | | [Arguments] | ${framesize} | ${start_rate} | ${step_rate}
 525 | | ...         | ${topology_type} | ${min_rate} | ${max_rate}
 526 | | ...         | ${loss_acceptance}=0 | ${loss_acceptance_type}='frames'
 527 | | ${duration}= | Set Variable | 10
 528 | | Set Duration | ${duration}
 529 | | Set Search Rate Boundaries | ${max_rate} | ${min_rate}
 530 | | Set Search Linear Step | ${step_rate}
 531 | | Set Search Frame Size | ${framesize}
 532 | | Set Search Rate Type pps
 533 | | Set Loss Acceptance | ${loss_acceptance}
 534 | | Run Keyword If | '${loss_acceptance_type}' == 'percentage'
 535 | | ...            | Set Loss Acceptance Type Percentage
 536 | | Linear Search | ${start_rate} | ${topology_type}
 537 | | ${rate_per_stream} | ${latency}= | Verify Search Result
 538 | | Display result of PDR search | ${rate_per_stream} | ${framesize} | 2
 539 | | ...                          | ${loss_acceptance} | ${loss_acceptance_type}
 540 | | ...                          | ${latency}
 541 | | Traffic should pass with partial loss | ${duration} | ${rate_per_stream}pps
 542 | | ...                                   | ${framesize} | ${topology_type}
 543 | | ...                                   | ${loss_acceptance}
 544 | | ...                                   | ${loss_acceptance_type}
 545 | | ...                                   | fail_on_loss=${False}
 546
 547 | Find NDR using binary search and pps
 548 | | [Documentation]
 549 | | ... | Find throughput by using RFC2544 binary search with non drop rate.
 550 | | ...
 551 | | ... | *Arguments:*
 552 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 553 | | ... | - binary_min - Lower boundary of search [pps]. Type: float
 554 | | ... | - binary_max - Upper boundary of search [pps]. Type: float
 555 | | ... | - topology_type - Topology type. Type: string
 556 | | ... | - min_rate - Lower limit of search [pps]. Type: float
 557 | | ... | - max_rate - Upper limit of search [pps]. Type: float
 558 | | ... | - threshold - Threshold to stop search [pps]. Type: integer
 559 | | ...
 560 | | ... | *Example:*
 561 | | ...
 562 | | ... | \| Find NDR using binary search and pps \| 64 \| 6000000 \
 563 | | ... | \| 12000000 \| 3-node-IPv4 \| 100000 \| 14880952 \| 50000
 564 | | [Arguments] | ${framesize} | ${binary_min} | ${binary_max}
 565 | | ...         | ${topology_type} | ${min_rate} | ${max_rate} | ${threshold}
 566 | | ${duration}= | Set Variable | 10
 567 | | Set Duration | ${duration}
 568 | | Set Search Rate Boundaries | ${max_rate} | ${min_rate}
 569 | | Set Search Frame Size | ${framesize}
 570 | | Set Search Rate Type pps
 571 | | Set Binary Convergence Threshold | ${threshold}
 572 | | Binary Search | ${binary_min} | ${binary_max} | ${topology_type}
 573 | | ${rate_per_stream} | ${latency}= | Verify Search Result
 574 | | Display result of NDR search | ${rate_per_stream} | ${framesize} | 2
 575 | | ...                          | ${latency}
 576 | | Traffic should pass with no loss | ${duration} | ${rate_per_stream}pps
 577 | | ...                              | ${framesize} | ${topology_type}
 578 | | ...                              | fail_on_loss=${False}
 579
 580 | Find PDR using binary search and pps
 581 | | [Documentation]
 582 | | ... | Find throughput by using RFC2544 binary search with partial drop rate
 583 | | ... | with PDR threshold and type specified by parameter.
 584 | | ...
 585 | | ... | *Arguments:*
 586 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 587 | | ... | - binary_min - Lower boundary of search [pps]. Type: float
 588 | | ... | - binary_max - Upper boundary of search [pps]. Type: float
 589 | | ... | - topology_type - Topology type. Type: string
 590 | | ... | - min_rate - Lower limit of search [pps]. Type: float
 591 | | ... | - max_rate - Upper limit of search [pps]. Type: float
 592 | | ... | - threshold - Threshold to stop search [pps]. Type: integer
 593 | | ... | - loss_acceptance - Accepted loss during search. Type: float
 594 | | ... | - loss_acceptance_type - Percentage or frames. Type: string
 595 | | ...
 596 | | ... | *Example:*
 597 | | ...
 598 | | ... | \| Find PDR using binary search and pps \| 64 \| 6000000 \
 599 | | ... | \| 12000000 \| 3-node-IPv4 \| 100000 \| 14880952 \| 50000 \| 0.5 \
 600 | | ... | \| percentage
 601 | | [Arguments] | ${framesize} | ${binary_min} | ${binary_max}
 602 | | ...         | ${topology_type} | ${min_rate} | ${max_rate} | ${threshold}
 603 | | ...         | ${loss_acceptance}=0 | ${loss_acceptance_type}='frames'
 604 | | ${duration}= | Set Variable | 10
 605 | | Set Duration | ${duration}
 606 | | Set Search Rate Boundaries | ${max_rate} | ${min_rate}
 607 | | Set Search Frame Size | ${framesize}
 608 | | Set Search Rate Type pps
 609 | | Set Loss Acceptance | ${loss_acceptance}
 610 | | Run Keyword If | '${loss_acceptance_type}' == 'percentage'
 611 | | ...            | Set Loss Acceptance Type Percentage
 612 | | Set Binary Convergence Threshold | ${threshold}
 613 | | Binary Search | ${binary_min} | ${binary_max} | ${topology_type}
 614 | | ${rate_per_stream} | ${latency}= | Verify Search Result
 615 | | Display result of PDR search | ${rate_per_stream} | ${framesize} | 2
 616 | | ...                          | ${loss_acceptance} | ${loss_acceptance_type}
 617 | | ...                          | ${latency}
 618 | | Traffic should pass with partial loss | ${duration} | ${rate_per_stream}pps
 619 | | ...                                   | ${framesize} | ${topology_type}
 620 | | ...                                   | ${loss_acceptance}
 621 | | ...                                   | ${loss_acceptance_type}
 622 | | ...                                   | fail_on_loss=${False}
 623
 624 | Find NDR using combined search and pps
 625 | | [Documentation]
 626 | | ... | Find throughput by using RFC2544 combined search (linear+binary) with
 627 | | ... | non drop rate.
 628 | | ...
 629 | | ... | *Arguments:*
 630 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 631 | | ... | - start_rate - Initial start rate [pps]. Type: float
 632 | | ... | - step_rate - Step of linear search [pps]. Type: float
 633 | | ... | - topology_type - Topology type. Type: string
 634 | | ... | - min_rate - Lower limit of search [pps]. Type: float
 635 | | ... | - max_rate - Upper limit of search [pps]. Type: float
 636 | | ... | - threshold - Threshold to stop search [pps]. Type: integer
 637 | | ...
 638 | | ... | *Example:*
 639 | | ...
 640 | | ... | \| Find NDR using combined search and pps \| 64 \| 5000000 \
 641 | | ... | \| 100000 \| 3-node-IPv4 \| 100000 \| 14880952 \| 5000
 642 | | [Arguments] | ${framesize} | ${start_rate} | ${step_rate}
 643 | | ...         | ${topology_type} | ${min_rate} | ${max_rate} | ${threshold}
 644 | | ${duration}= | Set Variable | 10
 645 | | Set Duration | ${duration}
 646 | | Set Search Rate Boundaries | ${max_rate} | ${min_rate}
 647 | | Set Search Linear Step | ${step_rate}
 648 | | Set Search Frame Size | ${framesize}
 649 | | Set Search Rate Type pps
 650 | | Set Binary Convergence Threshold | ${threshold}
 651 | | Combined Search | ${start_rate} | ${topology_type}
 652 | | ${rate_per_stream} | ${latency}= | Verify Search Result
 653 | | Display result of NDR search | ${rate_per_stream} | ${framesize} | 2
 654 | | ...                          | ${latency}
 655 | | Traffic should pass with no loss | ${duration} | ${rate_per_stream}pps
 656 | | ...                              | ${framesize} | ${topology_type}
 657 | | ...                              | fail_on_loss=${False}
 658
 659 | Find PDR using combined search and pps
 660 | | [Documentation]
 661 | | ... | Find throughput by using RFC2544 combined search (linear+binary) with
 662 | | ... | partial drop rate with PDR threshold and type specified by parameter.
 663 | | ...
 664 | | ... | *Arguments:*
 665 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 666 | | ... | - start_rate - Initial start rate [pps]. Type: float
 667 | | ... | - step_rate - Step of linear search [pps]. Type: float
 668 | | ... | - topology_type - Topology type. Type: string
 669 | | ... | - min_rate - Lower limit of search [pps]. Type: float
 670 | | ... | - max_rate - Upper limit of search [pps]. Type: float
 671 | | ... | - threshold - Threshold to stop search [pps]. Type: integer
 672 | | ... | - loss_acceptance - Accepted loss during search. Type: float
 673 | | ... | - loss_acceptance_type - Percentage or frames. Type: string
 674 | | ...
 675 | | ... | *Example:*
 676 | | ...
 677 | | ... | \| Find PDR using combined search and pps \| 64 \| 5000000 \
 678 | | ... | \| 100000 \| 3-node-IPv4 \| 100000 \| 14880952 \| 5000 \| 0.5 \
 679 | | ... | \| percentage
 680 | | [Arguments] | ${framesize} | ${start_rate} | ${step_rate}
 681 | | ...         | ${topology_type} | ${min_rate} | ${max_rate} | ${threshold}
 682 | | ...         | ${loss_acceptance}=0 | ${loss_acceptance_type}='frames'
 683 | | ${duration}= | Set Variable | 10
 684 | | Set Duration | ${duration}
 685 | | Set Search Rate Boundaries | ${max_rate} | ${min_rate}
 686 | | Set Search Linear Step | ${step_rate}
 687 | | Set Search Frame Size | ${framesize}
 688 | | Set Search Rate Type pps
 689 | | Set Loss Acceptance | ${loss_acceptance}
 690 | | Run Keyword If | '${loss_acceptance_type}' == 'percentage'
 691 | | ...            | Set Loss Acceptance Type Percentage
 692 | | Set Binary Convergence Threshold | ${threshold}
 693 | | Combined Search | ${start_rate} | ${topology_type}
 694 | | ${rate_per_stream} | ${latency}= | Verify Search Result
 695 | | Display result of PDR search | ${rate_per_stream} | ${framesize} | 2
 696 | | ...                          | ${loss_acceptance} | ${loss_acceptance_type}
 697 | | ...                          | ${latency}
 698 | | Traffic should pass with partial loss | ${duration} | ${rate_per_stream}pps
 699 | | ...                                   | ${framesize} | ${topology_type}
 700 | | ...                                   | ${loss_acceptance}
 701 | | ...                                   | ${loss_acceptance_type}
 702 | | ...                                   | fail_on_loss=${False}
 703
 704 | Display result of NDR search
 705 | | [Documentation]
 706 | | ... | Display result of NDR search in packet per seconds (total and per
 707 | | ... | stream) and Gbps total bandwidth with untagged packet.
 708 | | ... | Througput is calculated as:
 709 | | ... | Measured rate per stream * Total number of streams
 710 | | ... | Bandwidth is calculated as:
 711 | | ... | (Througput * (L2 Frame Size + IPG) * 8) / Max bitrate of NIC
 712 | | ...
 713 | | ... | *Arguments:*
 714 | | ... | - rate_per_stream - Measured rate per stream [pps]. Type: string
 715 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 716 | | ... | - nr_streams - Total number of streams. Type: integer
 717 | | ... | - latency - Latency stats. Type: dictionary
 718 | | ...
 719 | | ... | *Example:*
 720 | | ...
 721 | | ... | \| Display result of NDR search \| 4400000 \| 64 \| 2 \
 722 | | ... | \| (0, 10/10/10) \|
 723 | | [Arguments] | ${rate_per_stream} | ${framesize} | ${nr_streams}
 724 | | ...         | ${latency}
 725 | | ${framesize}= | Get Frame Size | ${framesize}
 726 | | ${rate_total}= | Evaluate | ${rate_per_stream}*${nr_streams}
 727 | | ${bandwidth_total}= | Evaluate | ${rate_total}*(${framesize}+20)*8/(10**9)
 728 | | Set Test Message | FINAL_RATE: ${rate_total} pps
 729 | | Set Test Message | (${nr_streams}x ${rate_per_stream} pps)
 730 | | ...              | append=yes
 731 | | Set Test Message | ${\n}FINAL_BANDWIDTH: ${bandwidth_total} Gbps (untagged)
 732 | | ...              | append=yes
 733 | | :FOR | ${idx} | ${lat} | IN ENUMERATE | @{latency}
 734 | | | Set Test Message | ${\n}LATENCY_STREAM_${idx}: ${lat} usec (min/avg/max)
 735 | | ...                | append=yes
 736
 737 | Display result of PDR search
 738 | | [Documentation]
 739 | | ... | Display result of PDR search in packet per seconds (total and per
 740 | | ... | stream) and Gbps total bandwidth with untagged packet.
 741 | | ... | Througput is calculated as:
 742 | | ... | Measured rate per stream * Total number of streams
 743 | | ... | Bandwidth is calculated as:
 744 | | ... | (Througput * (L2 Frame Size + IPG) * 8) / Max bitrate of NIC
 745 | | ...
 746 | | ... | *Arguments:*
 747 | | ... | - rate_per_stream - Measured rate per stream [pps]. Type: string
 748 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 749 | | ... | - nr_streams - Total number of streams. Type: integer
 750 | | ... | - loss_acceptance - Accepted loss during search. Type: float
 751 | | ... | - loss_acceptance_type - Percentage or frames. Type: string
 752 | | ... | - latency - Latency stats. Type: dictionary
 753 | | ...
 754 | | ... | *Example:*
 755 | | ...
 756 | | ... | \| Display result of PDR search \| 4400000 \| 64 \| 2 \| 0.5 \
 757 | | ... | \| percentage \| (0, 10/10/10) \|
 758 | | [Arguments] | ${rate_per_stream} | ${framesize} | ${nr_streams}
 759 | | ...         | ${loss_acceptance} | ${loss_acceptance_type} | ${latency}
 760 | | ${framesize}= | Get Frame Size | ${framesize}
 761 | | ${rate_total}= | Evaluate | ${rate_per_stream}*${nr_streams}
 762 | | ${bandwidth_total}= | Evaluate | ${rate_total}*(${framesize}+20)*8/(10**9)
 763 | | Set Test Message | FINAL_RATE: ${rate_total} pps
 764 | | Set Test Message | (${nr_streams}x ${rate_per_stream} pps)
 765 | | ...              | append=yes
 766 | | Set Test Message | ${\n}FINAL_BANDWIDTH: ${bandwidth_total} Gbps (untagged)
 767 | | ...              | append=yes
 768 | | :FOR | ${idx} | ${lat} | IN ENUMERATE | @{latency}
 769 | | | Set Test Message | ${\n}LATENCY_STREAM_${idx}: ${lat} usec (min/avg/max)
 770 | | ...                | append=yes
 771 | | Set Test Message | ${\n}LOSS_ACCEPTANCE: ${loss_acceptance} ${loss_acceptance_type}
 772 | | ...              | append=yes
 773
 774 | Traffic should pass with no loss
 775 | | [Documentation]
 776 | | ... | Send traffic at specified rate. No packet loss is accepted at loss
 777 | | ... | evaluation.
 778 | | ...
 779 | | ... | *Arguments:*
 780 | | ... | - duration - Duration of traffic run [s]. Type: integer
 781 | | ... | - rate - Rate for sending packets. Type: string
 782 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 783 | | ... | - topology_type - Topology type. Type: string
 784 | | ...
 785 | | ... | *Example:*
 786 | | ...
 787 | | ... | \| Traffic should pass with no loss \| 10 \| 4.0mpps \| 64 \
 788 | | ... | \| 3-node-IPv4
 789 | | [Arguments] | ${duration} | ${rate} | ${framesize} | ${topology_type}
 790 | | ...         | ${fail_on_loss}=${True}
 791 | | Clear and show runtime counters with running traffic | ${duration}
 792 | | ...  | ${rate} | ${framesize} | ${topology_type}
 793 | | Clear all counters on all DUTs
 794 | | Send traffic on tg | ${duration} | ${rate} | ${framesize}
 795 | | ...                | ${topology_type} | warmup_time=0
 796 | | Show statistics on all DUTs
 797 | | Run Keyword If | ${fail_on_loss} | No traffic loss occurred
 798
 799 | Traffic should pass with partial loss
 800 | | [Documentation]
 801 | | ... | Send traffic at specified rate. Partial packet loss is accepted
 802 | | ... | within loss acceptance value specified as argument.
 803 | | ...
 804 | | ... | *Arguments:*
 805 | | ... | - duration - Duration of traffic run [s]. Type: integer
 806 | | ... | - rate - Rate for sending packets. Type: string
 807 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 808 | | ... | - topology_type - Topology type. Type: string
 809 | | ... | - loss_acceptance - Accepted loss during search. Type: float
 810 | | ... | - loss_acceptance_type - Percentage or frames. Type: string
 811 | | ...
 812 | | ... | *Example:*
 813 | | ...
 814 | | ... | \| Traffic should pass with partial loss \| 10 \| 4.0mpps \| 64 \
 815 | | ... | \| 3-node-IPv4 \| 0.5 \| percentage
 816 | | [Arguments] | ${duration} | ${rate} | ${framesize} | ${topology_type}
 817 | | ...         | ${loss_acceptance} | ${loss_acceptance_type}
 818 | | ...         | ${fail_on_loss}=${True}
 819 | | Clear and show runtime counters with running traffic | ${duration}
 820 | | ...  | ${rate} | ${framesize} | ${topology_type}
 821 | | Clear all counters on all DUTs
 822 | | Send traffic on tg | ${duration} | ${rate} | ${framesize}
 823 | | ...                | ${topology_type} | warmup_time=0
 824 | | Show statistics on all DUTs
 825 | | Run Keyword If | ${fail_on_loss} | Partial traffic loss accepted
 826 | | ...            | ${loss_acceptance} | ${loss_acceptance_type}
 827
 828 | Clear and show runtime counters with running traffic
 829 | | [Documentation]
 830 | | ... | Start traffic at specified rate then clear runtime counters on all
 831 | | ... | DUTs. Wait for specified amount of time and capture runtime counters
 832 | | ... | on all DUTs. Finally stop traffic
 833 | | ...
 834 | | ... | *Arguments:*
 835 | | ... | - duration - Duration of traffic run [s]. Type: integer
 836 | | ... | - rate - Rate for sending packets. Type: string
 837 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 838 | | ... | - topology_type - Topology type. Type: string
 839 | | ...
 840 | | ... | *Example:*
 841 | | ...
 842 | | ... | \| Traffic should pass with partial loss \| 10 \| 4.0mpps \| 64 \
 843 | | ... | \| 3-node-IPv4 \| 0.5 \| percentage
 844 | | [Arguments] | ${duration} | ${rate} | ${framesize} | ${topology_type}
 845 | | Send traffic on tg | -1 | ${rate} | ${framesize}
 846 | | ...                | ${topology_type} | warmup_time=0 | async_call=${True}
 847 | | ...                | latency=${False}
 848 | | Clear runtime counters on all DUTs
 849 | | Sleep | ${duration}
 850 | | Show runtime counters on all DUTs
 851 | | Stop traffic on tg
 852
 853 | Add PCI devices to DUTs from 3-node single link topology
 854 | | ${dut1_if1_pci}= | Get Interface PCI Addr | ${dut1} | ${dut1_if1}
 855 | | ${dut1_if2_pci}= | Get Interface PCI Addr | ${dut1} | ${dut1_if2}
 856 | | ${dut2_if1_pci}= | Get Interface PCI Addr | ${dut2} | ${dut2_if1}
 857 | | ${dut2_if2_pci}= | Get Interface PCI Addr | ${dut2} | ${dut2_if2}
 858 | | Add PCI device | ${dut1} | ${dut1_if1_pci} | ${dut1_if2_pci}
 859 | | Add PCI device | ${dut2} | ${dut2_if1_pci} | ${dut2_if2_pci}