resources/libraries/robot/performance/performance_setup.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.DUTSetup
  16 | Library | resources.tools.wrk.wrk
  17 | Resource | resources/libraries/robot/performance/performance_configuration.robot
  18 | Resource | resources/libraries/robot/performance/performance_utils.robot
  19 | Resource | resources/libraries/robot/tcp/tcp_setup.robot
  20 | Documentation | Performance suite keywords - Suite and test setups and
  21 | ... | teardowns.
  22
  23 *** Keywords ***
  24
  25 # Keywords used in setups and teardowns
  26
  27 | Set variables in 2-node circular topology with DUT interface model
  28 | | [Documentation]
  29 | | ... | Compute path for testing on two given nodes in circular topology
  30 | | ... | based on interface model provided as an argument and set
  31 | | ... | corresponding suite variables.
  32 | | ...
  33 | | ... | *Arguments:*
  34 | | ... | - iface_model - Interface model. Type: string
  35 | | ...
  36 | | ... | _NOTE:_ This KW sets following suite variables:
  37 | | ... | - tg - TG node
  38 | | ... | - tg_if1 - 1st TG interface towards DUT.
  39 | | ... | - tg_if1 - 1st TG interface MAC address.
  40 | | ... | - tg_if2 - 2nd TG interface towards DUT.
  41 | | ... | - tg_if2 - 2nd TG interface MAC address.
  42 | | ... | - dut1 - DUT1 node
  43 | | ... | - dut1_if1 - 1st DUT interface towards TG.
  44 | | ... | - dut1_if2 - 2nd DUT interface towards TG.
  45 | | ...
  46 | | ... | *Example:*
  47 | | ...
  48 | | ... | \| Set variables in 2-node circular topology with DUT interface model\
  49 | | ... | \| Intel-X520-DA2 \|
  50 | | ...
  51 | | [Arguments] | ${iface_model}
  52 | | ...
  53 | | ${iface_model_list}= | Create list | ${iface_model}
  54 | | Append Node | ${nodes['TG']}
  55 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
  56 | | Append Node | ${nodes['TG']}
  57 | | Compute Path | always_same_link=${FALSE}
  58 | | ${tg_if1} | ${tg}= | First Interface
  59 | | ${dut1_if1} | ${dut1}= | First Ingress Interface
  60 | | ${dut1_if2} | ${dut1}= | Last Egress Interface
  61 | | ${tg_if2} | ${tg}= | Last Interface
  62 | | ${tg_if1_mac}= | Get Interface MAC | ${tg} | ${tg_if1}
  63 | | ${tg_if2_mac}= | Get Interface MAC | ${tg} | ${tg_if2}
  64 | | Set Suite Variable | ${tg}
  65 | | Set Suite Variable | ${tg_if1}
  66 | | Set Suite Variable | ${tg_if1_mac}
  67 | | Set Suite Variable | ${tg_if2}
  68 | | Set Suite Variable | ${tg_if2_mac}
  69 | | Set Suite Variable | ${dut1}
  70 | | Set Suite Variable | ${dut1_if1}
  71 | | Set Suite Variable | ${dut1_if2}
  72
  73 | Set variables in 3-node circular topology with DUT interface model
  74 | | [Documentation]
  75 | | ... | Compute path for testing on three given nodes in circular topology
  76 | | ... | based on interface model provided as an argument and set
  77 | | ... | corresponding suite variables.
  78 | | ...
  79 | | ... | *Arguments:*
  80 | | ... | - iface_model - Interface model. Type: string
  81 | | ...
  82 | | ... | _NOTE:_ This KW sets following suite variables:
  83 | | ... | - tg - TG node
  84 | | ... | - tg_if1 - 1st TG interface towards DUT.
  85 | | ... | - tg_if1 - 1st TG interface MAC address.
  86 | | ... | - tg_if2 - 2nd TG interface towards DUT.
  87 | | ... | - tg_if2 - 2nd TG interface MAC address.
  88 | | ... | - dut1 - DUT1 node
  89 | | ... | - dut1_if1 - DUT1 interface towards TG.
  90 | | ... | - dut1_if2 - DUT1 interface towards DUT2.
  91 | | ... | - dut2 - DUT2 node
  92 | | ... | - dut2_if1 - DUT2 interface towards DUT1.
  93 | | ... | - dut2_if2 - DUT2 interface towards TG.
  94 | | ...
  95 | | ... | *Example:*
  96 | | ...
  97 | | ... | \| Set variables in 3-node circular topology with DUT interface model\
  98 | | ... | \| Intel-X520-DA2 \|
  99 | | ...
 100 | | [Arguments] | ${iface_model}
 101 | | ...
 102 | | ${iface_model_list}= | Create list | ${iface_model}
 103 | | Append Node | ${nodes['TG']}
 104 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 105 | | Append Node | ${nodes['DUT2']} | filter_list=${iface_model_list}
 106 | | Append Node | ${nodes['TG']}
 107 | | Compute Path
 108 | | ${tg_if1} | ${tg}= | Next Interface
 109 | | ${dut1_if1} | ${dut1}= | Next Interface
 110 | | ${dut1_if2} | ${dut1}= | Next Interface
 111 | | ${dut2_if1} | ${dut2}= | Next Interface
 112 | | ${dut2_if2} | ${dut2}= | Next Interface
 113 | | ${tg_if2} | ${tg}= | Next Interface
 114 | | ${tg_if1_mac}= | Get Interface MAC | ${tg} | ${tg_if1}
 115 | | ${tg_if2_mac}= | Get Interface MAC | ${tg} | ${tg_if2}
 116 | | Set Suite Variable | ${tg}
 117 | | Set Suite Variable | ${tg_if1}
 118 | | Set Suite Variable | ${tg_if1_mac}
 119 | | Set Suite Variable | ${tg_if2}
 120 | | Set Suite Variable | ${tg_if2_mac}
 121 | | Set Suite Variable | ${dut1}
 122 | | Set Suite Variable | ${dut1_if1}
 123 | | Set Suite Variable | ${dut1_if2}
 124 | | Set Suite Variable | ${dut2}
 125 | | Set Suite Variable | ${dut2_if1}
 126 | | Set Suite Variable | ${dut2_if2}
 127
 128 | Set variables in 3-node circular topology with DUT interface model with double link between DUTs
 129 | | [Documentation]
 130 | | ... | Compute path for testing on three given nodes in circular topology
 131 | | ... | with double link between DUTs based on interface model provided as an
 132 | | ... | argument and set corresponding suite variables.
 133 | | ...
 134 | | ... | *Arguments:*
 135 | | ... | - iface_model - Interface model. Type: string
 136 | | ...
 137 | | ... | _NOTE:_ This KW sets following suite variables:
 138 | | ... | - tg - TG node
 139 | | ... | - tg_if1 - 1st TG interface towards DUT.
 140 | | ... | - tg_if1 - 1st TG interface MAC address.
 141 | | ... | - tg_if2 - 2nd TG interface towards DUT.
 142 | | ... | - tg_if2 - 2nd TG interface MAC address.
 143 | | ... | - dut1 - DUT1 node
 144 | | ... | - dut1_if1 - DUT1 interface towards TG.
 145 | | ... | - dut1_if2_1 - DUT1 interface 1 towards DUT2.
 146 | | ... | - dut1_if2_2 - DUT1 interface 2 towards DUT2.
 147 | | ... | - dut2 - DUT2 node
 148 | | ... | - dut2_if1_1 - DUT2 interface 1 towards DUT1.
 149 | | ... | - dut2_if1_2 - DUT2 interface 2 towards DUT1.
 150 | | ... | - dut2_if2 - DUT2 interface towards TG.
 151 | | ...
 152 | | ... | *Example:*
 153 | | ...
 154 | | ... | \| Set variables in 3-node circular topology with DUT interface model\
 155 | | ... | with double link between DUTs \| Intel-X520-DA2 \|
 156 | | ...
 157 | | [Arguments] | ${iface_model}
 158 | | ...
 159 | | ${iface_model_list}= | Create list | ${iface_model}
 160 | | # Compute path TG - DUT1 with single link in between
 161 | | Append Node | ${nodes['TG']}
 162 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 163 | | Append Node | ${nodes['TG']}
 164 | | Compute Path
 165 | | ${tg_if1} | ${tg}= | Next Interface
 166 | | ${dut1_if1} | ${dut1}= | Next Interface
 167 | | # Compute path TG - DUT2 with single link in between
 168 | | Clear Path
 169 | | Append Node | ${nodes['TG']}
 170 | | Append Node | ${nodes['DUT2']} | filter_list=${iface_model_list}
 171 | | Append Node | ${nodes['TG']}
 172 | | Compute Path
 173 | | ${tg_if2} | ${tg}= | Next Interface
 174 | | ${dut2_if2} | ${dut2}= | Next Interface
 175 | | # Compute path DUT1 - DUT2 with double link in between
 176 | | Clear Path
 177 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 178 | | Append Node | ${nodes['DUT2']} | filter_list=${iface_model_list}
 179 | | Append Node | ${nodes['DUT1']} | filter_list=${iface_model_list}
 180 | | Compute Path | always_same_link=${FALSE}
 181 | | ${dut1_if2_1} | ${dut1}= | First Interface
 182 | | ${dut1_if2_2} | ${dut1}= | Last Interface
 183 | | ${dut2_if1_1} | ${dut2}= | First Ingress Interface
 184 | | ${dut2_if1_2} | ${dut2}= | Last Egress Interface
 185 | | ${tg_if1_mac}= | Get Interface MAC | ${tg} | ${tg_if1}
 186 | | ${tg_if2_mac}= | Get Interface MAC | ${tg} | ${tg_if2}
 187 | | # Set suite variables
 188 | | Set Suite Variable | ${tg}
 189 | | Set Suite Variable | ${tg_if1}
 190 | | Set Suite Variable | ${tg_if1_mac}
 191 | | Set Suite Variable | ${tg_if2}
 192 | | Set Suite Variable | ${tg_if2_mac}
 193 | | Set Suite Variable | ${dut1}
 194 | | Set Suite Variable | ${dut1_if1}
 195 | | Set Suite Variable | ${dut1_if2_1}
 196 | | Set Suite Variable | ${dut1_if2_2}
 197 | | Set Suite Variable | ${dut2}
 198 | | Set Suite Variable | ${dut2_if1_1}
 199 | | Set Suite Variable | ${dut2_if1_2}
 200 | | Set Suite Variable | ${dut2_if2}
 201
 202 | Tear down guest VM with dpdk-testpmd
 203 | | [Documentation]
 204 | | ... | Stop all qemu processes with dpdk-testpmd running on ${dut_node}.
 205 | | ... | Argument is dictionary of all qemu nodes running with its names.
 206 | | ... | Dpdk-testpmd is stopped gracefully with printing stats.
 207 | | ...
 208 | | ... | *Arguments:*
 209 | | ... | - dut_node - Node where to clean qemu. Type: dictionary
 210 | | ... | - dut_vm_refs - VM references on node. Type: dictionary
 211 | | ...
 212 | | ... | *Example:*
 213 | | ...
 214 | | ... | \| Tear down guest VM with dpdk-testpmd \| ${node['DUT1']} \
 215 | | ... | \| ${dut_vm_refs} \|
 216 | | ...
 217 | | [Arguments] | ${dut_node} | ${dut_vm_refs}
 218 | | ${vms_number}= | Get Length | ${dut_vm_refs}
 219 | | ${index}= | Set Variable | ${0}
 220 | | :FOR | ${vm_name} | IN | @{dut_vm_refs}
 221 | | | ${vm}= | Get From Dictionary | ${dut_vm_refs} | ${vm_name}
 222 | | | ${index}= | Evaluate | ${index} + 1
 223 | | | Dpdk Testpmd Stop | ${vm}
 224 | | | Run Keyword | ${vm_name}.Qemu Set Node | ${dut_node}
 225 | | | Run Keyword | ${vm_name}.Qemu Clear Socks
 226 | | | Run Keyword If | '${index}' == '${vms_number}' | ${vm_name}.Qemu Kill All
 227
 228 | Tear down guest VM
 229 | | [Documentation]
 230 | | ... | Stop all qemu processes running on ${dut_node}.
 231 | | ... | Argument is dictionary of all qemu nodes running with its names.
 232 | | ...
 233 | | ... | *Arguments:*
 234 | | ... | - dut_node - Node where to clean qemu. Type: dictionary
 235 | | ... | - dut_vm_refs - VM references on node. Type: dictionary
 236 | | ...
 237 | | ... | *Example:*
 238 | | ...
 239 | | ... | \| Tear down guest VM \| ${node['DUT1']} \
 240 | | ... | \| ${dut_vm_refs} \|
 241 | | ...
 242 | | [Arguments] | ${dut_node} | ${dut_vm_refs}
 243 | | ${vms_number}= | Get Length | ${dut_vm_refs}
 244 | | ${index}= | Set Variable | ${0}
 245 | | :FOR | ${vm_name} | IN | @{dut_vm_refs}
 246 | | | ${vm}= | Get From Dictionary | ${dut_vm_refs} | ${vm_name}
 247 | | | ${index}= | Evaluate | ${index} + 1
 248 | | | Run Keyword | ${vm_name}.Qemu Set Node | ${dut_node}
 249 | | | Run Keyword | ${vm_name}.Qemu Clear Socks
 250 | | | Run Keyword If | '${index}' == '${vms_number}' | ${vm_name}.Qemu Kill All
 251
 252 # Suite setups
 253
 254 | Set up 2-node performance topology with DUT's NIC model
 255 | | [Documentation]
 256 | | ... | Suite preparation phase that sets the default startup configuration of
 257 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 258 | | ... | variables used in test cases based on interface model provided as an
 259 | | ... | argument. Initializes traffic generator.
 260 | | ...
 261 | | ... | *Arguments:*
 262 | | ... | - topology_type - Topology type. Type: string
 263 | | ... | - nic_model - Interface model. Type: string
 264 | | ...
 265 | | ... | *Example:*
 266 | | ...
 267 | | ... | \| 2-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \|
 268 | | ...
 269 | | [Arguments] | ${topology_type} | ${nic_model}
 270 | | ...
 271 | | Set variables in 2-node circular topology with DUT interface model
 272 | | ... | ${nic_model}
 273 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 274 | | ... | ${dut1} | ${dut1_if1} | ${dut1} | ${dut1_if2} | ${topology_type}
 275
 276 | Set up 2-node-switched performance topology with DUT's NIC model
 277 | | [Documentation]
 278 | | ... | Suite preparation phase that sets the default startup configuration of
 279 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 280 | | ... | variables used in test cases based on interface model provided as an
 281 | | ... | argument. Initializes traffic generator.
 282 | | ...
 283 | | ... | *Arguments:*
 284 | | ... | - topology_type - Topology type. Type: string
 285 | | ... | - nic_model - Interface model. Type: string
 286 | | ... | - tg_if1_dest_mac - Interface 1 destination MAC address. Type: string
 287 | | ... | - tg_if2_dest_mac - Interface 2 destination MAC address. Type: string
 288 | | ...
 289 | | ... | *Example:*
 290 | | ...
 291 | | ... | \| 2-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \
 292 | | ... | \| 22:22:33:44:55:66 \| 22:22:33:44:55:55 \|
 293 | | ...
 294 | | [Arguments] | ${topology_type} | ${nic_model} | ${tg_if1_dest_mac}
 295 | | ... | ${tg_if2_dest_mac}
 296 | | ...
 297 | | Set variables in 2-node circular topology with DUT interface model
 298 | | ... | ${nic_model}
 299 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 300 | | ... | ${dut1} | ${dut1_if1} | ${dut1} | ${dut1_if2} | ${topology_type}
 301 | | ... | ${tg_if1_dest_mac} | ${tg_if2_dest_mac}
 302
 303 | Set up 3-node performance topology with DUT's NIC model
 304 | | [Documentation]
 305 | | ... | Suite preparation phase that sets the default startup configuration of
 306 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 307 | | ... | variables used in test cases based on interface model provided as an
 308 | | ... | argument. Initializes traffic generator.
 309 | | ...
 310 | | ... | *Arguments:*
 311 | | ... | - topology_type - Topology type. Type: string
 312 | | ... | - nic_model - Interface model. Type: string
 313 | | ...
 314 | | ... | *Example:*
 315 | | ...
 316 | | ... | \| Set up 3-node performance topology with DUT's NIC model \| L2 \
 317 | | ... | \| Intel-X520-DA2 \|
 318 | | ...
 319 | | [Arguments] | ${topology_type} | ${nic_model}
 320 | | ...
 321 | | Set variables in 3-node circular topology with DUT interface model
 322 | | ... | ${nic_model}
 323 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 324 | | ... | ${dut1} | ${dut1_if1} | ${dut2} | ${dut2_if2} | ${topology_type}
 325
 326 | Set up 3-node performance topology with DUT's NIC model with double link between DUTs
 327 | | [Documentation]
 328 | | ... | Suite preparation phase that sets the default startup configuration of
 329 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 330 | | ... | variables used in test cases based on interface model provided as an
 331 | | ... | argument. Initializes traffic generator.
 332 | | ...
 333 | | ... | *Arguments:*
 334 | | ... | - topology_type - Topology type. Type: string
 335 | | ... | - nic_model - Interface model. Type: string
 336 | | ...
 337 | | ... | *Example:*
 338 | | ...
 339 | | ... | \| Set up 3-node performance topology with DUT's NIC model with \
 340 | | ... | double link between DUTs \| L2 \| Intel-X520-DA2 \|
 341 | | ...
 342 | | [Arguments] | ${topology_type} | ${nic_model}
 343 | | ...
 344 | | Set variables in 3-node circular topology with DUT interface model with double link between DUTs
 345 | | ... | ${nic_model}
 346 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 347 | | ... | ${dut1} | ${dut1_if1} | ${dut2} | ${dut2_if2} | ${topology_type}
 348
 349 | Set up DPDK 2-node performance topology with DUT's NIC model
 350 | | [Documentation]
 351 | | ... | Updates interfaces on all nodes and sets the global
 352 | | ... | variables used in test cases based on interface model provided as an
 353 | | ... | argument. Initializes traffic generator. Initializes DPDK test
 354 | | ... | environment.
 355 | | ...
 356 | | ... | *Arguments:*
 357 | | ... | - topology_type - Topology type. Type: string
 358 | | ... | - nic_model - Interface model. Type: string
 359 | | ...
 360 | | ... | *Example:*
 361 | | ...
 362 | | ... | \| Set up DPDK 2-node performance topology with DUT's NIC model \
 363 | | ... | \| L2 \| Intel-X520-DA2 \|
 364 | | ...
 365 | | [Arguments] | ${topology_type} | ${nic_model}
 366 | | ...
 367 | | Set variables in 2-node circular topology with DUT interface model
 368 | | ... | ${nic_model}
 369 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 370 | | ... | ${dut1} | ${dut1_if1} | ${dut1} | ${dut1_if2} | ${topology_type}
 371 | | Initialize DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 372
 373 | Set up DPDK 3-node performance topology with DUT's NIC model
 374 | | [Documentation]
 375 | | ... | Updates interfaces on all nodes and sets the global
 376 | | ... | variables used in test cases based on interface model provided as an
 377 | | ... | argument. Initializes traffic generator. Initializes DPDK test
 378 | | ... | environment.
 379 | | ...
 380 | | ... | *Arguments:*
 381 | | ... | - topology_type - Topology type. Type: string
 382 | | ... | - nic_model - Interface model. Type: string
 383 | | ...
 384 | | ... | *Example:*
 385 | | ...
 386 | | ... | \| 3-node Performance Suite Setup \| L2 \| Intel-X520-DA2 \|
 387 | | ...
 388 | | [Arguments] | ${topology_type} | ${nic_model}
 389 | | ...
 390 | | Set variables in 3-node circular topology with DUT interface model
 391 | | ... | ${nic_model}
 392 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 393 | | ... | ${dut1} | ${dut1_if1} | ${dut2} | ${dut2_if2} | ${topology_type}
 394 | | Initialize DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 395 | | Initialize DPDK Environment | ${dut2} | ${dut2_if1} | ${dut2_if2}
 396
 397 | Set up SRIOV 2-node performance topology with DUT's NIC model
 398 | | [Documentation]
 399 | | ... | Suite preparation phase that sets default startup configuration of
 400 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets global
 401 | | ... | variables used in test cases based on interface model provided as an
 402 | | ... | argument. Initializes traffic generator.
 403 | | ... | It configures PCI device with VFs on all DUTs.
 404 | | ...
 405 | | ... | *Arguments:*
 406 | | ... | - topology_type - Topology type. Type: string
 407 | | ... | - nic_model - Interface model. Type: string
 408 | | ... | - vf_driver - Virtual function driver. Type: string
 409 | | ... | - numvfs - Number of VFs. Type: integer
 410 | | ...
 411 | | ... | *Example:*
 412 | | ...
 413 | | ... | \| Set up SRIOV 2-node performance topology with DUT's NIC model \
 414 | | ... | \| L2 \| Intel-X520-DA2 \| AVF \|
 415 | | ...
 416 | | [Arguments] | ${topology_type} | ${nic_model} | ${vf_driver}
 417 | | ... | ${numvfs}=${1}
 418 | | ...
 419 | | Set variables in 2-node circular topology with DUT interface model
 420 | | ... | ${nic_model}
 421 | | Run Keyword If | '${vf_driver}' == 'AVF'
 422 | | ... | Configure AVF interfaces on all DUTs | numvfs=${numvfs}
 423 | | ... | topology_type=${topology_type}
 424 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 425 | | ... | ${dut1} | ${dut1_if1_vf0} | ${dut1} | ${dut1_if2_vf0}
 426 | | ... | ${topology_type}
 427
 428 | Set up SRIOV 3-node performance topology with DUT's NIC model
 429 | | [Documentation]
 430 | | ... | Suite preparation phase that sets default startup configuration of
 431 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets global
 432 | | ... | variables used in test cases based on interface model provided as an
 433 | | ... | argument. Initializes traffic generator.
 434 | | ... | It configures PCI device with VFs on all DUTs.
 435 | | ...
 436 | | ... | *Arguments:*
 437 | | ... | - topology_type - Topology type. Type: string
 438 | | ... | - nic_model - Interface model. Type: string
 439 | | ... | - vf_driver - Virtual function driver. Type: string
 440 | | ... | - numvfs - Number of VFs. Type: integer
 441 | | ...
 442 | | ... | *Example:*
 443 | | ...
 444 | | ... | \| Set up SRIOV 3-node performance topology with DUT's NIC model \
 445 | | ... | \| L2 \| Intel-X520-DA2 \| AVF \|
 446 | | ...
 447 | | [Arguments] | ${topology_type} | ${nic_model} | ${vf_driver}
 448 | | ... | ${numvfs}=${1}
 449 | | ...
 450 | | Set variables in 3-node circular topology with DUT interface model
 451 | | ... | ${nic_model}
 452 | | Run Keyword If | '${vf_driver}' == 'AVF'
 453 | | ... | Configure AVF interfaces on all DUTs | numvfs=${numvfs}
 454 | | ... | topology_type=${topology_type}
 455 | | Initialize traffic generator | ${tg} | ${tg_if1} | ${tg_if2}
 456 | | ... | ${dut1} | ${dut1_if1_vf0} | ${dut2} | ${dut2_if2_vf0}
 457 | | ... | ${topology_type}
 458
 459 | Set up IPSec performance test suite
 460 | | [Documentation]
 461 | | ... | Suite preparation phase that sets default startup configuration of
 462 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets global
 463 | | ... | variables used in test cases based on interface model provided as an
 464 | | ... | argument. Initializes traffic generator.
 465 | | ... | Then it configures crypto device and kernel module on all DUTs.
 466 | | ...
 467 | | ... | *Arguments:*
 468 | | ... | - topology_type - Topology type. Type: string
 469 | | ... | - nic_model - Interface model. Type: string
 470 | | ... | - crypto_type - Crypto device type - HW_cryptodev or SW_cryptodev
 471 | | ... | (Optional). Type: string, default value: HW_cryptodev
 472 | | ...
 473 | | ... | *Example:*
 474 | | ...
 475 | | ... | \| Set up IPSec performance test suite \| L2 \
 476 | | ... | \| Intel-X520-DA2 \|
 477 | | ...
 478 | | [Arguments] | ${topology_type} | ${nic_model} | ${crypto_type}=HW_cryptodev
 479 | | ...
 480 | | Set up 3-node performance topology with DUT's NIC model
 481 | | ... | ${topology_type} | ${nic_model}
 482 | | ${numvfs}= | Set Variable If
 483 | | ... | '${crypto_type}' == 'HW_cryptodev' | ${32}
 484 | | ... | '${crypto_type}' == 'SW_cryptodev' | ${0}
 485 | | Configure crypto device on all DUTs | force_init=${True} | numvfs=${numvfs}
 486 | | Run Keyword If | '${crypto_type}' == 'HW_cryptodev'
 487 | | ... | Configure kernel module on all DUTs | vfio_pci | force_load=${True}
 488
 489 | Set up performance test suite with MEMIF
 490 | | [Documentation]
 491 | | ... | Append memif_plugin.so to the list of enabled plugins.
 492 | | ...
 493 | | Set Suite Variable | @{plugins_to_enable}
 494 | | Append To List | ${plugins_to_enable} | memif_plugin.so
 495
 496 | Set up performance test suite with NAT
 497 | | [Documentation]
 498 | | ... | Append nat_plugin.so to the list of enabled plugins.
 499 | | ...
 500 | | Set Suite Variable | @{plugins_to_enable}
 501 | | Append To List | ${plugins_to_enable} | nat_plugin.so
 502
 503 | Set up performance test suite with ACL
 504 | | [Documentation]
 505 | | ... | Append acl_plugin.so to the list of enabled plugins.
 506 | | ...
 507 | | Set Suite Variable | @{plugins_to_enable}
 508 | | Append To List | ${plugins_to_enable} | acl_plugin.so
 509
 510 | Set up performance test suite with AVF driver
 511 | | [Documentation]
 512 | | ... | Append avf_plugin.so to the list of enabled plugins.
 513 | | ...
 514 | | Set Suite Variable | @{plugins_to_enable}
 515 | | Append To List | ${plugins_to_enable} | avf_plugin.so
 516
 517 | Set up performance test suite with Static SRv6 proxy
 518 | | [Documentation]
 519 | | ... | Append srv6as_plugin.so to the list of enabled plugins.
 520 | | ...
 521 | | Set Suite Variable | @{plugins_to_enable}
 522 | | Append To List | ${plugins_to_enable} | srv6as_plugin.so
 523
 524 | Set up performance test suite with Dynamic SRv6 proxy
 525 | | [Documentation]
 526 | | ... | Append srv6ad_plugin.so to the list of enabled plugins.
 527 | | ...
 528 | | Set Suite Variable | @{plugins_to_enable}
 529 | | Append To List | ${plugins_to_enable} | srv6ad_plugin.so
 530
 531 | Set up performance test suite with Masquerading SRv6 proxy
 532 | | [Documentation]
 533 | | ... | Append srv6am_plugin.so to the list of enabled plugins.
 534 | | ...
 535 | | Set Suite Variable | @{plugins_to_enable}
 536 | | Append To List | ${plugins_to_enable} | srv6am_plugin.so
 537
 538 | Set up performance test suite with LACP mode link bonding
 539 | | [Documentation]
 540 | | ... | Append lacp_plugin.so to the list of enabled plugins.
 541 | | ...
 542 | | Set Suite Variable | @{plugins_to_enable}
 543 | | Append To List | ${plugins_to_enable} | lacp_plugin.so
 544
 545 | Set up 3-node performance topology with wrk and DUT's NIC model
 546 | | [Documentation]
 547 | | ... | Suite preparation phase that sets the default startup configuration of
 548 | | ... | VPP on all DUTs. Updates interfaces on all nodes and sets the global
 549 | | ... | variables used in test cases based on interface model provided as an
 550 | | ... | argument. Installs the traffic generator.
 551 | | ...
 552 | | ... | *Arguments:*
 553 | | ... | - iface_model - Interface model. Type: string
 554 | | ...
 555 | | ... | *Example:*
 556 | | ...
 557 | | ... | \| Set up 3-node performance topology with wrk and DUT's NIC model\
 558 | | ... | \| Intel-X520-DA2 \|
 559 | | ...
 560 | | [Arguments] | ${iface_model}
 561 | | ...
 562 | | Set variables in 3-node circular topology with DUT interface model
 563 | | ... | ${iface_model}
 564 | | Iface update numa node | ${tg}
 565 # Make sure TRex is stopped
 566 | | ${running}= | Is TRex running | ${tg}
 567 | | Run keyword if | ${running}==${True} | Teardown traffic generator | ${tg}
 568 | | ${curr_driver}= | Get PCI dev driver | ${tg}
 569 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']}
 570 | | Run keyword if | '${curr_driver}'!='${None}'
 571 | | ... | PCI Driver Unbind | ${tg} |
 572 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']}
 573 # Bind tg_if1 to driver specified in the topology
 574 | | ${driver}= | Get Variable Value | ${tg['interfaces']['${tg_if1}']['driver']}
 575 | | PCI Driver Bind | ${tg}
 576 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']} | ${driver}
 577 # Set IP on tg_if1
 578 | | ${intf_name}= | Get Linux interface name | ${tg}
 579 | | ... | ${tg['interfaces']['${tg_if1}']['pci_address']}
 580 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.10.1 | 24
 581 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.20.1 | 24
 582 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.30.1 | 24
 583 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.40.1 | 24
 584 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.50.1 | 24
 585 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.60.1 | 24
 586 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.70.1 | 24
 587 | | Set Linux interface IP | ${tg} | ${intf_name} | 192.168.80.1 | 24
 588 | | Set Linux interface up | ${tg} | ${intf_name}
 589 | | Install wrk | ${tg}
 590
 591 # Suite teardowns
 592
 593 | Tear down 2-node performance topology
 594 | | [Documentation]
 595 | | ... | Suite teardown phase with traffic generator teardown.
 596 | | ...
 597 | | Teardown traffic generator | ${tg}
 598
 599 | Tear down 3-node performance topology
 600 | | [Documentation]
 601 | | ... | Suite teardown phase with traffic generator teardown.
 602 | | ...
 603 | | Teardown traffic generator | ${tg}
 604
 605 # Tests setups
 606
 607 | Set up performance test
 608 | | [Documentation] | Common test setup for performance tests.
 609 | | ...
 610 | | Reset VAT History On All DUTs | ${nodes}
 611 | | Create base startup configuration of VPP on all DUTs
 612
 613 | Set up tcp performance test
 614 | | [Documentation] | Common test setup for TCP performance tests.
 615 | | ...
 616 | | Reset VAT History On All DUTs | ${nodes}
 617 | | Create base startup configuration of VPP for TCP tests on all DUTs
 618
 619 | Set up performance test with Ligato Kubernetes
 620 | | [Documentation] | Common test setup for performance tests with Ligato \
 621 | | ... | Kubernetes.
 622 | | ...
 623 | | Apply Kubernetes resource on all duts | ${nodes} | namespaces/csit.yaml
 624 | | Apply Kubernetes resource on all duts | ${nodes} | pods/kafka.yaml
 625 | | Apply Kubernetes resource on all duts | ${nodes} | pods/etcdv3.yaml
 626 | | Apply Kubernetes resource on all duts | ${nodes}
 627 | | ... | configmaps/vswitch-agent-cfg.yaml
 628 | | Apply Kubernetes resource on all duts | ${nodes}
 629 | | ... | configmaps/vnf-agent-cfg.yaml
 630 | | Apply Kubernetes resource on all duts | ${nodes}
 631 | | ... | pods/contiv-sfc-controller.yaml
 632 | | Apply Kubernetes resource on all duts | ${nodes}
 633 | | ... | pods/contiv-vswitch.yaml
 634
 635 | Set up performance test with containers
 636 | | [Documentation]
 637 | | ... | Common test setup for performance tests with containers
 638 | | ...
 639 | | ... | *Arguments:*
 640 | | ... | - chains: Total number of chains. Type: integer
 641 | | ... | - nodeness: Total number of nodes per chain. Type: integer
 642 | | ... | - auto_scale - If True, use same amount of Dataplane threads for
 643 | | ... |   network function as DUT, otherwise use single physical core for
 644 | | ... |   every network function. Type: boolean
 645 | | ...
 646 | | ... | *Example:*
 647 | | ...
 648 | | ... | \| Set up performance test with containers \| 1 \| 1 \|
 649 | | ...
 650 | | [Arguments] | ${nf_chains}=${1} | ${nf_nodes}=${1} | ${auto_scale}=${True}
 651 | | ...
 652 | | Set Test Variable | @{container_groups} | @{EMPTY}
 653 | | Set Test Variable | ${container_group} | CNF
 654 | | Set Test Variable | ${nf_nodes}
 655 | | Import Library | resources.libraries.python.ContainerUtils.ContainerManager
 656 | | ... | engine=${container_engine} | WITH NAME | ${container_group}
 657 | | Construct chains of containers on all DUTs | ${nf_chains} | ${nf_nodes}
 658 | | ... | auto_scale=${auto_scale}
 659 | | Acquire all '${container_group}' containers
 660 | | Create all '${container_group}' containers
 661 | | Configure VPP in all '${container_group}' containers
 662 | | Stop VPP service on all DUTs | ${nodes}
 663 | | Start VPP in all '${container_group}' containers
 664 | | Start VPP service on all DUTs | ${nodes}
 665 | | Append To List | ${container_groups} | ${container_group}
 666
 667 # Tests teardowns
 668
 669 | Tear down performance discovery test
 670 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 671 | | ... | tests.
 672 | | ...
 673 | | ... | *Arguments:*
 674 | | ... | - rate - Rate for sending packets. Type: string
 675 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 676 | | ... | - topology_type - Topology type. Type: string
 677 | | ...
 678 | | ... | *Example:*
 679 | | ...
 680 | | ... | \| Tear down performance discovery test \| 4.0mpps \| 64 \
 681 | | ... | \| 3-node-IPv4 \|
 682 | | ...
 683 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 684 | | ...
 685 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 686 | | Show VAT History On All DUTs | ${nodes}
 687 | | Run Keyword If Test Failed
 688 | | ... | Set Test Variable | ${pkt_trace} | ${True}
 689 | | Run Keyword If Test Failed
 690 | | ... | Traffic should pass with no loss | ${perf_trial_duration} | ${rate}
 691 | | ... | ${framesize} | ${topology_type} | fail_on_loss=${False}
 692
 693 | Tear down performance mrr test
 694 | | [Documentation] | Common test teardown for max-received-rate performance
 695 | | ... | tests.
 696 | | ...
 697 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 698 | | Show VAT History On All DUTs | ${nodes}
 699
 700 | Tear down performance test with wrk
 701 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 702 | | ... | tests.
 703 | | ...
 704 | | ... | *Example:*
 705 | | ...
 706 | | ... | \| Tear down performance test with wrk \|
 707 | | ...
 708 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 709 | | Show VAT History On All DUTs | ${nodes}
 710 | | Show statistics on all DUTs | ${nodes}
 711
 712 | Tear down performance test with container
 713 | | [Documentation]
 714 | | ... | Common test teardown for performance tests which uses containers.
 715 | | ...
 716 | | :FOR | ${container_group} | IN | @{container_groups}
 717 | | | Destroy all '${container_group}' containers
 718
 719 | Tear down performance test with vhost and VM with dpdk-testpmd
 720 | | [Documentation] | Common test teardown for performance tests which use
 721 | | ... | vhost(s) and VM(s) with dpdk-testpmd.
 722 | | ...
 723 | | ... | *Arguments:*
 724 | | ... | - rate - Rate for sending packets. Type: string
 725 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 726 | | ... | - topology_type - Topology type. Type: string
 727 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 728 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 729 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 730 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 731 | | ...
 732 | | ... | *Example:*
 733 | | ...
 734 | | ... | \| Tear down performance test with vhost and VM with dpdk-testpmd \
 735 | | ... | \| 4.0mpps \| 64 \| 3-node-IPv4 \| ${node['DUT1']} \| ${dut_vm_refs} \
 736 | | ... | \| ${node['DUT2']} \| ${dut_vm_refs} \|
 737 | | ...
 738 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 739 | | ... | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 740 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 741 | | ...
 742 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 743 | | Show VAT History On All DUTs | ${nodes}
 744 | | Show VPP vhost on all DUTs | ${nodes}
 745 | | Show statistics on all DUTs | ${nodes}
 746 | | Run Keyword If Test Failed
 747 | | ... | Traffic should pass with no loss | ${perf_trial_duration} | ${rate}
 748 | | ... | ${framesize} | ${topology_type} | fail_on_loss=${False}
 749 | | Run keyword unless | ${dut1_node}==${None}
 750 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 751 | | Run keyword unless | ${dut2_node}==${None}
 752 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 753
 754 | Tear down mrr test with vhost and VM with dpdk-testpmd
 755 | | [Documentation] | Common test teardown for mrr tests which use
 756 | | ... | vhost(s) and VM(s) with dpdk-testpmd.
 757 | | ...
 758 | | ... | *Arguments:*
 759 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 760 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 761 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 762 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 763 | | ...
 764 | | ... | *Example:*
 765 | | ...
 766 | | ... | \| Tear down performance test with vhost and VM with dpdk-testpmd \
 767 | | ... | \| ${node['DUT1']} \| ${dut_vm_refs} \
 768 | | ... | \| ${node['DUT2']} \| ${dut_vm_refs} \|
 769 | | ...
 770 | | [Arguments] | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 771 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 772 | | ...
 773 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 774 | | Show VAT History On All DUTs | ${nodes}
 775 | | Show VPP vhost on all DUTs | ${nodes}
 776 | | Show statistics on all DUTs | ${nodes}
 777 | | Run keyword unless | ${dut1_node}==${None}
 778 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 779 | | Run keyword unless | ${dut2_node}==${None}
 780 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 781
 782 | Tear down performance test with vhost and VM with dpdk-testpmd and ACL
 783 | | [Documentation] | Common test teardown for performance tests which use
 784 | | ... | vhost(s) and VM(s) with ACL and dpdk-testpmd.
 785 | | ...
 786 | | ... | *Arguments:*
 787 | | ... | - rate - Rate for sending packets. Type: string
 788 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 789 | | ... | - topology_type - Topology type. Type: string
 790 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 791 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 792 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 793 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 794 | | ...
 795 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 796 | | ... | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 797 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 798 | | ...
 799 | | Tear down performance test with vhost and VM with dpdk-testpmd
 800 | | ... | ${rate} | ${framesize} | ${topology_type}
 801 | | ... | ${dut1_node} | ${dut1_vm_refs}
 802 | | ... | ${dut2_node} | ${dut2_vm_refs}
 803 | | Run Keyword If Test Failed | Vpp Log Plugin Acl Settings | ${dut1}
 804 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 805 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 806
 807 | Tear down mrr test with vhost and VM with dpdk-testpmd and ACL
 808 | | [Documentation] | Common test teardown for mrr tests which use
 809 | | ... | vhost(s) and VM(s) with ACL and dpdk-testpmd.
 810 | | ...
 811 | | ... | *Arguments:*
 812 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 813 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 814 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 815 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 816 | | ...
 817 | | [Arguments] | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 818 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 819 | | ...
 820 | | Tear down mrr test with vhost and VM with dpdk-testpmd
 821 | | ... | ${dut1_node} | ${dut1_vm_refs}
 822 | | ... | ${dut2_node} | ${dut2_vm_refs}
 823 | | Run Keyword If Test Failed | Vpp Log Plugin Acl Settings | ${dut1}
 824 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 825 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 826
 827 | Tear down performance pdrchk test with vhost and VM with dpdk-testpmd
 828 | | [Documentation] | Common test teardown for performance pdrchk tests which \
 829 | | ... | use vhost(s) and VM(s) with dpdk-testpmd.
 830 | | ...
 831 | | ... | *Arguments:*
 832 | | ... | - rate - Rate for sending packets. Type: string
 833 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 834 | | ... | - topology_type - Topology type. Type: string
 835 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 836 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 837 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 838 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 839 | | ...
 840 | | ... | *Example:*
 841 | | ...
 842 | | ... | \| Tear down performance pdrchk test with vhost and VM with \
 843 | | ... | dpdk-testpmd \| 4.0mpps \| 64 \| 3-node-IPv4 \| ${node['DUT1']} \
 844 | | ... | \| ${dut_vm_refs} \| ${node['DUT2']} \| ${dut_vm_refs} \|
 845 | | ...
 846 | | [Arguments] | ${rate} | ${framesize} | ${topology_type}
 847 | | ... | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 848 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 849 | | ...
 850 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 851 | | Show VAT History On All DUTs | ${nodes}
 852 | | Show VPP vhost on all DUTs | ${nodes}
 853 | | Show statistics on all DUTs | ${nodes}
 854 | | Run keyword unless | ${dut1_node}==${None}
 855 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 856 | | Run keyword unless | ${dut2_node}==${None}
 857 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 858
 859 | Tear down performance mrr test with vhost and VM with dpdk-testpmd
 860 | | [Documentation] | Common test teardown for performance mrr tests which \
 861 | | ... | use vhost(s) and VM(s) with dpdk-testpmd.
 862 | | ...
 863 | | ... | *Arguments:*
 864 | | ... | - dut1_node - Node where to clean qemu. Type: dictionary
 865 | | ... | - dut1_vm_refs - VM references on node. Type: dictionary
 866 | | ... | - dut2_node - Node where to clean qemu. Type: dictionary
 867 | | ... | - dut2_vm_refs - VM references on node. Type: dictionary
 868 | | ...
 869 | | ... | *Example:*
 870 | | ...
 871 | | ... | \| Tear down performance mrr test with vhost and VM with \
 872 | | ... | dpdk-testpmd \| ${node['DUT1']} \| ${dut_vm_refs} \| ${node['DUT2']} \
 873 | | ... | \| ${dut_vm_refs} \|
 874 | | ...
 875 | | [Arguments] | ${dut1_node}=${None} | ${dut1_vm_refs}=${None}
 876 | | ... | ${dut2_node}=${None} | ${dut2_vm_refs}=${None}
 877 | | ...
 878 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
 879 | | Show VAT History On All DUTs | ${nodes}
 880 | | Show VPP vhost on all DUTs | ${nodes}
 881 | | Run keyword unless | ${dut1_node}==${None}
 882 | | ... | Tear down guest VM with dpdk-testpmd | ${dut1} | ${dut1_vm_refs}
 883 | | Run keyword unless | ${dut2_node}==${None}
 884 | | ... | Tear down guest VM with dpdk-testpmd | ${dut2} | ${dut2_vm_refs}
 885
 886 | Tear down DPDK 2-node performance topology
 887 | | [Documentation]
 888 | | ... | Suite teardown phase with traffic generator teardown.
 889 | | ... | Cleanup DPDK test environment.
 890 | | ...
 891 | | Teardown traffic generator | ${tg}
 892 | | Cleanup DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 893
 894 | Tear down DPDK 3-node performance topology
 895 | | [Documentation]
 896 | | ... | Suite teardown phase with traffic generator teardown.
 897 | | ... | Cleanup DPDK test environment.
 898 | | ...
 899 | | Teardown traffic generator | ${tg}
 900 | | Cleanup DPDK Environment | ${dut1} | ${dut1_if1} | ${dut1_if2}
 901 | | Cleanup DPDK Environment | ${dut2} | ${dut2_if1} | ${dut2_if2}
 902
 903 | Tear down performance discovery test with NAT
 904 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 905 | | ... | tests with NAT feature used.
 906 | | ...
 907 | | ... | *Arguments:*
 908 | | ... | - rate - Rate for sending packets. Type: string
 909 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 910 | | ... | - traffic_profile - Traffic profile. Type: string
 911 | | ...
 912 | | ... | *Example:*
 913 | | ...
 914 | | ... | \| Tear down performance discovery test with NAT \| 100000pps \| 64 \
 915 | | ... | \| ${traffic_profile} \|
 916 | | ...
 917 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
 918 | | ...
 919 | | Tear down performance discovery test | ${rate} | ${framesize}
 920 | | ... | ${traffic_profile}
 921 | | Show NAT verbose | ${dut1}
 922 | | Show NAT verbose | ${dut2}
 923
 924 | Tear down mrr test with NAT
 925 | | [Documentation] | Common test teardown for mrr performance \
 926 | | ... | tests with NAT feature used.
 927 | | ...
 928 | | ... | \| Tear down mrr test with NAT \|
 929 | | ...
 930 | | Tear down performance mrr test
 931 | | Show NAT verbose | ${dut1}
 932 | | Show NAT verbose | ${dut2}
 933
 934 | Tear down performance test with ACL
 935 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 936 | | ... | tests with ACL feature used.
 937 | | ...
 938 | | ... | *Arguments:*
 939 | | ... | - rate - Rate for sending packets. Type: string
 940 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 941 | | ... | - traffic_profile - Traffic profile. Type: string
 942 | | ...
 943 | | ... | *Example:*
 944 | | ...
 945 | | ... | \| Tear down performance test with ACL \| 100000pps \| 64 \
 946 | | ... | \| ${traffic_profile} \|
 947 | | ...
 948 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
 949 | | ...
 950 | | Tear down performance discovery test | ${rate} | ${framesize}
 951 | | ... | ${traffic_profile}
 952 | | Run Keyword If Test Failed | Vpp Log Plugin Acl Settings | ${dut1}
 953 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 954 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 955
 956 | Tear down mrr test with ACL
 957 | | [Documentation] | Common test teardown for mrr performance \
 958 | | ... | tests with ACL feature used.
 959 | | ...
 960 | | ... | *Example:*
 961 | | ...
 962 | | ... | \| Tear down mrr test with ACL \|
 963 | | ...
 964 | | Tear down performance mrr test
 965 | | Run Keyword If Test Failed | Vpp Log Plugin Acl Settings | ${dut1}
 966 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 967 | | ... | Vpp Log Plugin Acl Interface Assignment | ${dut1}
 968
 969 | Tear down performance test with MACIP ACL
 970 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
 971 | | ... | tests with MACIP ACL feature used.
 972 | | ...
 973 | | ... | *Arguments:*
 974 | | ... | - rate - Rate for sending packets. Type: string
 975 | | ... | - framesize - L2 Frame Size [B]. Type: integer
 976 | | ... | - traffic_profile - Traffic profile. Type: string
 977 | | ...
 978 | | ... | *Example:*
 979 | | ...
 980 | | ... | \| Tear down performance test with MACIP ACL \| 100000pps \| 64 \
 981 | | ... | \| ${traffic_profile} \|
 982 | | ...
 983 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
 984 | | ...
 985 | | Tear down performance discovery test | ${rate} | ${framesize}
 986 | | ... | ${traffic_profile}
 987 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
 988 | | ... | Vpp Log Macip Acl Settings | ${dut1}
 989 | | Run Keyword And Ignore Error
 990 | | ... | Vpp Log Macip Acl Interface Assignment | ${dut1}
 991
 992 | Tear down mrr test with MACIP ACL
 993 | | [Documentation] | Common test teardown for mrr performance \
 994 | | ... | tests with MACIP ACL feature used.
 995 | | ...
 996 | | ... | *Example:*
 997 | | ...
 998 | | ... | \| Tear down mrr test with MACIP ACL \|
 999 | | ...
