resources/libraries/robot/performance/performance_setup.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.DUTSetup
  16 | Library | resources.tools.wrk.wrk
  17 | Resource | resources/libraries/robot/performance/performance_configuration.robot
  18 | Resource | resources/libraries/robot/performance/performance_utils.robot
  19 | Resource | resources/libraries/robot/tcp/tcp_setup.robot
  20 | Documentation | Performance suite keywords - Suite and test setups and
  21 | ... | teardowns.
  22
  23 *** Keywords ***
  24
  25 # Keywords used in setups and teardowns
  26
  27 | Set variables in 2-node circular topology
  28 | | [Documentation]
  29 | | ... | Compute path for testing on two given nodes in circular
  30 | | ... | topology and set corresponding suite variables.
  31 | | ...
  32 | | ... | _NOTE:_ This KW sets following suite variables:
  33 | | ... | - tg - TG node
  34 | | ... | - tg_if1 - 1st TG interface towards DUT.
  35 | | ... | - tg_if2 - 2nd TG interface towards DUT.
  36 | | ... | - dut1 - DUT1 node
  37 | | ... | - dut1_if1 - 1st DUT interface towards TG.
  38 | | ... | - dut1_if2 - 2nd DUT interface towards TG.
  39 | | ...
  40 | | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  41 | | Compute Path | always_same_link=${FALSE}
  42 | | ${tg_if1} | ${tg}= | First Interface
  43 | | ${dut1_if1} | ${dut1}= | First Ingress Interface
  44 | | ${dut1_if2} | ${dut1}= | Last Egress Interface
  45 | | ${tg_if2} | ${tg}= | Last Interface
  46 | | Set Suite Variable | ${tg}
  47 | | Set Suite Variable | ${tg_if1}
  48 | | Set Suite Variable | ${tg_if2}
  49 | | Set Suite Variable | ${dut1}
  50 | | Set Suite Variable | ${dut1_if1}
  51 | | Set Suite Variable | ${dut1_if2}
  52
  53 | Set variables in 3-node circular topology
  54 | | [Documentation]
  55 | | ... | Compute path for testing on three given nodes in circular
  56 | | ... | topology and set corresponding suite variables.
  57 | | ...
  58 | | ... | _NOTE:_ This KW sets following suite variables:
  59 | | ... | - tg - TG node
  60 | | ... | - tg_if1 - TG interface towards DUT1.
  61 | | ... | - tg_if2 - TG interface towards DUT2.
  62 | | ... | - dut1 - DUT1 node
  63 | | ... | - dut1_if1 - DUT1 interface towards TG.
  64 | | ... | - dut1_if2 - DUT1 interface towards DUT2.
  65 | | ... | - dut2 - DUT2 node
  66 | | ... | - dut2_if1 - DUT2 interface towards DUT1.
  67 | | ... | - dut2_if2 - DUT2 interface towards TG.
  68 | | ...
  69 | | Append Nodes | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']}
  70 | | ... | ${nodes['TG']}
  71 | | Compute Path
  72 | | ${tg_if1} | ${tg}= | Next Interface
  73 | | ${dut1_if1} | ${dut1}= | Next Interface
  74 | | ${dut1_if2} | ${dut1}= | Next Interface
  75 | | ${dut2_if1} | ${dut2}= | Next Interface
  76 | | ${dut2_if2} | ${dut2}= | Next Interface
  77 | | ${tg_if2} | ${tg}= | Next Interface
  78 | | Set Suite Variable | ${tg}
  79 | | Set Suite Variable | ${tg_if1}
  80 | | Set Suite Variable | ${tg_if2}
  81 | | Set Suite Variable | ${dut1}
  82 | | Set Suite Variable | ${dut1_if1}
  83 | | Set Suite Variable | ${dut1_if2}
  84 | | Set Suite Variable | ${dut2}
  85 | | Set Suite Variable | ${dut2_if1}
  86 | | Set Suite Variable | ${dut2_if2}
  87
  88 | Set variables in 2-node circular topology with DUT interface model
  89 | | [Documentation]
  90 | | ... | Compute path for testing on two given nodes in circular topology
  91 | | ... | based on interface model provided as an argument and set
  92 | | ... | corresponding suite variables.
  93 | | ...
  94 | | ... | *Arguments:*
  95 | | ... | - iface_model - Interface model. Type: string
  96 | | ...
  97 | | ... | _NOTE:_ This KW sets following suite variables:
  98 | | ... | - tg - TG node
  99 | | ... | - tg_if1 - 1st TG interface towards DUT.
 100 | | ... | - tg_if2 - 2nd TG interface towards DUT.
 101 | | ... | - dut1 - DUT1 node
 102 | | ... | - dut1_if1 - 1st DUT interface towards TG.
 103 | | ... | - dut1_if2 - 2nd DUT interface towards TG.
 104 | | ...
 105 | | ... | *Example:*
 106 | | ...
 107 | | ... | \| Set variables in 2-node circular topology with DUT interface model\
 108 | | ... | \| Intel-X520-DA2 \|
 109 | | ...
 110 | | [Arguments] | ${iface_model}
 111 | | ...
 112 | | ${iface_model_list}= | Create list | ${iface_model}
 113 | | Append Node | ${nodes['TG']}
 114 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 115 | | Append Node | ${nodes['TG']}
 116 | | Compute Path | always_same_link=${FALSE}
 117 | | ${tg_if1} | ${tg}= | First Interface
 118 | | ${dut1_if1} | ${dut1}= | First Ingress Interface
 119 | | ${dut1_if2} | ${dut1}= | Last Egress Interface
 120 | | ${tg_if2} | ${tg}= | Last Interface
 121 | | Set Suite Variable | ${tg}
 122 | | Set Suite Variable | ${tg_if1}
 123 | | Set Suite Variable | ${tg_if2}
 124 | | Set Suite Variable | ${dut1}
 125 | | Set Suite Variable | ${dut1_if1}
 126 | | Set Suite Variable | ${dut1_if2}
 127
 128 | Set variables in 3-node circular topology with DUT interface model
 129 | | [Documentation]
 130 | | ... | Compute path for testing on three given nodes in circular topology
 131 | | ... | based on interface model provided as an argument and set
 132 | | ... | corresponding suite variables.
 133 | | ...
 134 | | ... | *Arguments:*
 135 | | ... | - iface_model - Interface model. Type: string
 136 | | ...
 137 | | ... | _NOTE:_ This KW sets following suite variables:
 138 | | ... | - tg - TG node
 139 | | ... | - tg_if1 - TG interface towards DUT1.
 140 | | ... | - tg_if2 - TG interface towards DUT2.
 141 | | ... | - dut1 - DUT1 node
 142 | | ... | - dut1_if1 - DUT1 interface towards TG.
 143 | | ... | - dut1_if2 - DUT1 interface towards DUT2.
 144 | | ... | - dut2 - DUT2 node
 145 | | ... | - dut2_if1 - DUT2 interface towards DUT1.
 146 | | ... | - dut2_if2 - DUT2 interface towards TG.
 147 | | ...
 148 | | ... | *Example:*
 149 | | ...
 150 | | ... | \| Set variables in 3-node circular topology with DUT interface model\
 151 | | ... | \| Intel-X520-DA2 \|
 152 | | ...
 153 | | [Arguments] | ${iface_model}
 154 | | ...
 155 | | ${iface_model_list}= | Create list | ${iface_model}
 156 | | Append Node | ${nodes['TG']}
 157 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 158 | | Append Node | ${nodes['DUT2']} | filter_list=${iface_model_list}
 159 | | Append Node | ${nodes['TG']}
 160 | | Compute Path
 161 | | ${tg_if1} | ${tg}= | Next Interface
 162 | | ${dut1_if1} | ${dut1}= | Next Interface
 163 | | ${dut1_if2} | ${dut1}= | Next Interface
 164 | | ${dut2_if1} | ${dut2}= | Next Interface
 165 | | ${dut2_if2} | ${dut2}= | Next Interface
 166 | | ${tg_if2} | ${tg}= | Next Interface
 167 | | Set Suite Variable | ${tg}
 168 | | Set Suite Variable | ${tg_if1}
 169 | | Set Suite Variable | ${tg_if2}
 170 | | Set Suite Variable | ${dut1}
 171 | | Set Suite Variable | ${dut1_if1}
 172 | | Set Suite Variable | ${dut1_if2}
 173 | | Set Suite Variable | ${dut2}
 174 | | Set Suite Variable | ${dut2_if1}
 175 | | Set Suite Variable | ${dut2_if2}
 176
 177 | Set variables in 3-node circular topology with DUT interface model with double link between DUTs
 178 | | [Documentation]
 179 | | ... | Compute path for testing on three given nodes in circular topology
 180 | | ... | with double link between DUTs based on interface model provided as an
 181 | | ... | argument and set corresponding suite variables.
 182 | | ...
 183 | | ... | *Arguments:*
 184 | | ... | - iface_model - Interface model. Type: string
 185 | | ...
 186 | | ... | _NOTE:_ This KW sets following suite variables:
 187 | | ... | - tg - TG node
 188 | | ... | - tg_if1 - TG interface towards DUT1.
 189 | | ... | - tg_if2 - TG interface towards DUT2.
 190 | | ... | - dut1 - DUT1 node
 191 | | ... | - dut1_if1 - DUT1 interface towards TG.
 192 | | ... | - dut1_if2_1 - DUT1 interface 1 towards DUT2.
 193 | | ... | - dut1_if2_2 - DUT1 interface 2 towards DUT2.
 194 | | ... | - dut2 - DUT2 node
 195 | | ... | - dut2_if1_1 - DUT2 interface 1 towards DUT1.
 196 | | ... | - dut2_if1_2 - DUT2 interface 2 towards DUT1.
 197 | | ... | - dut2_if2 - DUT2 interface towards TG.
 198 | | ...
 199 | | ... | *Example:*
 200 | | ...
 201 | | ... | \| Set variables in 3-node circular topology with DUT interface model\
 202 | | ... | with double link between DUTs \| Intel-X520-DA2 \|
 203 | | ...
 204 | | [Arguments] | ${iface_model}
 205 | | ...
 206 | | ${iface_model_list}= | Create list | ${iface_model}
 207 | | # Compute path TG - DUT1 with single link in between
 208 | | Append Node | ${nodes['TG']}
 209 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 210 | | Append Node | ${nodes['TG']}
 211 | | Compute Path
 212 | | ${tg_if1} | ${tg}= | Next Interface
 213 | | ${dut1_if1} | ${dut1}= | Next Interface
 214 | | # Compute path TG - DUT2 with single link in between
 215 | | Clear Path
 216 | | Append Node | ${nodes['TG']}
 217 | | Append Node | ${nodes['DUT2']} | filter_list=${iface_model_list}
 218 | | Append Node | ${nodes['TG']}
 219 | | Compute Path
 220 | | ${tg_if2} | ${tg}= | Next Interface
 221 | | ${dut2_if2} | ${dut2}= | Next Interface
 222 | | # Compute path DUT1 - DUT2 with double link in between
 223 | | Clear Path
 224 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 225 | | Append Node | ${nodes['DUT2']} | filter_list=${iface_model_list}
 226 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 227 | | Compute Path | always_same_link=${FALSE}
 228 | | ${dut1_if2_1} | ${dut1}= | First Interface
 229 | | ${dut1_if2_2} | ${dut1}= | Last Interface
 230 | | ${dut2_if1_1} | ${dut2}= | First Ingress Interface
 231 | | ${dut2_if1_2} | ${dut2}= | Last Egress Interface
 232 | | # Set suite variables
 233 | | Set Suite Variable | ${tg}
 234 | | Set Suite Variable | ${tg_if1}
 235 | | Set Suite Variable | ${tg_if2}
 236 | | Set Suite Variable | ${dut1}
 237 | | Set Suite Variable | ${dut1_if1}
 238 | | Set Suite Variable | ${dut1_if2_1}
 239 | | Set Suite Variable | ${dut1_if2_2}
 240 | | Set Suite Variable | ${dut2}
 241 | | Set Suite Variable | ${dut2_if1_1}
 242 | | Set Suite Variable | ${dut2_if1_2}
 243 | | Set Suite Variable | ${dut2_if2}
 244
 245 | Tear down guest VM with dpdk-testpmd
 246 | | [Documentation]
 247 | | ... | Stop all qemu processes with dpdk-testpmd running on ${dut_node}.
 248 | | ... | Argument is dictionary of all qemu nodes running with its names.
 249 | | ... | Dpdk-testpmd is stopped gracefully with printing stats.
 250 | | ...
 251 | | ... | *Arguments:*
 252 | | ... | - dut_node - Node where to clean qemu. Type: dictionary
 253 | | ... | - dut_vm_refs - VM references on node. Type: dictionary
 254 | | ...
 255 | | ... | *Example:*
 256 | | ...
 257 | | ... | \| Tear down guest VM with dpdk-testpmd \| ${node['DUT1']} \
 258 | | ... | \| ${dut_vm_refs} \|
 259 | | ...
 260 | | [Arguments] | ${dut_node} | ${dut_vm_refs}
 261 | | ${vms_number}= | Get Length | ${dut_vm_refs}
 262 | | ${index}= | Set Variable | ${0}
 263 | | :FOR | ${vm_name} | IN | @{dut_vm_refs}
 264 | | | ${vm}= | Get From Dictionary | ${dut_vm_refs} | ${vm_name}
 265 | | | ${index}= | Evaluate | ${index} + 1
 266 | | | Dpdk Testpmd Stop | ${vm}
 267 | | | Run Keyword | ${vm_name}.Qemu Set Node | ${dut_node}
 268 | | | Run Keyword | ${vm_name}.Qemu Clear Socks
 269 | | | Run Keyword If | '${index}' == '${vms_number}' | ${vm_name}.Qemu Kill All
 270
 271 | Tear down guest VM
 272 | | [Documentation]
 273 | | ... | Stop all qemu processes running on ${dut_node}.
 274 | | ... | Argument is dictionary of all qemu nodes running with its names.
 275 | | ...
 276 | | ... | *Arguments:*
 277 | | ... | - dut_node - Node where to clean qemu. Type: dictionary
 278 | | ... | - dut_vm_refs - VM references on node. Type: dictionary
 279 | | ...
 280 | | ... | *Example:*
 281 | | ...
 282 | | ... | \| Tear down guest VM \| ${node['DUT1']} \
 283 | | ... | \| ${dut_vm_refs} \|
 284 | | ...
 285 | | [Arguments] | ${dut_node} | ${dut_vm_refs}
 286 | | ${vms_number}= | Get Length | ${dut_vm_refs}
 287 | | ${index}= | Set Variable | ${0}
 288 | | :FOR | ${vm_name} | IN | @{dut_vm_refs}
 289 | | | ${vm}= | Get From Dictionary | ${dut_vm_refs} | ${vm_name}
 290 | | | ${index}= | Evaluate | ${index} + 1
 291 | | | Run Keyword | ${vm_name}.Qemu Set Node | ${dut_node}
 292 | | | Run Keyword | ${vm_name}.Qemu Clear Socks
 293 | | | Run Keyword If | '${index}' == '${vms_number}' | ${vm_name}.Qemu Kill All
 294
 295 # Suite setups
 296
 297 | Set up 2-node performance topology with DUT's NIC model
 298 | | [Documentation]
 299 | | ... | Suite preparation phase that sets the default startup configuration of
 300 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 301 | | ... | variables used in test cases based on interface model provided as an
 302 | | ... | argument. Initializes traffic generator.
 303 | | ...
 304 | | ... | *Arguments:*
 305 | | ... | - topology_type - Topology type. Type: string
 306 | | ... | - nic_model - Interface model. Type: string
 307 | | ...
 308 | | ... | *Example:*
 309 | | ...
 310 | | ... | \| 2-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \|
 311 | | ...
 312 | | [Arguments] | ${topology_type} | ${nic_model}
 313 | | ...
 314 | | Set variables in 2-node circular topology with DUT interface model
 315 | | ... | ${nic_model}
 316 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 317 | | ... | ${dut1} | ${dut1_if1} | ${dut1} | ${dut1_if2} | ${topology_type}
 318
 319 | Set up 2-node-switched performance topology with DUT's NIC model
 320 | | [Documentation]
 321 | | ... | Suite preparation phase that sets the default startup configuration of
 322 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 323 | | ... | variables used in test cases based on interface model provided as an
 324 | | ... | argument. Initializes traffic generator.
 325 | | ...
 326 | | ... | *Arguments:*
 327 | | ... | - topology_type - Topology type. Type: string
 328 | | ... | - nic_model - Interface model. Type: string
 329 | | ... | - tg_if1_dest_mac - Interface 1 destination MAC address. Type: string
 330 | | ... | - tg_if2_dest_mac - Interface 2 destination MAC address. Type: string
 331 | | ...
 332 | | ... | *Example:*
 333 | | ...
 334 | | ... | \| 2-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \
 335 | | ... | \| 22:22:33:44:55:66 \| 22:22:33:44:55:55 \|
 336 | | ...
 337 | | [Arguments] | ${topology_type} | ${nic_model} | ${tg_if1_dest_mac}
 338 | | ... | ${tg_if2_dest_mac}
 339 | | ...
 340 | | Set variables in 2-node circular topology with DUT interface model
 341 | | ... | ${nic_model}
 342 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 343 | | ... | ${dut1} | ${dut1_if1} | ${dut1} | ${dut1_if2} | ${topology_type}
 344 | | ... | ${tg_if1_dest_mac} | ${tg_if2_dest_mac}
 345
 346 | Set up 3-node performance topology with DUT's NIC model
 347 | | [Documentation]
 348 | | ... | Suite preparation phase that sets the default startup configuration of
 349 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 350 | | ... | variables used in test cases based on interface model provided as an
 351 | | ... | argument. Initializes traffic generator.
 352 | | ...
 353 | | ... | *Arguments:*
 354 | | ... | - topology_type - Topology type. Type: string
 355 | | ... | - nic_model - Interface model. Type: string
 356 | | ...
 357 | | ... | *Example:*
 358 | | ...
 359 | | ... | \| Set up 3-node performance topology with DUT's NIC model \| L2 \
 360 | | ... | \| Intel-X520-DA2 \|
 361 | | ...
 362 | | [Arguments] | ${topology_type} | ${nic_model}
 363 | | ...
 364 | | Set variables in 3-node circular topology with DUT interface model
 365 | | ... | ${nic_model}
 366 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 367 | | ... | ${dut1} | ${dut1_if1} | ${dut2} | ${dut2_if2} | ${topology_type}
 368
 369 | Set up 3-node performance topology with DUT's NIC model with double link between DUTs
 370 | | [Documentation]
 371 | | ... | Suite preparation phase that sets the default startup configuration of
 372 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 373 | | ... | variables used in test cases based on interface model provided as an
 374 | | ... | argument. Initializes traffic generator.
 375 | | ...
 376 | | ... | *Arguments:*
 377 | | ... | - topology_type - Topology type. Type: string
 378 | | ... | - nic_model - Interface model. Type: string
 379 | | ...
 380 | | ... | *Example:*
 381 | | ...
 382 | | ... | \| Set up 3-node performance topology with DUT's NIC model with \
 383 | | ... | double link between DUTs \| L2 \| Intel-X520-DA2 \|
 384 | | ...
 385 | | [Arguments] | ${topology_type} | ${nic_model}
 386 | | ...
 387 | | Set variables in 3-node circular topology with DUT interface model with double link between DUTs
 388 | | ... | ${nic_model}
 389 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 390 | | ... | ${dut1} | ${dut1_if1} | ${dut2} | ${dut2_if2} | ${topology_type}
 391
 392 | Set up DPDK 2-node performance topology with DUT's NIC model
 393 | | [Documentation]
 394 | | ... | Updates interfaces on all nodes and sets the global
 395 | | ... | variables used in test cases based on interface model provided as an
 396 | | ... | argument. Initializes traffic generator. Initializes DPDK test
 397 | | ... | environment.
 398 | | ...
 399 | | ... | *Arguments:*
 400 | | ... | - topology_type - Topology type. Type: string
 401 | | ... | - nic_model - Interface model. Type: string
 402 | | ...
 403 | | ... | *Example:*
 404 | | ...
 405 | | ... | \| Set up DPDK 2-node performance topology with DUT's NIC model \
 406 | | ... | \| L2 \| Intel-X520-DA2 \|
 407 | | ...
 408 | | [Arguments] | ${topology_type} | ${nic_model}
 409 | | ...
 410 | | Set variables in 2-node circular topology with DUT interface model
 411 | | ... | ${nic_model}
 412 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 413 | | ... | ${dut1} | ${dut1_if1} | ${dut1} | ${dut1_if2} | ${topology_type}
 414 | | Initialize DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 415
 416 | Set up DPDK 3-node performance topology with DUT's NIC model
 417 | | [Documentation]
 418 | | ... | Updates interfaces on all nodes and sets the global
 419 | | ... | variables used in test cases based on interface model provided as an
 420 | | ... | argument. Initializes traffic generator. Initializes DPDK test
 421 | | ... | environment.
 422 | | ...
 423 | | ... | *Arguments:*
 424 | | ... | - topology_type - Topology type. Type: string
 425 | | ... | - nic_model - Interface model. Type: string
 426 | | ...
 427 | | ... | *Example:*
 428 | | ...
 429 | | ... | \| 3-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \|
 430 | | ...
 431 | | [Arguments] | ${topology_type} | ${nic_model}
 432 | | ...
 433 | | Set variables in 3-node circular topology with DUT interface model
 434 | | ... | ${nic_model}
 435 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 436 | | ... | ${dut1} | ${dut1_if1} | ${dut2} | ${dut2_if2} | ${topology_type}
 437 | | Initialize DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 438 | | Initialize DPDK Environment | ${dut2} | ${dut2_if1} | ${dut2_if2}
 439
 440 | Set up IPSec performance test suite
 441 | | [Documentation]
 442 | | ... | Suite preparation phase that sets default startup configuration of
 443 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets global
 444 | | ... | variables used in test cases based on interface model provided as an
 445 | | ... | argument. Initializes traffic generator.
 446 | | ... | Then it configures crypto device and kernel module on all DUTs.
 447 | | ...
 448 | | ... | *Arguments:*
 449 | | ... | - topology_type - Topology type. Type: string
 450 | | ... | - nic_model - Interface model. Type: string
 451 | | ... | - crypto_type - Crypto device type - HW_cryptodev or SW_cryptodev
 452 | | ... | (Optional). Type: string, default value: HW_cryptodev
 453 | | ...
 454 | | ... | *Example:*
 455 | | ...
 456 | | ... | \| Set up IPSec performance test suite \| L2 \
 457 | | ... | \| Intel-X520-DA2 \|
 458 | | ...
 459 | | [Arguments] | ${topology_type} | ${nic_model} | ${crypto_type}=HW_cryptodev
 460 | | ...
 461 | | Set up 3-node performance topology with DUT's NIC model
 462 | | ... | ${topology_type} | ${nic_model}
 463 | | ${numvfs}= | Set Variable If
 464 | | ... | '${crypto_type}' == 'HW_cryptodev' | ${32}
 465 | | ... | '${crypto_type}' == 'SW_cryptodev' | ${0}
 466 | | Configure crypto device on all DUTs | force_init=${True} | numvfs=${numvfs}
 467 | | Run Keyword If | '${crypto_type}' == 'HW_cryptodev'
 468 | | ... | Configure kernel module on all DUTs | igb_uio | force_load=${True}
 469
 470 | Set up performance topology with containers
 471 | | [Documentation]
 472 | | ... | Suite preparation phase that starts containers
 473 | | ...
 474 | | Set Suite Variable | @{container_groups} | @{EMPTY}
 475 | | Construct VNF containers on all DUTs
 476 | | Acquire all 'VNF' containers
 477 | | Create all 'VNF' containers
 478 | | Configure VPP in all 'VNF' containers
 479 | | Install VPP in all 'VNF' containers
 480
 481 | Set up performance test suite with MEMIF
 482 | | [Documentation]
 483 | | ... | Append memif_plugin.so to the list of enabled plugins.
 484 | | ...
 485 | | Set Suite Variable | @{plugins_to_enable}
 486 | | Append To List | ${plugins_to_enable} | memif_plugin.so
 487
 488 | Set up performance test suite with NAT
 489 | | [Documentation]
 490 | | ... | Append nat_plugin.so to the list of enabled plugins.
 491 | | ...
 492 | | Set Suite Variable | @{plugins_to_enable}
 493 | | Append To List | ${plugins_to_enable} | nat_plugin.so
 494
 495 | Set up performance test suite with ACL
 496 | | [Documentation]
 497 | | ... | Append acl_plugin.so to the list of enabled plugins.
 498 | | ...
 499 | | Set Suite Variable | @{plugins_to_enable}
 500 | | Append To List | ${plugins_to_enable} | acl_plugin.so
 501
 502 | Set up performance test suite with Static SRv6 proxy
 503 | | [Documentation]
 504 | | ... | Append srv6as_plugin.so to the list of enabled plugins.
 505 | | ...
 506 | | Set Suite Variable | @{plugins_to_enable}
 507 | | Append To List | ${plugins_to_enable} | srv6as_plugin.so
 508
 509 | Set up performance test suite with Dynamic SRv6 proxy
 510 | | [Documentation]
 511 | | ... | Append srv6ad_plugin.so to the list of enabled plugins.
 512 | | ...
 513 | | Set Suite Variable | @{plugins_to_enable}
 514 | | Append To List | ${plugins_to_enable} | srv6ad_plugin.so
 515
 516 | Set up performance test suite with Masquerading SRv6 proxy
 517 | | [Documentation]
 518 | | ... | Append srv6am_plugin.so to the list of enabled plugins.
 519 | | ...
 520 | | Set Suite Variable | @{plugins_to_enable}
 521 | | Append To List | ${plugins_to_enable} | srv6am_plugin.so
 522
 523 | Set up performance test suite with LACP mode link bonding
 524 | | [Documentation]
 525 | | ... | Append lacp_plugin.so to the list of enabled plugins.
 526 | | ...
 527 | | Set Suite Variable | @{plugins_to_enable}
 528 | | Append To List | ${plugins_to_enable} | lacp_plugin.so
 529
 530 | Set up 3-node performance topology with wrk and DUT's NIC model
 531 | | [Documentation]
 532 | | ... | Suite preparation phase that sets the default startup configuration of
 533 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 534 | | ... | variables used in test cases based on interface model provided as an
 535 | | ... | argument. Installs the traffic generator.
 536 | | ...
 537 | | ... | *Arguments:*
 538 | | ... | - iface_model - Interface model. Type: string
 539 | | ...
 540 | | ... | *Example:*
 541 | | ...
 542 | | ... | \| Set up 3-node performance topology with wrk and DUT's NIC model\
 543 | | ... | \| Intel-X520-DA2 \|
 544 | | ...
 545 | | [Arguments] | ${iface_model}
 546 | | ...
 547 | | Set variables in 3-node circular topology with DUT interface model
 548 | | ... | ${iface_model}
 549 | | Iface update numa node | ${tg}
 550 # Make sure TRex is stopped
 551 | | ${running}= | Is TRex running | ${tg}
 552 | | Run keyword if | ${running}==${True} | Teardown traffic generator | ${tg}
 553 | | ${curr_driver}= | Get PCI dev driver | ${tg}
 554 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']}
 555 | | Run keyword if | '${curr_driver}'!='${None}'
 556 | | ... | PCI Driver Unbind | ${tg} |
 557 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']}
 558 # Bind tg_if1 to driver specified in the topology
 559 | | ${driver}= | Get Variable Value | ${tg['interfaces']['${tg_if1}']['driver']}
 560 | | PCI Driver Bind | ${tg}
 561 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']} | ${driver}
 562 # Set IP on tg_if1
 563 | | ${intf_name}= | Get Linux interface name | ${tg}
 564 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']}
 565 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.10.1 | 24
 566 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.20.1 | 24
 567 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.30.1 | 24
 568 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.40.1 | 24
 569 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.50.1 | 24
 570 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.60.1 | 24
 571 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.70.1 | 24
 572 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.80.1 | 24
 573 | | Set Linux interface up | ${tg} | ${intf_name}
 574 | | Install wrk | ${tg}
 575
 576 # Suite teardowns
 577
 578 | Tear down 2-node performance topology
 579 | | [Documentation]
 580 | | ... | Suite teardown phase with traffic generator teardown.
 581 | | ...
 582 | | Teardown traffic generator | ${tg}
 583
 584 | Tear down 2-node performance topology with container
 585 | | [Documentation]
 586 | | ... | Suite teardown phase with traffic generator teardown and container
 587 | | ... | destroy.
 588 | | ...
 589 | | Teardown traffic generator | ${tg}
 590 | | :FOR | ${group} | IN | @{container_groups}
 591 | | | Destroy all '${group}' containers
 592
 593 | Tear down 3-node performance topology
 594 | | [Documentation]
 595 | | ... | Suite teardown phase with traffic generator teardown.
 596 | | ...
 597 | | Teardown traffic generator | ${tg}
 598
 599 | Tear down 3-node performance topology with container
 600 | | [Documentation]
 601 | | ... | Suite teardown phase with traffic generator teardown and container
 602 | | ... | destroy.
 603 | | ...
 604 | | Teardown traffic generator | ${tg}
 605 | | :FOR | ${group} | IN | @{container_groups}
 606 | | | Destroy all '${group}' containers
 607
 608 # Tests setups
 609
 610 | Set up performance test
 611 | | [Documentation] | Common test setup for performance tests.
 612 | | ...
 613 | | Reset VAT History On All DUTs | ${nodes}
 614 | | Create base startup configuration of VPP on all DUTs
 615
 616 | Set up tcp performance test
 617 | | [Documentation] | Common test setup for TCP performance tests.
 618 | | ...
 619 | | Reset VAT History On All DUTs | ${nodes}
 620 | | Create base startup configuration of VPP for TCP tests on all DUTs
 621
 622 | Set up performance test with Ligato Kubernetes
 623 | | [Documentation] | Common test setup for performance tests with Ligato \
 624 | | ... | Kubernetes.
 625 | | ...
 626 | | Apply Kubernetes resource on all duts | ${nodes} | namespaces/csit.yaml
 627 | | Apply Kubernetes resource on all duts | ${nodes} | pods/kafka.yaml
 628 | | Apply Kubernetes resource on all duts | ${nodes} | pods/etcdv3.yaml
 629 | | Apply Kubernetes resource on all duts | ${nodes}
 630 | | ... | configmaps/vswitch-agent-cfg.yaml
 631 | | Apply Kubernetes resource on all duts | ${nodes}
 632 | | ... | configmaps/vnf-agent-cfg.yaml
 633 | | Apply Kubernetes resource on all duts | ${nodes}
 634 | | ... | pods/contiv-sfc-controller.yaml
 635 | | Apply Kubernetes resource on all duts | ${nodes}
 636 | | ... | pods/contiv-vswitch.yaml
 637
 638 # Tests teardowns
 639
 640 | Tear down performance discovery test
 641 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 642 | | ... | tests.
 643 | | ...
 644 | | ... | *Arguments:*
 645 | | ... | - rate - Rate for sending packets. Type: string
 646 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 647 | | ... | - topology_type - Topology type. Type: string
 648 | | ...
 649 | | ... | *Example:*
 650 | | ...
 651 | | ... | \| Tear down performance discovery test \| 4.0mpps \| 64 \
 652 | | ... | \| 3-node-IPv4 \|
 653 | | ...
 654 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 655 | | ...
 656 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 657 | | Show VAT History On All DUTs | ${nodes}
 658 | | Run Keyword If Test Failed
 659 | | ... | Set Test Variable | ${pkt_trace} | ${True}
 660 | | Run Keyword If Test Failed
 661 | | ... | Traffic should pass with no loss | ${perf_trial_duration} | ${rate}
 662 | | ... | ${framesize} | ${topology_type} | fail_on_loss=${False}
 663
 664 | Tear down performance ndrchk test
 665 | | [Documentation] | Common test teardown for ndrchk performance tests.
 666 | | ...
 667 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 668 | | Show VAT History On All DUTs | ${nodes}
 669
 670 | Tear down performance pdrchk test
 671 | | [Documentation] | Common test teardown for pdrchk performance tests.
 672 | | ...
 673 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 674 | | Show VAT History On All DUTs | ${nodes}
 675
 676 | Tear down performance mrr test
 677 | | [Documentation] | Common test teardown for max-received-rate performance
 678 | | ... | tests.
 679 | | ...
 680 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 681 | | Show VAT History On All DUTs | ${nodes}
 682
 683 | Tear down performance test with wrk
 684 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 685 | | ... | tests.
 686 | | ...
 687 | | ... | *Example:*
 688 | | ...
 689 | | ... | \| Tear down performance test with wrk \|
 690 | | ...
 691 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 692 | | Show VAT History On All DUTs | ${nodes}
 693 | | Show statistics on all DUTs | ${nodes}
 694
 695 | Tear down performance test with vhost and VM with dpdk-testpmd
 696 | | [Documentation] | Common test teardown for performance tests which use
 697 | | ... | vhost(s) and VM(s) with dpdk-testpmd.
 698 | | ...
 699 | | ... | *Arguments:*
 700 | | ... | - rate - Rate for sending packets. Type: string
 701 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 702 | | ... | - topology_type - Topology type. Type: string
 703 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 704 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 705 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 706 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 707 | | ...
 708 | | ... | *Example:*
 709 | | ...
 710 | | ... | \| Tear down performance test with vhost and VM with dpdk-testpmd \
 711 | | ... | \| 4.0mpps \| 64 \| 3-node-IPv4 \| ${node['DUT1']} \| ${dut_vm_refs} \
 712 | | ... | \| ${node['DUT2']} \| ${dut_vm_refs} \|
 713 | | ...
 714 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 715 | | ... | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 716 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 717 | | ...
 718 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 719 | | Show VAT History On All DUTs | ${nodes}
 720 | | Show VPP vhost on all DUTs | ${nodes}
 721 | | Show statistics on all DUTs | ${nodes}
 722 | | Run Keyword If Test Failed
 723 | | ... | Traffic should pass with no loss | ${perf_trial_duration} | ${rate}
 724 | | ... | ${framesize} | ${topology_type} | fail_on_loss=${False}
 725 | | Run keyword unless | ${dut1_node}==${None}
 726 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 727 | | Run keyword unless | ${dut2_node}==${None}
 728 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 729
 730 | Tear down mrr test with vhost and VM with dpdk-testpmd
 731 | | [Documentation] | Common test teardown for mrr tests which use
 732 | | ... | vhost(s) and VM(s) with dpdk-testpmd.
 733 | | ...
 734 | | ... | *Arguments:*
 735 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 736 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 737 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 738 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 739 | | ...
 740 | | ... | *Example:*
 741 | | ...
 742 | | ... | \| Tear down performance test with vhost and VM with dpdk-testpmd \
 743 | | ... | \| ${node['DUT1']} \| ${dut_vm_refs} \
 744 | | ... | \| ${node['DUT2']} \| ${dut_vm_refs} \|
 745 | | ...
 746 | | [Arguments] | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 747 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 748 | | ...
 749 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 750 | | Show VAT History On All DUTs | ${nodes}
 751 | | Show VPP vhost on all DUTs | ${nodes}
 752 | | Show statistics on all DUTs | ${nodes}
 753 | | Run keyword unless | ${dut1_node}==${None}
 754 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 755 | | Run keyword unless | ${dut2_node}==${None}
 756 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 757
 758 | Tear down performance test with vhost and VM with dpdk-testpmd and ACL
 759 | | [Documentation] | Common test teardown for performance tests which use
 760 | | ... | vhost(s) and VM(s) with ACL and dpdk-testpmd.
 761 | | ...
 762 | | ... | *Arguments:*
 763 | | ... | - rate - Rate for sending packets. Type: string
 764 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 765 | | ... | - topology_type - Topology type. Type: string
 766 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 767 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 768 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 769 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 770 | | ...
 771 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 772 | | ... | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 773 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 774 | | ...
 775 | | Tear down performance test with vhost and VM with dpdk-testpmd
 776 | | ... | ${rate} | ${framesize} | ${topology_type}
 777 | | ... | ${dut1_node} | ${dut1_vm_refs}
 778 | | ... | ${dut2_node} | ${dut2_vm_refs}
 779 | | Vpp Log Plugin Acl Settings | ${dut1}
 780 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 781 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 782
 783 | Tear down mrr test with vhost and VM with dpdk-testpmd and ACL
 784 | | [Documentation] | Common test teardown for mrr tests which use
 785 | | ... | vhost(s) and VM(s) with ACL and dpdk-testpmd.
 786 | | ...
 787 | | ... | *Arguments:*
 788 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 789 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 790 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 791 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 792 | | ...
 793 | | [Arguments] | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 794 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 795 | | ...
 796 | | Tear down mrr test with vhost and VM with dpdk-testpmd
 797 | | ... | ${dut1_node} | ${dut1_vm_refs}
 798 | | ... | ${dut2_node} | ${dut2_vm_refs}
 799 | | Vpp Log Plugin Acl Settings | ${dut1}
 800 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 801 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 802
 803 | Tear down performance pdrchk test with vhost and VM with dpdk-testpmd
 804 | | [Documentation] | Common test teardown for performance pdrchk tests which \
 805 | | ... | use vhost(s) and VM(s) with dpdk-testpmd.
 806 | | ...
 807 | | ... | *Arguments:*
 808 | | ... | - rate - Rate for sending packets. Type: string
 809 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 810 | | ... | - topology_type - Topology type. Type: string
 811 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 812 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 813 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 814 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 815 | | ...
 816 | | ... | *Example:*
 817 | | ...
 818 | | ... | \| Tear down performance pdrchk test with vhost and VM with \
 819 | | ... | dpdk-testpmd \| 4.0mpps \| 64 \| 3-node-IPv4 \| ${node['DUT1']} \
 820 | | ... | \| ${dut_vm_refs} \| ${node['DUT2']} \| ${dut_vm_refs} \|
 821 | | ...
 822 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 823 | | ... | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 824 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 825 | | ...
 826 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 827 | | Show VAT History On All DUTs | ${nodes}
 828 | | Show VPP vhost on all DUTs | ${nodes}
 829 | | Show statistics on all DUTs | ${nodes}
 830 | | Run keyword unless | ${dut1_node}==${None}
 831 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 832 | | Run keyword unless | ${dut2_node}==${None}
 833 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 834
 835 | Tear down performance mrr test with vhost and VM with dpdk-testpmd
 836 | | [Documentation] | Common test teardown for performance mrr tests which \
 837 | | ... | use vhost(s) and VM(s) with dpdk-testpmd.
 838 | | ...
 839 | | ... | *Arguments:*
 840 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 841 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 842 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 843 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 844 | | ...
 845 | | ... | *Example:*
 846 | | ...
 847 | | ... | \| Tear down performance mrr test with vhost and VM with \
 848 | | ... | dpdk-testpmd \| ${node['DUT1']} \| ${dut_vm_refs} \| ${node['DUT2']} \
 849 | | ... | \| ${dut_vm_refs} \|
 850 | | ...
 851 | | [Arguments] | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 852 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 853 | | ...
 854 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 855 | | Show VAT History On All DUTs | ${nodes}
 856 | | Show VPP vhost on all DUTs | ${nodes}
 857 | | Run keyword unless | ${dut1_node}==${None}
 858 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 859 | | Run keyword unless | ${dut2_node}==${None}
 860 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 861
 862 | Tear down DPDK 2-node performance topology
 863 | | [Documentation]
 864 | | ... | Suite teardown phase with traffic generator teardown.
 865 | | ... | Cleanup DPDK test environment.
 866 | | ...
 867 | | Teardown traffic generator | ${tg}
 868 | | Cleanup DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 869
 870 | Tear down DPDK 3-node performance topology
 871 | | [Documentation]
 872 | | ... | Suite teardown phase with traffic generator teardown.
 873 | | ... | Cleanup DPDK test environment.
 874 | | ...
 875 | | Teardown traffic generator | ${tg}
 876 | | Cleanup DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 877 | | Cleanup DPDK Environment | ${dut2} | ${dut2_if1} | ${dut2_if2}
 878
 879 | Tear down performance discovery test with NAT
 880 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 881 | | ... | tests with NAT feature used.
 882 | | ...
 883 | | ... | *Arguments:*
 884 | | ... | - rate - Rate for sending packets. Type: string
 885 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 886 | | ... | - traffic_profile - Traffic profile. Type: string
 887 | | ...
 888 | | ... | *Example:*
 889 | | ...
 890 | | ... | \| Tear down performance discovery test with NAT \| 100000pps \| 64 \
 891 | | ... | \| ${traffic_profile} \|
 892 | | ...
 893 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
 894 | | ...
 895 | | Tear down performance discovery test | ${rate} | ${framesize}
 896 | | ... | ${traffic_profile}
 897 | | Show NAT verbose | ${dut1}
 898 | | Show NAT verbose | ${dut2}
 899
 900 | Tear down mrr test with NAT
 901 | | [Documentation] | Common test teardown for mrr performance \
 902 | | ... | tests with NAT feature used.
 903 | | ...
 904 | | ... | \| Tear down mrr test with NAT \|
 905 | | ...
 906 | | Tear down performance mrr test
 907 | | Show NAT verbose | ${dut1}
 908 | | Show NAT verbose | ${dut2}
 909
 910 | Tear down performance test with ACL
 911 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 912 | | ... | tests with ACL feature used.
 913 | | ...
 914 | | ... | *Arguments:*
 915 | | ... | - rate - Rate for sending packets. Type: string
 916 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 917 | | ... | - traffic_profile - Traffic profile. Type: string
 918 | | ...
 919 | | ... | *Example:*
 920 | | ...
 921 | | ... | \| Tear down performance test with ACL \| 100000pps \| 64 \
 922 | | ... | \| ${traffic_profile} \|
 923 | | ...
 924 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
 925 | | ...
 926 | | Tear down performance discovery test | ${rate} | ${framesize}
 927 | | ... | ${traffic_profile}
 928 | | Vpp Log Plugin Acl Settings | ${dut1}
 929 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 930 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 931
 932 | Tear down mrr test with ACL
 933 | | [Documentation] | Common test teardown for mrr performance \
 934 | | ... | tests with ACL feature used.
 935 | | ...
 936 | | ... | *Example:*
 937 | | ...
 938 | | ... | \| Tear down mrr test with ACL \|
 939 | | ...
 940 | | Tear down performance mrr test
 941 | | Vpp Log Plugin Acl Settings | ${dut1}
 942 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 943 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 944
 945 | Tear down performance test with MACIP ACL
 946 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 947 | | ... | tests with MACIP ACL feature used.
 948 | | ...
 949 | | ... | *Arguments:*
 950 | | ... | - rate - Rate for sending packets. Type: string
 951 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 952 | | ... | - traffic_profile - Traffic profile. Type: string
 953 | | ...
 954 | | ... | *Example:*
 955 | | ...
 956 | | ... | \| Tear down performance test with MACIP ACL \| 100000pps \| 64 \
 957 | | ... | \| ${traffic_profile} \|
 958 | | ...
 959 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
 960 | | ...
 961 | | Tear down performance discovery test | ${rate} | ${framesize}
 962 | | ... | ${traffic_profile}
 963 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 964 | | ... | Vpp Log Macip Acl Settings | ${dut1}
 965 | | Run Keyword And Ignore Error
 966 | | ... | Vpp Log Macip Acl Interface Assignment | ${dut1}
 967
 968 | Tear down mrr test with MACIP ACL
 969 | | [Documentation] | Common test teardown for mrr performance \
 970 | | ... | tests with MACIP ACL feature used.
 971 | | ...
 972 | | ... | *Example:*
 973 | | ...
 974 | | ... | \| Tear down mrr test with MACIP ACL \|
 975 | | ...
 976 | | Tear down performance mrr test
 977 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 978 | | ... | Vpp Log Macip Acl Settings | ${dut1}
 979 | | Run Keyword And Ignore Error
 980 | | ... | Vpp Log Macip Acl Interface Assignment | ${dut1}
 981
 982 | Tear down performance test with Ligato Kubernetes
 983 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 984 | | ... | tests with Ligato Kubernetes.
 985 | | ...
 986 | | Run Keyword If Test Failed
 987 | | ... | Get Kubernetes logs on all DUTs | ${nodes} | csit
 988 | | Run Keyword If Test Failed
 989 | | ... | Describe Kubernetes resource on all DUTs | ${nodes} | csit
 990 | | Delete Kubernetes resource on all DUTs | ${nodes} | csit
 991
 992 | Tear down performance test with SRv6 with encapsulation
 993 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 994 | | ... | tests with SRv6 with encapsulation feature used.
 995 | | ...
 996 | | ... | *Arguments:*
 997 | | ... | - rate - Rate for sending packets. Type: string
 998 | | ... | - framesize - L2 Frame Size [B]. Type: integer/string
 999 | | ... | - traffic_profile - Traffic profile. Type: string
1000 | | ...
1001 | | ... | *Example:*
1002 | | ...
1003 | | ... | \| Tear down performance test with SRv6 with encapsulation \
1004 | | ... | \| 100000pps \| 64 \| ${traffic_profile} \|
1005 | | ...
1006 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
1007 | | ...
1008 | | Tear down performance discovery test | ${rate} | ${framesize}
1009 | | ... | ${traffic_profile}
1010 | | Run Keyword If Test Failed | Show SR Policies on all DUTs | ${nodes}
1011 | | Run Keyword If Test Failed
1012 | | ... | Show SR Steering Policies on all DUTs | ${nodes}
1013 | | Run Keyword If Test Failed | Show SR LocalSIDs on all DUTs | ${nodes}
1014
1015 | Tear down mrr test with SRv6 with encapsulation
1016 | | [Documentation] | Common test teardown for mrr tests with SRv6 with \
1017 | | ... | encapsulation feature used.
1018 | | ...
1019 | | ... | *Example:*
1020 | | ...
1021 | | ... | \| Tear down mrr test with SRv6 with encapsulation \|
1022 | | ...
1023 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
1024 | | Show VAT History On All DUTs | ${nodes}
1025 | | Run Keyword If Test Failed | Show SR Policies on all DUTs | ${nodes}
1026 | | Run Keyword If Test Failed
1027 | | ... | Show SR Steering Policies on all DUTs | ${nodes}
1028 | | Run Keyword If Test Failed | Show SR LocalSIDs on all DUTs | ${nodes}