1000 | | Tear down performance mrr test
1001 | | Run Keyword If Test Failed | Run Keyword And Ignore Error
1002 | | ... | Vpp Log Macip Acl Settings | ${dut1}
1003 | | Run Keyword And Ignore Error
1004 | | ... | Vpp Log Macip Acl Interface Assignment | ${dut1}
1005
1006 | Tear down performance test with Ligato Kubernetes
1007 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
1008 | | ... | tests with Ligato Kubernetes.
1009 | | ...
1010 | | Run Keyword If Test Failed
1011 | | ... | Get Kubernetes logs on all DUTs | ${nodes} | csit
1012 | | Run Keyword If Test Failed
1013 | | ... | Describe Kubernetes resource on all DUTs | ${nodes} | csit
1014 | | Delete Kubernetes resource on all DUTs | ${nodes} | csit
1015
1016 | Tear down performance test with SRv6 with encapsulation
1017 | | [Documentation] | Common test teardown for ndrdisc and pdrdisc performance \
1018 | | ... | tests with SRv6 with encapsulation feature used.
1019 | | ...
1020 | | ... | *Arguments:*
1021 | | ... | - rate - Rate for sending packets. Type: string
1022 | | ... | - framesize - L2 Frame Size [B]. Type: integer/string
1023 | | ... | - traffic_profile - Traffic profile. Type: string
1024 | | ...
1025 | | ... | *Example:*
1026 | | ...
1027 | | ... | \| Tear down performance test with SRv6 with encapsulation \
1028 | | ... | \| 100000pps \| 64 \| ${traffic_profile} \|
1029 | | ...
1030 | | [Arguments] | ${rate} | ${framesize} | ${traffic_profile}
1031 | | ...
1032 | | Tear down performance discovery test | ${rate} | ${framesize}
1033 | | ... | ${traffic_profile}
1034 | | Run Keyword If Test Failed | Show SR Policies on all DUTs | ${nodes}
1035 | | Run Keyword If Test Failed
1036 | | ... | Show SR Steering Policies on all DUTs | ${nodes}
1037 | | Run Keyword If Test Failed | Show SR LocalSIDs on all DUTs | ${nodes}
1038
1039 | Tear down mrr test with SRv6 with encapsulation
1040 | | [Documentation] | Common test teardown for mrr tests with SRv6 with \
1041 | | ... | encapsulation feature used.
1042 | | ...
1043 | | ... | *Example:*
1044 | | ...
1045 | | ... | \| Tear down mrr test with SRv6 with encapsulation \|
1046 | | ...
1047 | | Remove All Added Ports On All DUTs From Topology | ${nodes}
1048 | | Show VAT History On All DUTs | ${nodes}
1049 | | Run Keyword If Test Failed | Show SR Policies on all DUTs | ${nodes}
1050 | | Run Keyword If Test Failed
1051 | | ... | Show SR Steering Policies on all DUTs | ${nodes}
1052 | | Run Keyword If Test Failed | Show SR LocalSIDs on all DUTs | ${nodes}